eclipse-scala-ide 4.7.0-1

#Maintainer: Andrzej Giniewicz <gginiu@gmail.com>
#Contributor: Kristof Jozsa <kjozsa@fsdev.hu>

pkgname=eclipse-scala-ide
pkgver=4.7.0
pkgrel=1
pkgdesc="Scala IDE for Eclipse"
arch=('any')
url="http://www.scala-ide.org/"
license=('custom')
depends=('eclipse>=4.7')

source=($pkgname-$pkgver.zip::"http://download.scala-ide.org/sdk/lithium/e47/scala212/stable/update-site.zip"
        "LICENSE" "scala-ide.desktop" "product.png"
)
sha512sums=('331b35466574423c8bf2ca2accd71e95b3b66548911a6d2b258df278a605dcee30638fe36a1969a8f2dd9a2453c51b2f1255f63cd399f81067458c58a1d31f6c'
            '8fc7bc4f43590d477955dc2334a9489d8825b4d363d1b09f987aa93626a8ee58ec48072e1378b776937867553bc9d4aff18652d605518532efe43a8e12757a71'
            '33ef15cbb30e868f2e1560da3ce3e1dae0e4944d6a21fb22a8827d500e3540b82ace19fd7e1629a6fe338eab47cf7f1f249ab5dfd0fd7e413f5249d7929fbb6d'
            '7e3e8c874cd57f0413a84c9bfe6beff18aa442a4a74f4be0ef5d223407ddd12408f97b329a8e2ed9acad3867bfbea6c878d5d4dc3fb3592f3b05819e346e8544')

package() {
  install -D -m0644 "${srcdir}"/LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -D -m0644 "${srcdir}"/scala-ide.desktop "${pkgdir}/usr/share/applications/scala-ide.desktop"
  install -D -m0644 "${srcdir}"/product.png "${pkgdir}/usr/lib/eclipse/dropins/scala-ide/icon.png"

  _dest="${pkgdir}/usr/lib/eclipse/dropins/${pkgname/eclipse-}/eclipse"
  cd "${srcdir}/base"

  # Features
  find features -type f | while read -r _feature ; do
    if [[ "${_feature}" =~ (.*\.jar$) ]] ; then
      install -dm755 "${_dest}/${_feature%*.jar}"
      cd "${_dest}/${_feature/.jar}"
      # extract features (otherwise they are not visible in about dialog)
      jar xf "${srcdir}/base/${_feature}" || return 1
    else
      install -Dm644 "${_feature}" "${_dest}/${_feature}"
    fi
  done

  # Plugins
  find plugins -type f | while read -r _plugin ; do
    install -Dm644 "${_plugin}" "${_dest}/${_plugin}"
  done
}