; Nazwa: Drwal_Menu_v-2.1.txt
; Autor: Janusz [Fris]
;============ OPIS ==================
; UWAGA !!
; W przypadku innych wersji systemu niz Windows XP
; trzeba uruchamiac EasyUO jako administrator
;
; Skrypt Testowany na systemach Windows XP SP3 oraz Windows 7 SP1
;
; -------------------------------------------
; Skrypt dziala z wieloma juczniakami ale najlepiej mic max 3 bo przy wiekszej liczbie
; juczniaki nie potrafia podejsc do postaci i klody laduja w plecaku postaci.
; Skrypt rabie dowolne wybrane rodzaje drzew, sam uzywa komendy .pojemnik na pierwszej znalezionej juce
; jesli juka zostanie zapelniona ustawi pojemnik na kolejnej
; Przycisk Magazyn przezuca klody po kolei z kazdej juki do magazynu i wypisuje kwity jesli klod
; jest conajmniej 2010 sztuk wiec trzeba miec przy sobie troche zlota np. 3000
;--------------------------------------------
set %ID_Plecaka_Na_Kwity  ;ID Plecaka na kwity ohii w magazynie
;set %klody_na_raz 200  ;tu wpisz po ile klod na raz ma przezucac z juczniaka do magazynu, sprawdzic to mozna poprzez podniesienie jakiejs ilosci i sprawdzenie czy nie przekracza ona maksymalnego udzwigu wypisanego w ingo postaci
set %Skrzynia_Magazyn_X ( 623 + #CLILEFT )
set %Skrzynia_Magazyn_Y ( 348 + #CLITOP )
set %PlecakJuczniaka_X ( 73 + #CLILEFT )
set %PlecakJuczniaka_Y ( 87 + #CLITOP )
set %ZamknijPlecakJuczniaka_X %PlecakJuczniaka_X + 100
set %ZamknijPlecakJuczniaka_Y %PlecakJuczniaka_Y + 100
set %click_X_Przerwij 188
set %click_Y_Przerwij 168
set %Max_waga #maxweight - 50
set %Max_odleglosc 20
set #lpc 2000
menu clear
menu window color btnface
menu window size 220 240
menu window title Drwal 2.1
menu font size 8
;=================== odleglosc ================
menu font size 9
menu font bgcolor btnface
menu text mtomk 10 115 Max Oldeglosc:
menu edit mekopanie 120 112 30 %Max_odleglosc ; numer drzewa
;=================== przyciski =================
menu font color black
menu font style b
menu button mbwszystko 10 140 115 20 Zaznacz wszystko
menu button mbnic 135 140 75 20 Odznacz

menu button mbstart 10 165 60 24 Start
menu button mbstop 75 165 60 24 Stop
menu button mbMagazyn 140 165 70 24 Magazyn
;=================== klody ======================
menu font style
menu font size 8
menu check mcDrzewo 20 27 90 15 #false drzewo
menu check mcCedr 20 47 90 15 #false cedr
menu check mcDab 20 67 90 15 #false dab
menu check mcOrzech 20 87 90 15 #false orzech
;------------------------------------------------------
menu check mcWierzba 110 27 90 15 #false wierzba
menu check mcCyprys 110 47 90 15 #false cyprys
menu check mcCis 110 67 90 15 #false cis
menu check mcOhii 110 87 90 15 #false o'hii
;=================== info o rudach ==================
menu shape msopis_rud 8 5 205 17 3 7 1 blue 2 blue
menu text mtopis_rudy 12 7 Zaznacz drzewa do szukania:
menu shape msrudy 8 20 205 85 3 7 1 black 2 black
menu font size 9
menu text mtTytulStatus 13 193 Zajete miejsce w juce
menu shape msStatusTitle 10 193 200 15 3 7 1 blue 2 green
menu shape msStatus 10 207 200 30 3 7 1 green 2 green

menu show
;menu hideEUO
;====================================================
set #lpc 10
set #menubutton n/a
;=================== petla ===========================
repeat
  if #menubutton = CLOSED ;wcisnieto przycisk X
  {
     menu hide
     set #menubutton N/A
     halt
  }
  if #menubutton = mbMagazyn ;wcisnieto przycisk X
  {
     set #menubutton N/A
     gosub domagazynu
  }
  if #menubutton = mbstart
  {
     set %TuWcisnietoStart_X #charposx
     set %TuWcisnietoStart_Y #charposy
     set %JakisKontener #backpackid
     set #menubutton n/a
     menu delete mbstart
     menu font bgcolor btnface
     gosub menucheck

     gosub Wskaz_juczniaka
     gosub WycelujWJuke 1
     if #RESULT = WycelujWjuke
        gosub WycelujWJuke 1

     move %TuWcisnietoStart_X %TuWcisnietoStart_Y 0 20s
     gosub SkanujTeren
     gosub MainLoop
  }
  if #menubutton = mbwszystko
  {
     gosub wszystko mcDrzewo mcCedr mcDab mcOrzech mcWierzba mcCyprys mcCis mcOhii
     set #menubutton n/a
  }
  if #menubutton = mbnic
  {
     gosub nic mcDrzewo mcCedr mcDab mcOrzech mcWierzba mcCyprys mcCis mcOhii
     set #menubutton n/a
  }
until #false
;================= pola wyboru =======================
sub menucheck
  set #lpc 200
  menu get mcDrzewo
  if #menures = #true
     {
     set %mc1 drzewo
     set %JestCoWywalac 1
     }

  menu get mcCedr
  if #menures = #true
     {
     set %mc2 cedr
     set %JestCoWywalac 1
     }

  menu get mcDab
  if #menures = #true
     {
     set %mc3 dab
     set %JestCoWywalac 1
     }

  menu get mcOrzech
  if #menures = #true
     {
     set %mc4 orzech
     set %JestCoWywalac 1
     }

  menu get mcWierzba
  if #menures = #true
     {
     set %mc5 wierzba
     set %JestCoWywalac 1
     }

  menu get mcCyprys
  if #menures = #true
     {
     set %mc6 cyprys
     set %JestCoWywalac 1
     }

  menu get mcCis
  if #menures = #true
     {
     set %mc7 cis
     set %JestCoWywalac 1
     }

  menu get mcOhii
  if #menures = #true
     {
     set %mc8 o'hii
     set %JestCoWywalac 1
     }

  menu get mekopanie
  set %Max_odleglosc #menures

  set #lpc 10
return
;--------------------------------------------------------------
sub SkanujTeren
  set #lpc 4000
  event sysmessage Szukam drzew...
  tile Init
  set %x_poczatek #charposx - %Max_odleglosc
  set %y_poczatek #charposy - %Max_odleglosc
  set %x_koniec #charposx + %Max_odleglosc
  set %y_koniec #charposy + %Max_odleglosc
  set %licznik 0
  for %x %x_poczatek %x_koniec
  {
      for %y %y_poczatek %y_koniec
      {
          tile Cnt %x %y
          for %i 1 #tilecnt
          {
              tile Get %x %y %i
              if ( %mc1 in #tilename && Impassable in #tileflags ) || ( %mc2 in #tilename && Impassable in #tileflags ) || ( %mc3 in #tilename && Impassable in #tileflags ) || ( %mc4 in #tilename && Impassable in #tileflags ) || ( %mc5 in #tilename && Impassable in #tileflags ) || ( %mc6 in #tilename && Impassable in #tileflags ) || ( %mc7 in #tilename && Impassable in #tileflags ) || ( %mc8 in #tilename && Impassable in #tileflags )
              { ;ustawia tablice poletak z warzywami
                  set %licznik %licznik + 1
                  set %_x . %licznik %x ;tworzenie tablicy
                  set %_y . %licznik %y ;tworzenie tablicy
                  set %_z . %licznik #tilez ;tworzenie tablicy
                  set %_tt . %licznik #tiletype
                  break
              }
          }
      }
  }
  set #lpc 10
return
;----------------------------------------------------------------
sub MainLoop
  set #lpc 10
  event sysmessage Znaleziono %licznik drzew.
  for %j 1 %licznik
  {
      gosub Podejdz_do_drzewa %_x . %j %_y . %j %_z . %j
      gosub Scinaj_drzewo %_x . %j %_y . %j %_z . %j %_tt . %j %j
      if #RESULT = PetlaPrzyciskow
      {
         break
      }
  }
  event sysmessage KONIEC RABANIA.
  gosub ZerujTablice
  gosub Rysuj_przycisk_start
return
;--------------------------------------------------
sub Podejdz_do_drzewa
  set %krzaczek_x %1
  set %krzaczek_y %2
  set %krzaczek_z %3
  set #lpc 200
  move %krzaczek_x %krzaczek_y 1 5s
  gosub CzyJestemNaPozycji
  if #RESULT <> NaMiejscu
  {
      set %czas #scnt2 + 20
      event pathfind %krzaczek_x %krzaczek_y %krzaczek_z
      repeat
          if %czas < #scnt2
          {
              gosub CzyJestemNaPozycji
              if #RESULT = NaMiejscu
              {
                 set #lpc 10
                 return
              }
              else
              {
                 set %czas #scnt2 + 20
                 event pathfind %krzaczek_x %krzaczek_y %krzaczek_z
              }
          }
          scanjournal 1
          if _*sapie* in #journal || _*trzeszczy* in #journal
          {
             wait 2s
             event macro 1 0 odpocznijcie
             wait 8s
             event macro 1 0 Za mna
          }
          if Can't_get_there in #journal || stoisz_za_daleko in #journal || _That_is_too in #journal
          {
              gosub CzyJestemNaPozycji
              if #RESULT = NaMiejscu
              {
                 set #lpc 10
                 return
              }
              else
              {
                 move %krzaczek_x %krzaczek_y 1 5s
              }
          }

      until #false
  }
set #lpc 10
return
;--------------------------------------------------
sub CzyJestemNaPozycji
  if %krzaczek_x > #CHARPOSX && %krzaczek_y = #CHARPOSY ;drzewo na wschod
  {
     set %Cel_x %krzaczek_x - 1
     set %Cel_y %krzaczek_y
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x > #CHARPOSX && %krzaczek_y < #CHARPOSY ;drzewo na polnocny wschod
  {
     set %Cel_x %krzaczek_x - 1
     set %Cel_y %krzaczek_y + 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x > #CHARPOSX && %krzaczek_y > #CHARPOSY ;drzewo na poludniowy wschod
  {
     set %Cel_x %krzaczek_x - 1
     set %Cel_y %krzaczek_y - 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x = #CHARPOSX && %krzaczek_y > #CHARPOSY ;drzewo poludnie
  {
     set %Cel_x %krzaczek_x
     set %Cel_y %krzaczek_y - 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x < #CHARPOSX && %krzaczek_y > #CHARPOSY ;drzewo poludniowy zachod
  {
     set %Cel_x %krzaczek_x + 1
     set %Cel_y %krzaczek_y - 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x < #CHARPOSX && %krzaczek_y = #CHARPOSY ;drzewo na zachod
  {
     set %Cel_x %krzaczek_x + 1
     set %Cel_y %krzaczek_y
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x < #CHARPOSX && %krzaczek_y < #CHARPOSY ;drzewo na zachodni polnoc
  {
     set %Cel_x %krzaczek_x + 1
     set %Cel_y %krzaczek_y + 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x = #CHARPOSX && %krzaczek_y < #CHARPOSY ;drzewo na polnoc
  {
     set %Cel_x %krzaczek_x
     set %Cel_y %krzaczek_y + 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
return
;--------------------------------------------------
sub Wskaz_juczniaka
  ;pause
  event macro 1 0 Podejdzcie tu
  event sysmessage Szukam juczniakow.
  wait 1s
  finditem wn_bo_yab G_2 ;szuka juczniakow na ziemi
  wait 2
  if #findkind <> -1
  {
      for #findindex 1 #findcnt
      {
         ;finditem wn_bo_yab G_2
         set %Id_juczniaka . #findindex #findid
         ignoreitem #findid
      }
      set %Cnt_juczniak #findcnt
      ignoreitem reset
  }
  event sysmessage Ilosc juk: %Cnt_juczniak
return
;----------------------------------------------------------
sub UstawPojemnik
  event macro 1 0 .pojemnik
  repeat
  until #contsize = 250_180
  click 128 225 mc
  event macro 22
  wait 2
  if #targcurs = 1
  {
     event macro 22
  }
  set %Timer #scnt2 + 20
  repeat
     if %Timer < #scnt2
     {
        key Esc
        return GoToUstawPojemnik
     }
  until #targcurs = 0
return
;--------------------------------------------------------
sub WycelujWJuke
  set #lpc 10
  set %KtoraJuka %1
  finditem %Id_juczniaka . %KtoraJuka G_2
  wait 2
  if #findkind = -1
  {
      event macro 1 0 Podejdzcie tu
      wait 3s
      return WycelujWjuke
  }
  set #LTARGETID #findid
  set #LTARGETX #findx
  set #LTARGETY #findy
  set #LTARGETZ #findz
  set #LTARGETKIND 1
  gosub UstawPojemnik
  set %OstatniaJukaNr %KtoraJuka
return
;--------------------------------------------------
sub UzyjNarzedzia
  ignoreitem reset
  finditem fsf C_ , #charid
  wait 2
  if #findkind = -1
  {
     finditem fsf C_ , #backpackid
     wait 2
     if #findkind <> -1
     {
        set #lobjectid #findid
        event macro 17
        return ToporWplecaku
     }
     else
     {
        return NieMaTopora
     }
  }
  set #lobjectid #findid
  event macro 17 0
  wait 2
  if #targcurs = 0
  {
     set #lobjectid #findid
     event macro 17 0
  }
  set %TimeCelownik #scnt2 + 20
  repeat
      if %TimeCelownik < #scnt2
      {
         set %TimeCelownik #scnt2 + 20
         set #lobjectid #findid
         event macro 17 0
      }
  until #targcurs = 1
return
;--------------------------------------------------
sub Scinaj_drzewo
  set %iteracja %5
  if #RESULT = NieMaTopora
  {
    menu hide
    set #sysmsgcol 1080
    event sysmessage Nie znaleziono Topora.
    halt
  }
  if #RESULT = ToporWplecaku
  {
     gosub UzyjNarzedzia
  }
  ; sprawdza czy juczniaki sa blisko postaci
  for %k 1 %Cnt_juczniak
  {
      finditem %Id_juczniaka . %k G_2
      wait 2
      if #findkind = -1
      {
         for %n 1 3
         {
             event macro 1 0 podejdzcie
             wait 2s
             scanjournal 1
             if _*sapie* in #journal || _*trzeszczy* in #journal
             {
                 event macro 1 0 odpocznijcie
                 wait 8s
                 event macro 1 0 za mna
                 event macro 1 0 podejdzcie
                 wait 2s
             }
             finditem %Id_juczniaka . %k G_2
             wait 2
             if #findkind <> -1
             {
                break
             }
             if #findkind = -1 && %n = 3
             {
                event sysmessage Nie widze juczniaka.
                return PetlaPrzyciskow
             }
             if #findkind = -1 && %n < 3
             {
                event macro 1 0 podejdzcie
                wait 2s
             }
         }
      }
  }
  event sysmessage Drzewo nr. %iteracja
  gosub UzyjNarzedzia
  set #LTARGETX %_x . %iteracja
  set #LTARGETY %_y . %iteracja
  set #ltargetz %_z . %iteracja
  set #ltargettile %_tt . %iteracja
  set #ltargetkind 3
  set #sysmsgcol 75
  event macro 22
  set #lpc 1000
  repeat
      if *STOP = 1
      {
          click 187 165
          wait 6s
          set *WAIT 0
          repeat
          until *STOP = 0
          break
      }
      if Jesiania_nie_zetniesz_tego_drzewa. in #journal
      {
          display ok JEST JESIEN I NIE DA SIE SCINAC OHII
          gosub Rysuj_przycisk_start
          return PetlaPrzyciskow
      }
      if #menubutton = mbstop ;wcisnieto przycisk X
      {
          set %psx 188
          set %psy 165
          click %psx %psy
          set #menubutton N/A
          gosub Rysuj_przycisk_start
          return PetlaPrzyciskow
      }
      scanjournal 1
      if Nie_masz_juz_miejsca_w_plecaku. in #journal
      {
         gosub ZapelnienieJuki
         if %Cnt_juczniak = 1
         {
            event sysmessage Juczniak pelny. Koniec scinania.
            gosub Rysuj_przycisk_start
            return PetlaPrzyciskow
         }
         set %NrJuki %OstatniaJukaNr + 1
         if %NrJuki > %Cnt_juczniak
         {
            set #sysmsgcol 1080
            event sysmessage Wszystkie juki zapelnione.
            return PetlaPrzyciskow
         }
         gosub WycelujWJuke %NrJuki
         break
      }
      if #weight > %Max_waga
      {
         click 187 165
         event sysmessage Za duzo wazysz. Skrypt zatrzymany.
         gosub Rysuj_przycisk_start
         return PetlaPrzyciskow
      }
  until To_drzewo_wyglada_juz_na_wystarczajaco_obciete. in #journal
  set #lpc 10
  gosub ZapelnienieJuki
return
;--------------------------------------------------
sub ZapelnienieJuki
  set %JakisGump #contid
  set %ToCzyjasJuka 0
  finditem %Id_juczniaka1 G_2
  if #findkind = -1
  {
     return
  }
  set #lobjectid %Id_juczniaka1
  event macro 17
  set %CasPlecJuki #scnt2 + 10
  set %CzyjasJuka #scnt2 + 50
  repeat
      if %CasPlecJuki < #scnt2
      {
          set #lobjectid %Id_juczniaka1
          event macro 17
          set %CasPlecJuki #scnt2 + 10
      }
      if %CzyjasJuka < #scnt2
      {
         set %ToCzyjasJuka 1
         break
      }
  until %JakisGump notin #contid
  wait 5
  set %waga 0
  finditem zlk C_ , #contid
  if #findkind <> -1
  {
     for #findindex 1 #findcnt
     {
        if #findtype = zlk
        {
           set %waga ( %waga + #findstack )
        }
     }
     event sysmessage waga %waga
     menu font style bold
     menu text mtStatus 15 213 %waga z 2000
  }

return
;--------------------------------------------------
sub domagazynu   ;otwiera magazyn
  finditem pof C
  wait 2
  if #findstack < 30
  {
     event sysmessage Masz za malo zlota na wypisywanie kwitow
     event macro 1 0 Stop!!
     return
  }
  repeat
      finditem * G_5  ;szuka wszystkiego
      wait 2
      event Property #findid
      ignoreitem #findid
  until Magazynier in #property
  ignoreitem reset
  move #findx #findy 1 30s
  event macro 1 0 Podejdzcie.
  wait 5

  set #NEXTCPOSX %Skrzynia_Magazyn_X
  set #NEXTCPOSY %Skrzynia_Magazyn_Y
  event macro 1 0 Magazynier otworz skrzynie
  repeat
     wait 5
  until #CONTSIZE = 180_240
  set %SkrzyniaMagazyn #CONTID
  wait 3
  contpos %Skrzynia_Magazyn_X %Skrzynia_Magazyn_Y
  if N/A in %Id_juczniaka1
  {
     gosub Wskaz_juczniaka
  }
  set %JakisGump #contid
  set %ToCzyjasJuka 0
  for %m 1 %Cnt_juczniak
  {
      finditem %Id_juczniaka . %m G_2
      wait 2
      if #findkind = -1
      {
         event sysmessage Nie widze juczniaka.
         return
      }
      set #lobjectid %Id_juczniaka . %m
      event macro 17
      set %CasPlecJuki #scnt2 + 10
      set %CzyjasJuka #scnt2 + 50
      repeat
          if %CasPlecJuki < #scnt2
          {
              set #lobjectid %Id_juczniaka . %m
              event macro 17
              set %CasPlecJuki #scnt2 + 10
          }
          if %CzyjasJuka < #scnt2
          {
             set %ToCzyjasJuka 1
             break
          }
      until %JakisGump notin #contid
      if %ToCzyjasJuka = 1
      {
         set %ToCzyjasJuka 0
         continue
      }
      set %PlecakJuczniaka #contid
      contpos %PlecakJuczniaka_X %PlecakJuczniaka_Y
      event sysmessage Przeliczam klody w juczniaku
      gosub PrzeliczSztaby juka
      wait 3
      event sysmessage Przeliczam klody w magazynie
      gosub PrzeliczSztaby magazyn
      set #lpc 100
      for %a 1 8
      {
          set %SztabyNazwaJuka %RudaNazwaJuka_ . %a
          set %SztabyIloscJuka %RudaIloscJuka_ . %a
          set %SztabyNazwaMagazyn %RudaNazwaMagazyn_ . %a
          set %SztabyIloscMagazyn %RudaIloscMagazyn_ . %a
          if %SztabyNazwaJuka = %SztabyNazwaMagazyn
          {
             set %SumaSztab ( %SztabyIloscJuka + %SztabyIloscMagazyn )
             ;event sysmessage SumaSztab %SumaSztab
             if %SumaSztab > 2000
             {
                set %DoUzupelnienia ( 2010 - %SztabyIloscMagazyn )
                event sysmessage Uzupelniam klody do 2000 sztuk.
                gosub PrzeniesPrzedmiot %RudaIdJuka_ . %a %DoUzupelnienia %SkrzyniaMagazyn
                ;wait 1s
                event sysmessage Wypisuje kwit.
                gosub Sztaby_do_kwitow
             }
             scanjournal 1
             if _too_heavy in #journal
             {
                finditem zlk C_ , #backpackid
                wait 2
                for #findindex 1 #findcnt
                {
                    gosub PrzeniesPrzedmiot #findid #findstack %PlecakJuczniaka
                }
             }
          }
      }
      ignoreitem reset
      event sysmessage Przenosze reszte sztab do magazynu.
      finditem zlk C_ , %PlecakJuczniaka
      wait 2
      for #findindex 1 #findcnt
      {
         gosub PrzeniesPrzedmiot #findid #findstack %SkrzyniaMagazyn
         scanjournal 1
         if _too_heavy in #journal
         {
            finditem zlk C_ , #backpackid
            wait 2
            for #findindex 1 #findcnt
            {
                gosub PrzeniesPrzedmiot #findid #findstack %PlecakJuczniaka
            }
            event sysmessage Magazyn pelny.
            gosub Sztaby_do_kwitow
         }
      }
      finditem EAG_RZF C_ , %PlecakJuczniaka
      wait 2
      for #findindex 1 #findcnt
         {
         gosub PrzeniesPrzedmiot #findid #findstack #backpackid
         }
      click %ZamknijPlecakJuczniaka_X %ZamknijPlecakJuczniaka_Y r
      wait 3
      set %JakisGump #contid
  }
  gosub Sztaby_do_kwitow
  gosub PrzenoszenieKwitow
  event sysmessage Klody przezucone.
return
;--------------------------------------------------------
sub Sztaby_do_kwitow
  ;--- tworzenie wiazki 2000 sztab
  finditem ZLK C_ , %SkrzyniaMagazyn
  wait 2
  set %StartX_kupki 0
  set %StartY_kupki 150
  set %X_kupki %StartX_kupki + 10
  set %Y_kupki 150
  for #findindex 1 #findcnt
    {
    if #findstack > 2000
       {
       set %Wielokrotnosc2k ( #findstack / 2000 )
       event sysmessage Kupek po 2k: %Wielokrotnosc2k
       set %ID_starej_kupki #findid
       for %c 1 %Wielokrotnosc2k
         {
         set %X_kupki %X_kupki + 20
         ;event sysmessage Pozycja sztabek: %X_kupki %Y_kupki
         exevent drag #findid 2000
         wait 5
         if dwj in #findtype
            exevent dropc %SkrzyniaMagazyn 200 150
         else
            exevent dropc %SkrzyniaMagazyn %X_kupki %Y_kupki
         wait 5
         finditem enk_dwj C_ , %SkrzyniaMagazyn
         wait 2
         }
       }
    ;ignoreitem #findid
    }
;---- wypisywanie kwitu
  wait 5
  ;pause
  ignoreitem reset
  finditem ZLK C_ , %SkrzyniaMagazyn
  wait 2
  for #findindex 1 #findcnt
  {
      if #findstack = 2000
      {
         event macro 1 0 wypisz kwit
         set %CzasKwitu #scnt2 + 30
         repeat
             if %CzasKwitu < #scnt2
             {
                 event macro 1 0 wypisz kwit
                 set %CzasKwitu #scnt2 + 30
             }
         until #targcurs = 1
         set #ltargetid #findid
         set #ltargetx #findx
         set #ltargety #findy
         set #ltargetkind 1
         event macro 22
         wait 15
         event macro 1 0 tak
         wait 1s
         ignoreitem #findid
         continue
      }
  }
return
;---------------------------------------------
sub PrzenoszenieKwitow
;---- przenoszenie kwitu
  finditem %ID_Plecaka_Na_Kwity C_ , %SkrzyniaMagazyn
  wait 2
  if #findkind = -1
  {
      set %ID_Plecaka_Na_Kwity %SkrzyniaMagazyn
  }
  else
  {
      set #lobjectid %ID_Plecaka_Na_Kwity
      event macro 17
  }
  finditem TVH C_ , #backpackid
  wait 2
  for #findindex 1 #findcnt
  {
      exevent drag #findid 1
      wait 5
      exevent dropc %ID_Plecaka_Na_Kwity
      wait 5
      continue
  }
return
;---------------------------------------------
sub PrzeliczSztaby
  set #lpc 2000
  set %NazwyRud_1 klody
  set %NazwyRud_2 cedr
  set %NazwyRud_3 dab
  set %NazwyRud_4 orzech
  set %NazwyRud_5 wierzba
  set %NazwyRud_6 cyprys
  set %NazwyRud_7 cis
  set %NazwyRud_8 o'hii
  if juka in %1
  {
     finditem zlk C_ , %PlecakJuczniaka
     wait 2
  }
  if magazyn in %1
  {
     finditem zlk C_ , %SkrzyniaMagazyn
     wait 2
  }
  for #findindex 1 #findcnt
      {
      event Property #findid
      wait 2
      for %i 1 8
      {
          set %RudaRodzaj %NazwyRud_ . %i
          if %RudaRodzaj in #property
          {
             if juka in %1
             {
                set %RudaNazwaJuka_ . %i %RudaRodzaj
                set %RudaIloscJuka_ . %i #findstack
                set %RudaIdJuka_ . %i #findid
                ;event sysmessage N: %RudaNazwaJuka_ . %i Cnt: %RudaIloscJuka_ . %i
             }
             if magazyn in %1
             {
                set %RudaNazwaMagazyn_ . %i %RudaRodzaj
                set %RudaIloscMagazyn_ . %i #findstack
                ;event sysmessage N: %RudaNazwaMagazyn_ . %i Cnt: %RudaIloscMagazyn_ . %i
             }
          }
      }
  }
  set #lpc 10
return
;---------------------------------------------
sub PrzeniesPrzedmiot ;( ID przedmiotu, ilosc, gdzie przezucic )
  exevent drag %1 %2
  wait 5
  exevent dropc %3
  wait 5
return
;--------------------------------------------------
sub Rysuj_przycisk_start
  set #menubutton N/A
  menu font color black
  menu font style b
  menu font bgcolor btnface
  menu button mbstart 10 165 60 24 Start
return
;--------------------------------------------------
sub ZerujTablice
  set #lpc 4000
  for %j 1 %licznik
  {
      set %_x . %j
      set %_y . %j
      set %_z . %j
      set %_tt . %j
  }
  set #lpc 10
return
;-----------------------------------------------
sub wszystko
  #lpc 100
  for %i 1 %0
  {
      menu Set % . %i #true
  }
return
;-----------------------------------------------
sub nic
  #lpc 100
  for %i 1 %0
  {
      menu Set % . %i #false
  }
return