Ejemplo algoritmo ahorcado

https://youtu.be/k3zV40fR1N8

Algoritmo ahorcado
	Definir pais Como Caracter // palabra secreta, almacenar el pais
	Definir pais_jugador Como Caracter // almacenar las letras acertadas del jugador
	Definir letras_jugador Como Caracter // almacenar las letras ingresadas por el jugador
	Definir letra Como Caracter // letra de cada turno
	Definir longitud_p Como Entero // almacenar cantidad de caracteres en el pais
	Definir x Como Entero // selector de pais
	Definir intentos Como Entero // cantidad de intentos
	x = Aleatorio(1,12) // generacion aleatoria de numero que representara un pais  NO azar(12)+1
	// Asignacion de la palabra secreta
	Segun x  Hacer
		1:
			pais = "arabia"
		2:
			pais = "alemania"
		3:
			pais = "colombia"
		4:
			pais = "italia"
		5:
			pais = "argentina"
		6:
			pais = "bolivia"
		7:
			pais = "peru"
		8:
			pais = "francia"
		9:
			pais = "portugal"
		10:
			pais = "venezuela"
		11:
			pais = "belgica"
		12:
			pais = "chile"
	FinSegun
	pais_jugador = ""
	// iniciazalizacion de textos
	letras_jugador = "" // variable de historico de letras
	longitud_p = longitud(pais) // cantidad de caracteres
	intentos = 12
	acumulador_aciertos = 0
	// mensajes informativos
	Borrar Pantalla
	Escribir "Juego del ahorcado"
	Escribir "Adivina la palabra"
	Escribir "" // salto de linea
	Escribir "" // salto de linea
	// Dibujar el tablero inicial
	Para i=1 Hasta longitud_p Hacer
		Escribir "_ " Sin Saltar
	FinPara
	Escribir "" // salto de linea
	Escribir "" // salto de linea
	// ciclo repetitivo para pedir letras en el juego
	Mientras intentos>=1 Hacer
		contador_acierto = 0
		Escribir "has usado las letras: ",letras_jugador
		//Escribir "has usado formado: ",pais_jugador
		Escribir "te quedan: ",intentos," intentos"
		Escribir "Digite una letra:"
		Leer letra
		// ciclo para verificar si la letra ya fue ingresada previamente
		Para j=1 Hasta longitud(letras_jugador) Hacer
			Si letra=subcadena(letras_jugador,j,j) Entonces
				control = 1
				j = longitud(letras_jugador)+1
				i = longitud_p+1 // forzar salida del mientras
				contador_acierto = 99 // para evitar conflictos con la ausencia de aciertos
			Sino
				control = 9
			FinSi
		FinPara
		// si la letra es nueva, se agrega a la variable de historico de letras
		Si control=9 Entonces
			letras_jugador = letras_jugador+letra
		FinSi
		i = 1 // contador para recorrer los caracteres de la palabra secreta
		// recorrer la palabra secreta y verificar si la letra existe en ella
		Mientras i<=longitud_p Hacer
			//Si letra=subcadena(pais_jugador,i,i) Entonces
				// ya dijo previamente esta letra y esta en la palabra secreta
			//	control = 1
			//	i = longitud_p // forzar salida del ciclo
			//Sino
				Si letra=subcadena(pais,i,i) Entonces
					contador_acierto = contador_acierto+1
					acumulador_aciertos = acumulador_aciertos+1
					Si acumulador_aciertos=longitud_p Entonces
						i = longitud_p+1 // forzar salida del mientras
						intentos = 0 // forzar salida de la peticion de letras
					FinSi
				FinSi
			//FinSi
			i = i+1
		FinMientras
		// si tuvo por lo menos un acierto, actualizo los aciertos del jugador
		Si contador_acierto>0 Y contador_acierto<98 Entonces // evito las repeticiones de letra con contador_acierto<98
			control = 2
			pais_jugador = pais_jugador+letra
		FinSi
		// no se dieron aciertos
		Si contador_acierto=0 Entonces
			control = 3
		FinSi
		// mensaje para el usuario
		Segun control  Hacer
			1:
				Escribir "Ya dijiste esa letra, dime otra"
				intentos = intentos+1 // no le quitamos el turno
			2:
				Escribir "Ha acertado la letra ",letra
			3:
				Escribir "Esta letra no se encuentra"
		FinSegun

		Esperar 1 Segundos
		//Esperar Tecla
		Borrar Pantalla // opcional
		// actualizacion de variables
		control = 0
		intentos = intentos-1
		// ******************
		escribir "Juego del ahorcado"
		Escribir "Adivina la palabra"
		Escribir "" // salto de linea
		Escribir "" // salto de linea
		// Dibujar el tablero inicial
		// *******************
		// mostrar las letras o los espacios
		Para j=1 Hasta longitud_p Hacer
			// reiniciada para diferenciar letras correctas de espacios en blanco
			contador_acierto = 0
			// compara una letra de la palabra secreta con todas las ingresadas por el jugador
			Para i=1 Hasta longitud(pais_jugador) Hacer
				Si subcadena(pais,j,j)=subcadena(pais_jugador,i,i) Entonces
					contador_acierto = contador_acierto+1
				FinSi
			FinPara
			// sin aciertos, muestro un espacio en blanco, de lo contrario muestro la letra
			Si contador_acierto=0 Entonces
				Escribir "_ " Sin Saltar
			Sino
				Escribir subcadena(pais,j,j) Sin Saltar
			FinSi
		FinPara
		Escribir "" // salto de linea
		Escribir "" // salto de linea
	FinMientras
	// fin del juego y resultado
	Si acumulador_aciertos=longitud_p Entonces
		Escribir "Gano"
	Sino
		Escribir "Perdio"
		Escribir "La palabra era"
		Escribir pais
	FinSi
FinAlgoritmo