/*
// Load this SQL script.

	ALTER TABLE `guild` ADD COLUMN `gpack` DATETIME NOT NULL DEFAULT '0000-00-00 00:00:00'  AFTER `emblem_data`;

*/

prontera,155,181,5	script	Sample	757,{
.@guild_id = getcharid(2);
if( !.@guild_id ){
	mes "You didnt have a guild.";
}else{
	query_sql( "SELECT `char_id`,`connect_member`,`gpack` FROM `guild` WHERE `guild_id` = "+.@guild_id,.@master,.@online,.@gpack$ );
	if( getcharid(0) != .@master ){
		mes "You're not guild master of this guild.";
	}else if( .@online < .min_online_member ){
		mes "You need to have minimum "+.min_online_member+" member to online before you can take this.";
	}else if( .@gpack$ != "0000-00-00 00:00:00" ){
		mes "Your Guild already claimed this since ^FF0000"+.@gpack$+"^000000";
	}else{
		mes "Do you want to claim GPack...?";
		mes "You got "+.@online+" member online.";
		mes "are you sure to claim it now ?? you can only claim once.";
		mes "^FF0000Same IP users wont be able to get rewards.^000000";
		next;
		if( select( "Yes, claim it","Close" ) == 1 ){
			query_sql( "SELECT `account_id`,`last_ip` FROM `login` WHERE `account_id` <> "+getcharid(3)+" AND `account_id` IN ( SELECT `account_id` FROM `guild_member` WHERE `guild_id` = "+.@guild_id+" AND `online` = 1 ) GROUP BY `last_ip` ORDER BY `account_id` ASC ",.@account_id,.@last_ip$ );
			.@size = getarraysize( .@account_id );
			while( .@member < .@size ){
				.@reward = 0;
				while( .@reward < .member_reward_size ){
					getitem .member_reward[.@reward],.member_reward_qty[.@reward],.@account_id[.@member];
					.@reward++;
				}
				.@member++;
			}
			.@reward = 0;
			while( .@reward < .master_reward_size ){
				getitem .master_reward[.@reward],.master_reward_qty[.@reward];
				.@reward++;
			}
			query_sql( "UPDATE `guild` SET `gpack` = NOW() WHERE `guild_id` = "+.@guild_id );
			mes "Rewards has been assigned to all users...users who didnt received the rewards are most probably having the similar IP with other users.";
			dispbottom "Member who didnt get the rewards are most probably they have similar IP with other users within the Guild.";
		}
	}
}
close;

OnInit:
// minimum member to online and get the rewards.
.min_online_member = 2;

// reward for guild master
setarray .master_reward,512,607,608;
setarray .master_reward_qty,10,20,30;

// reward for member master
setarray .member_reward,512,607,608;
setarray .member_reward_qty,1,2,3;

.master_reward_size = getarraysize( .master_reward );
.member_reward_size = getarraysize( .member_reward );
end;
}