Test AW functionality

////Imports
import mods.artisanworktables.builder.RecipeBuilder;

////Variables
val ironChestPlate = <minecraft:iron_chestplate>;
val ironChestPlateBasicLight = <minecraft:iron_chestplate>.withTag({AttributeModifiers: [{Slot:"chest",AttributeName:"generic.movementSpeed",Name:"generic.movementSpeed",Amount:0.2,Operation:1,UUIDLeast:1,UUIDMost:1}, {Slot:"chest",AttributeName:"generic.armor",Name:"generic.armor",Amount:5,Operation:0,UUIDLeast:10,UUIDMost:10}], display:{Name:"Light Iron Chestplate"}});
val ironChestPlateBasicSteadfast = <minecraft:iron_chestplate>.withTag({AttributeModifiers: [{Slot:"chest",AttributeName:"generic.knockbackResistance",Name:"generic.knockbackResistance",Amount:0.2,Operation:0,UUIDLeast:2,UUIDMost:2}, {Slot:"chest",AttributeName:"generic.armor",Name:"generic.armor",Amount:6,Operation:0,UUIDLeast:20,UUIDMost:20}], display:{Name:"Steadfast Iron Chestplate"}});
val ironChestPlateEnhanced = <minecraft:iron_chestplate>.withTag({AttributeModifiers: [{Slot:"chest",AttributeName:"generic.maxHealth",Name:"generic.maxHealth",Amount:5,Operation:0,UUIDLeast:100,UUIDMost:100}, {Slot:"chest",AttributeName:"generic.armor",Name:"generic.armor",Amount:6,Operation:0,UUIDLeast:30,UUIDMost:30}], display:{Name:"Enhanced Iron Chestplate"}});
val ironChestPlateEnhancedLight = <minecraft:iron_chestplate>.withTag({AttributeModifiers: [{Slot:"chest",AttributeName:"generic.maxHealth",Name:"generic.maxHealth",Amount:5,Operation:0,UUIDLeast:110,UUIDMost:110}, {Slot:"chest",AttributeName:"generic.movementSpeed",Name:"generic.movementSpeed",Amount:0.2,Operation:1,UUIDLeast:111,UUIDMost:111}, {Slot:"chest",AttributeName:"generic.armor",Name:"generic.armor",Amount:5,Operation:0,UUIDLeast:40,UUIDMost:40}], display:{Name:"Light Enhanced Iron Chestplate"}});
val ironChestPlateEnhancedSteadfast = <minecraft:iron_chestplate>.withTag({AttributeModifiers: [{Slot:"chest",AttributeName:"generic.maxHealth",Name:"generic.maxHealth",Amount:5,Operation:0,UUIDLeast:120,UUIDMost:120}, {Slot:"chest",AttributeName:"generic.knockbackResistance",Name:"generic.knockbackResistance",Amount:0.2,Operation:0,UUIDLeast:121,UUIDMost:121}, {Slot:"chest",AttributeName:"generic.armor",Name:"generic.armor",Amount:6,Operation:0,UUIDLeast:50,UUIDMost:50}], display:{Name:"Steadfast Enhanced Iron Chestplate"}});
val bsHammer = <ore:artisansHammer>;
val ingotIron = <ore:ingotIron>;
val plateIron = <ore:plateIron>;



//remove initially
recipes.remove(ironChestPlate);


//Basic chestplate
RecipeBuilder.get("blacksmith")
    .setShaped([[ingotIron, null, ingotIron], [ingotIron, ingotIron, ingotIron], [ingotIron, ingotIron, ingotIron]])
    .setTool(bsHammer, 2)
    .addOutput(ironChestPlate)
    .requireGameStages("ANY", ["diagramIronChestBasic"])
    .excludeGameStages(["metalSkillBasic"])
    .create();
//Basic chestplate +1
RecipeBuilder.get("blacksmith")
    .setShaped([[ingotIron, null, ingotIron], [ingotIron, ingotIron, ingotIron], [ingotIron, ingotIron, ingotIron]])
    .setTool(bsHammer, 2)
    .addOutput(ironChestPlate, 60)
    .addOutput(ironChestPlateBasicLight, 20)
    .addOutput(ironChestPlateBasicSteadfast, 20)
    .requireGameStages("ALL", ["diagramIronChestBasic", "metalSkillBasic"])
    .create();

//Enhanced chestplate
RecipeBuilder.get("blacksmith")
    .setShaped([[ingotIron, null, ingotIron], [plateIron, ingotIron, plateIron], [ingotIron, ingotIron, ingotIron]])
    .setTool(bsHammer, 3)
    .addOutput(ironChestPlateEnhanced)
    .requireGameStages("ANY", ["diagramIronChestAdvanced"])
    .excludeGameStages(["metalSkillBasic"])
    .create();
//Enhanced chestplate +1
RecipeBuilder.get("blacksmith")
    .setShaped([[ingotIron, null, ingotIron], [plateIron, ingotIron, plateIron], [ingotIron, ingotIron, ingotIron]])
    .setTool(bsHammer, 3)
    .addOutput(ironChestPlateEnhanced, 60)
    .addOutput(ironChestPlateEnhancedLight, 20)
    .addOutput(ironChestPlateEnhancedSteadfast, 20)
    .requireGameStages("ALL", ["diagramIronChestAdvanced", "metalSkillBasic"])
    .create();