Example-OscarCtrl

#include <GUIConstantsEx.au3>
#include 'OscarGraphics.au3'

Opt('GUIOnEventMode', 1)

Global $oCtrl = _OscarCtrl()   ; erstellt ein Objekt mit den Create- u. SetData-Methoden aller 3 Ctrl
Global $hGui


_Batterie()
Sleep(750)

_Bulb()
Sleep(750)

_Traffic()
Exit

;===================================================================================== Batterie ====
Func _Batterie()
    Local $iLeft = 200, $iTop = 30, $iPercent = 0
    $hGui = GUICreate('_GUICtrlBatterieLevel', 300, 180)
    GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
    Local $idBatterieLevel = $oCtrl.BatterieLevel_Create($iLeft, $iTop, $iPercent)
    Local $idBatterieLevel2 = $oCtrl.BatterieLevel_Create(30, $iTop, $iPercent)
    GUISetState(@SW_SHOW, $hGui)
    Sleep(1000)
    $oCtrl.BatterieLevel_SetData($idBatterieLevel2, 33)
    For $iPercent = 1 To 100
        $oCtrl.BatterieLevel_SetData($idBatterieLevel, $iPercent)
        Sleep(20)
    Next
    $oCtrl.BatterieLevel_SetData($idBatterieLevel2, 66)
    For $iPercent = 100 To 25 Step -1
        $oCtrl.BatterieLevel_SetData($idBatterieLevel, $iPercent)
        Sleep(50)
    Next
    $oCtrl.BatterieLevel_SetData($idBatterieLevel2, 100)
    Sleep(1000)
    $oCtrl.BatterieLevel_SetData($idBatterieLevel, 50)
    Sleep(1000)
    $oCtrl.BatterieLevel_SetData($idBatterieLevel, 75)
    WinWaitClose($hGui)
EndFunc

;========================================================================================= Bulb ====
Func _Bulb()
    Local $iLeft = 30, $iTop = 30
    $hGui = GUICreate('_GUICtrlLightBulb', 300, 180)
    GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
    Local $idLightBulb1 = $oCtrl.LightBulb_Create($iLeft, $iTop, $LB_OFF)
    Local $idLightBulb2 = $oCtrl.LightBulb_Create($iLeft + 150, $iTop, $LB_OFF)
    GUISetState(@SW_SHOW, $hGui)
    Sleep(500)
    $oCtrl.LightBulb_SetData($idLightBulb1, $LB_ON)
    Sleep(500)
    $oCtrl.LightBulb_SetData($idLightBulb1, $LB_OFF)
    For $i = 0 To 9
        $oCtrl.LightBulb_SetData($idLightBulb2, Mod($i,2))
        Sleep(500)
    Next
    WinWaitClose($hGui)
EndFunc

;====================================================================================== Traffic ====
Func _Traffic()
    Local $iLeft = 30, $iTop = 30
    $hGui = GUICreate('_GUICtrlTrafficLight', 300, 180)
    GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
    Local $idTrafficLight1 = $oCtrl.TrafficLight_Create($iLeft, $iTop, $TL_OFF)
    Local $idTrafficLight2 = $oCtrl.TrafficLight_Create($iLeft + 130, $iTop, $TL_OFF)
    GUISetState(@SW_SHOW, $hGui)

    Local Const $iBlinkTime = 500
    Local Const $iPhaseTime = 2000
    Local Const $iWaitRedTime = 1000
    Local Const $iGreenTime = 8000
    For $i = 0 To 4
        $oCtrl.TrafficLight_SetData($idTrafficLight1, $TL_YELLOW) ; Ampel-1 gelb
        $oCtrl.TrafficLight_SetData($idTrafficLight2, $TL_YELLOW) ; Ampel-2 gelb
        Sleep($iBlinkTime)
        $oCtrl.TrafficLight_SetData($idTrafficLight1, $TL_OFF) ; Ampel-1 aus
        $oCtrl.TrafficLight_SetData($idTrafficLight2, $TL_OFF) ; Ampel-2 aus
        Sleep($iBlinkTime)
    Next
    $oCtrl.TrafficLight_SetData($idTrafficLight1, $TL_GREEN) ; Ampel-1 grün
    $oCtrl.TrafficLight_SetData($idTrafficLight2, $TL_RED) ; Ampel-2 rot
    Sleep($iGreenTime)
    Do
        $oCtrl.TrafficLight_SetData($idTrafficLight1, $TL_YELLOW) ; Ampel-1 gelb
        Sleep($iPhaseTime)
        $oCtrl.TrafficLight_SetData($idTrafficLight1, $TL_RED) ; Ampel-1 rot
        Sleep($iWaitRedTime)
        $oCtrl.TrafficLight_SetData($idTrafficLight2, $TL_YELLOWRED) ; Ampel-2 gelb/rot
        Sleep($iPhaseTime)
        $oCtrl.TrafficLight_SetData($idTrafficLight2, $TL_GREEN) ; Ampel-2 grün
        Sleep($iGreenTime)
        $oCtrl.TrafficLight_SetData($idTrafficLight2, $TL_YELLOW) ; Ampel-2 gelb
        Sleep($iPhaseTime)
        $oCtrl.TrafficLight_SetData($idTrafficLight2, $TL_RED) ; Ampel-2 rot
        Sleep($iWaitRedTime)
        $oCtrl.TrafficLight_SetData($idTrafficLight1, $TL_YELLOWRED) ; Ampel-1 gelb/rot
        Sleep($iPhaseTime)
        $oCtrl.TrafficLight_SetData($idTrafficLight1, $TL_GREEN) ; Ampel-1 grün
        Sleep($iGreenTime)
    Until Not BitAND(WinGetState($hGui), 2)
EndFunc

Func _CloseGui()
    GUIDelete($hGui)
EndFunc