REM x16emu -bas MIMIC.BAS
REM Change line 30 to use better graphics.
REM Change line 62 decrease the timeout.
REM Press the randomly selected key: D F J K
REM before time runs out.
REM Score is how many times you get it right.
REM The variable TI updates once per 'jiffy' (1/60 second)
20 DIM P(4)
21 LET P(0)=ASC("D")
22 LET P(1)=ASC("F")
23 LET P(2)=ASC("J")
24 LET P(3)=ASC("K")
30 T$="!!!!":F$="...."
40 POKE 646,1
50 R$=CHR$(28)+T$+CHR$(30)+F$+CHR$(154)+F$+CHR$(158)+F$+CHR$(5)
51 G$=CHR$(28)+F$+CHR$(30)+T$+CHR$(154)+F$+CHR$(158)+F$+CHR$(5)
52 B$=CHR$(28)+F$+CHR$(30)+F$+CHR$(154)+T$+CHR$(158)+F$+CHR$(5)
53 Y$=CHR$(28)+F$+CHR$(30)+F$+CHR$(154)+F$+CHR$(158)+T$+CHR$(5)
55 SC=-1
60 U = INT(RND(1)*4):SC=SC+1
61 PRINTCHR$(147)
62 Z=TI+60
64 PRINT":D  :F  :J  :K",SC
70 IF U < 1 THEN PRINT R$:GOTO 80
71 IF U < 2 THEN PRINT G$:GOTO 80
72 IF U < 3 THEN PRINT B$:GOTO 80
73 IF U < 4 THEN PRINT Y$:GOTO 80
80 IF TI>Z THEN 110
90 GET A$:IF A$="" THEN 80
100 IF P(U)=ASC(A$) THEN 60
102 PRINT:PRINT:PRINT"SORRY."
103 GOTO 120
110 PRINT:PRINT:PRINT"TOO SLOW."
115 GOTO 125
120 PRINT"SHOULD HAVE PICKED ";CHR$(P(U))
125 PRINT
130 PRINT"YOUR SCORE:", SC