擬似フルスクリーン関数 / Pseudo Full Screen Function

; ============================
; Pseudo Full Screen Function
; ============================

F1::PseudoFullScreen(1) ; Show Taskbar
F2::PseudoFullScreen(0) ; Hide Taskbar
F3::PseudoFullScreen() ; Restore
Esc::ExitApp

PseudoFullScreen(Mode=-1, WinTitle="A") {
    static 0:=OnExit("PseudoFullScreen"), ID, Style, X, Y, W, H, MinMax
    if (WinExist(WinTitle) || WinTitle = 0) {
        if (ID)
            ID := RestorePFS(ID, Style, X, Y, W, H, MinMax)
        if (Mode < 0 || WinTitle = 0)
            return
        else if (Mode) {
            WinGetPos, Task_X, Task_Y, Task_W, Task_H, ahk_class Shell_TrayWnd
            if (Task_X != Task_Y) ; Bottom/Right
                Task_X := Task_Y := 0
            else if (Task_X = 0 && Task_Y = 0 && Task_W > Task_H) ; Up
                Task_X := 0, Task_Y := Task_H
            else if (Task_X = 0 && Task_Y = 0 && Task_W < Task_H) ; Left
                Task_X := Task_W, Task_Y := 0
            (Task_W > Task_H) ? Task_W := 0 : Task_H := 0 ; Length/Width
        } else
            Task_X := Task_Y := Task_W := Task_H := 0
        SysGet, SM_CXSIZEFRAME, 32
        SysGet, SM_CYSIZEFRAME, 33
        WinGet, ID, ID
        WinGet, MinMax, MinMax
        WinGet, WS_CAPTION, Style
        if (Style := WS_CAPTION & 0xC00000)
            WinSet, Style, -0xC00000
        WinRestore
        WinGetPos, X, Y, W, H
        WinMove,,, Task_X-SM_CXSIZEFRAME, Task_Y-SM_CYSIZEFRAME, A_ScreenWidth+SM_CXSIZEFRAME*2-Task_W, A_ScreenHeight+SM_CYSIZEFRAME*2-Task_H
    }
}

RestorePFS(ID, Style, X, Y, W, H, MinMax) {
    if WinExist("ahk_id" ID) {
        if (Style)
            WinSet, Style, +0xC00000
        WinMove,,, X, Y, W, H
        if (MinMax = 1)
            WinMaximize
        else if (MinMax = -1)
            WinMinimize
        return 0
    }
    return 1
}