///////////////////////////////////////////////////////////////////////////////////////////////////////
//////////////////// B U L L S E Y E | W O R K S //////////////////////////////////////////////////////
////////////////////     Created by: Unknown     //////////////////////////////////////////////////////
////////////////////      Modified by: BullsEyE  //////////////////////////////////////////////////////
////////////////////         Date:04-23-18       //////////////////////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////////////////////////////

0 spawn {

    kk_fnc_getZoom = {
        (
            [0.5,0.5]
            distance
            worldToScreen
            positionCameraToWorld
            [0,1.05,1]
        ) * (
            getResolution
            select
            5
        )
    };

    while {true} do
    {
        waitUntil {currentVisionMode player == 1};

        // Dynamic Blur
        private _ppBlur = ppEffectCreate ["dynamicBlur", 190];
        _ppBlur ppEffectForceInNVG true;

        // Edge Blur
        private _ppRim = ppEffectCreate ["RadialBlur", 451];
        _ppRim ppEffectAdjust [0.015, 0.015, 0.22, 0.3];
        _ppRim ppEffectForceInNVG true;

        // Color and Contrast
        private _ppColor = ppEffectCreate ["ColorCorrections", 2003];
        _ppColor ppEffectAdjust [1, 1, -0.02, [0.0, 0.0, 0.0, 0.0], [1.3, 1.2, 0.0, 0.9], [6, 1, 1, 0.0]];
        _ppColor ppEffectForceInNVG true;

        // Film Grain
        private _ppFilm = ppEffectCreate ["FilmGrain", 2501];
        _ppFilm ppEffectForceInNVG true;

        [_ppBlur, _ppRim, _ppColor, _ppFilm] ppEffectEnable true;
        [_ppRim, _ppColor] ppEffectCommit 0;

        waitUntil {
            private _zoomintensity = (call kk_fnc_getZoom * 10) / 30;
            _ppBlur ppEffectAdjust [0.20 + (_zoomIntensity * 0.30)];
            _ppFilm ppEffectAdjust [0.20, 1, _zoomIntensity, 0.4, 0.2, false];
            [_ppBlur, _ppFilm] ppEffectCommit 0;
            (currentVisionMode player != 1)
        };

        ppEffectDestroy [_ppBlur, _ppRim, _ppColor, _ppFilm];
    };
};