inherit image_types

MIA_IMG_ROOTFS_TYPE ?= "ext3"
MIA_IMG_ROOTFS = "${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.${MIA_IMG_ROOTFS_TYPE}"
MIA_OUT_DIR = "miaimg-out"

do_image_miaimg[depends] = "\
    virtual/kernel:do_deploy \
    u-boot:do_deploy \
    "

deploy_uboot_files () {
    # Copy U-Boot files.
    if [ -n "${SPL_BINARY}" ]; then
        cp ${SPL_BINARY} ${MIA_OUT_DIR}/
        cp u-boot-${MACHINE}.${UBOOT_SUFFIX} ${MIA_OUT_DIR}/
    else
        cp u-boot-${MACHINE}.${UBOOT_SUFFIX} ${MIA_OUT_DIR}/
    fi
}

deploy_bootfs_files () {
    # Copy kernel binary.
    cp ${KERNEL_IMAGETYPE}-${MACHINE}.bin ${MIA_OUT_DIR}/uImage

    # Copy device tree files
    if test -n "${KERNEL_DEVICETREE}"; then
        for DTS_FILE in ${KERNEL_DEVICETREE}; do
            DTS_BASE_NAME=`basename ${DTS_FILE} .dtb`
            if [ -e "${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb" ]; then
                kernel_bin="`readlink ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${MACHINE}.bin`"
                kernel_bin_for_dtb="`readlink ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb | sed "s,$DTS_BASE_NAME,${MACHINE},g;s,\.dtb$,.bin,g"`"
                if [ $kernel_bin = $kernel_bin_for_dtb ]; then
                    cp ${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb ${MIA_OUT_DIR}/${DTS_BASE_NAME}.dtb
                fi
            else
                bbfatal "${DTS_FILE} does not exist."
            fi
        done
    fi
}

deploy_rootfs_files () {
    cp ${MIA_IMG_ROOTFS} ${MIA_OUT_DIR}/rootfs.${MIA_IMG_ROOTFS_TYPE}
}

IMAGE_CMD_miaimg () {
    bbwarn "Create MIA image"

    cd ${DEPLOY_DIR_IMAGE}

    rm -rf ${MIA_OUT_DIR}
    mkdir ${MIA_OUT_DIR}

    deploy_uboot_files;
    deploy_bootfs_files;
    deploy_rootfs_files;
}

# This image depends on the rootfs image.
IMAGE_TYPEDEP_miaimg += "${MIA_IMG_ROOTFS_TYPE}"