ToFDX12Switcher

@echo off

echo Tower of Fantasy DX12 Switcher
echo Run in Administrator mode!!!

:: Set TOFDIR to your ToF install folder
set TOFDIR=C:\Tower Of Fantasy

if not exist "%TOFDIR%\Hotta\Binaries\Win64\QRSL.exe" goto BADDIR

echo Install folder: %TOFDIR%

echo Commands:
echo 1 - Enable DX12
echo 2 - Revert all changes
echo Q - Quit
echo Enter command:

:REQUESTINPUT
set /p input=""

echo %input%
if "%input%" == "1" goto ENABLE
if "%input%" == "2" goto DISABLE
if "%input%" == "Q" goto :EOF

echo Invalid command. Retry:
goto REQUESTINPUT

:ENABLE
echo Enable DX12 requested.
copy /y "%TOFDIR%\Hotta\Binaries\Win64\QRSL.exe" "%TOFDIR%\Hotta\Binaries\Win64\QRSL_dx12.exe"
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\QRSL.exe" /f /v Debugger /t REG_SZ /d "%TOFDIR%\Hotta\Binaries\Win64\QRSL_dx12.exe updater -dx12 """
echo DX12 enabled. Launch game via launcher and enjoy.
pause
goto :EOF

:DISABLE
echo Revert all changes requested.
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\QRSL.exe" /f /v Debugger
del "%TOFDIR%\Hotta\Binaries\Win64\QRSL_dx12.exe"
echo Revert completed.
pause
goto :EOF

:BADDIR
echo Invalid ToF install folder, file not found: %TOFDIR%\Hotta\Binaries\Win64\QRSL.exe
echo Edit %0 file and set TOFDIR to point to a ToF install folder (e.g. C:\Tower Of Fantasy)
pause