Fallout 4: Scavver mod menu

Scriptname ScavverMessageScript extends ObjectReference
{ It just works. }

; SCAVVER MOD BY @THORALDGM | [email protected] | SCRIPT UPDATED 20160711

; -----------------------------------------------------------------------------
; PROPERTIES
; -----------------------------------------------------------------------------

ObjectReference Property pScavver Auto Const Mandatory

GlobalVariable Property pgvScavverAddsPerks Auto Mandatory
GlobalVariable Property pgvScavverBeardTime Auto Mandatory
GlobalVariable Property pgvScavverHasMapMarker Auto Mandatory
GlobalVariable Property pgvScavverNoteRead Auto Mandatory
GlobalVariable Property pgvScavverStatusSniffer Auto Mandatory

Message Property pScavverBeardMessage Auto Const Mandatory
Message Property pScavverBookMessage Auto Const Mandatory
Message Property pScavverDevMessage Auto Const Mandatory
Message Property pScavverStatMessage Auto Const Mandatory
Message Property pScavverTheftMessage Auto Const Mandatory

Quest Property pScavverQuest Auto Const Mandatory

; -----------------------------------------------------------------------------
; EVENT: ON ACTIVATE
; -----------------------------------------------------------------------------

Event OnActivate(ObjectReference akActionRef)
	int ButtonPressed  ; Do not show menu until quest has been started

	If pgvScavverNoteRead.GetValue() == 0      ; If note has never been read
		pgvScavverNoteRead.SetValue(1)         ; Mark note as read
		pScavverQuest.Start()                  ; Start quest (default is stage 10, NO marker)
	EndIf

	ButtonPressed = pScavverBookMessage.Show() ; Now show the menu

	If ButtonPressed == 0
		If pgvScavverHasMapMarker.GetValue() == 0
			Debug.Notification("SCAVVER: MAP MARKER ON")
			pgvScavverHasMapMarker.SetValue(1)
			pScavverQuest.SetStage(11)   ; Stage 11 is Find the Scavver WITH marker
			pScavverQuest.SetActive()    ; Make the quest marker active
		Else
			Debug.Notification("Scavver marker is already shown.")
		EndIf
	ElseIf ButtonPressed == 1
		If pgvScavverHasMapMarker.GetValue() == 1
			pScavverQuest.SetStage(10)        ; Stage 10 is Find the Scavver WITHOUT marker
			pScavverQuest.SetActive(false)    ; Make the quest marker inactive
			pgvScavverHasMapMarker.SetValue(0)
			Debug.Notification("SCAVVER: MAP MARKER OFF")
		Else
			Debug.Notification("Scavver marker is already hidden.")
		EndIf
	ElseIf ButtonPressed == 2
		If pgvScavverStatusSniffer.GetValue() == 0
			ButtonPressed = pScavverDevMessage.Show()

			If ButtonPressed == 0
				Debug.Notification("SCAVVER: DEV NOTIFICATIONS ON")
				pgvScavverStatusSniffer.SetValue(1)
			EndIf
		Else
			Debug.Notification("Scavver dev mode is already on.")
		EndIf
	ElseIf ButtonPressed == 3
		If pgvScavverStatusSniffer.GetValue() == 1
			pgvScavverStatusSniffer.SetValue(0)
			Debug.Notification("SCAVVER: DEV NOTIFICATIONS OFF")
		Else
			Debug.Notification("Scavver dev mode is already off.")
		EndIf
	ElseIf ButtonPressed == 4
		ButtonPressed = pScavverStatMessage.Show()
	ElseIf ButtonPressed == 5
		If pgvScavverAddsPerks.GetValue() == 1
			Debug.Notification("SCAVVER: REWARD PERKS OFF")
			pgvScavverAddsPerks.SetValue(0)
		Else
			Debug.Notification("Scavver reward perks are already off.")
		EndIf
	ElseIf ButtonPressed == 6
		If pgvScavverAddsPerks.GetValue() == 0
			pgvScavverAddsPerks.SetValue(1)
			Debug.Notification("SCAVVER: REWARD PERKS ON")
		Else
			Debug.Notification("Scavver reward perks are already on.")
		EndIf
	ElseIf ButtonPressed == 7
		ButtonPressed = pScavverTheftMessage.Show()

		If ButtonPressed == 0
			pScavver.RemoveAllItems(Game.GetPlayer())
		EndIf
	ElseIf ButtonPressed == 8
		String BeardMsg = "Scavver beard rate: updated."
		ButtonPressed = pScavverBeardMessage.Show()

		If ButtonPressed == 0
			pgvScavverBeardTime.SetValue(30240)
			BeardMsg = "Scavver beard rate: Game Week."                ; 8.4 hours
		ElseIf ButtonPressed == 1
			pgvScavverBeardTime.SetValue(4320)
			BeardMsg = "Scavver beard rate: Game Day."                 ; 1.2 hours
		Else
			; Not a button, do nothing
		EndIf

		Debug.Notification(BeardMsg)
	ElseIf ButtonPressed == 9
		; Exit menu
	EndIf
EndEvent