prontera,147,238,5	script	頭飾存放倉庫	10013,{
	mes "["+strnpcinfo(1)+"]";
	mes "您可以將特定的頭飾放入典藏倉庫";
	mes "將可以獲得額外的能力加成";
	mes "相同的頭飾無法重複放入";
	mes "取出時仍保有精煉度及卡片相關素質";
	next;
	switch(select("存入頭飾:取出頭飾"))
	{
		case 1:
			mes "["+strnpcinfo(1)+"]";
			mes "請選擇您要放入的頭飾";
			next;
			for (.@i = 1; .@i < getarraysize(.EquipPosEN); .@i++)
				.@MenuPos$ = .@MenuPos$+"- "+sprintf("%-8s",F_getpositionname(.EquipPosEN[.@i]))+" "+((getequipisequiped(.EquipPosEN[.@i]))?"^0000FF"+getequipname(.EquipPosEN[.@i])+"^000000":"^656565無裝備^000000")+":";
			.@j = select(.@MenuPos$);
			if (getequipid(.EquipPosEN[.@j]) == -1)
			{
				mes "["+strnpcinfo(1)+"]";
				mes "您沒有穿戴裝備。";
				close;;
			}
			.@nameid = getequipid(.EquipPosEN[.@j]);
			.@refine_cnt = getequiprefinerycnt(.EquipPosEN[.@j]);
			.@card0 = getequipcardid(.EquipPosEN[.@j],6);
			.@card1 = getequipcardid(.EquipPosEN[.@j],7);
			.@card2 = getequipcardid(.EquipPosEN[.@j],8);
			.@card3 = getequipcardid(.EquipPosEN[.@j],9);
			for(.@i=0; .@i<5; .@i++)
			{
				.@OptID[.@i] = getequiprandomoption(.EquipPosEN[.@j],.@i,ROA_ID);
				.@OptVal[.@i] =getequiprandomoption(.EquipPosEN[.@j],.@i,ROA_VALUE);
				.@OptParam[.@i] = getequiprandomoption(.EquipPosEN[.@j],.@i,ROA_PARAM);
			}
			query_sql("SELECT `nameid` FROM `head_storage` WHERE `char_id` = '"+getcharid(0)+"'",.@check_id);
			.@index = inarray(.@check_id, .@nameid);
			if(.@index > -1)
			{
				mes "["+strnpcinfo(1)+"]";
				mes "這項裝備已在倉庫中。";
				close;
			}
			delequip .EquipPosEN[.@j];
			query_sql "INSERT INTO `head_storage` ( `char_id`, `nameid`, `refine`, `card0`, `card1`, `card2`, `card3`, `OptID1`, `OptVal1`, `OptParam1`, `OptID2`, `OptVal2`, `OptParam2`, `OptID3`, `OptVal3`, `OptParam3`, `OptID4`, `OptVal4`, `OptParam4`, `OptID5`, `OptVal5`, `OptParam5` ) VALUES ( '"+getcharid(0)+"', '"+.@nameid+"' , '"+.@refine_cnt+"' , '"+.@card0+"' , '"+.@card1+"' , '"+.@card2+"' , '"+.@card3+"' , '"+.@OptID[0]+"' , '"+.@OptVal[0]+"', '"+.@OptParam[0]+"', '"+.@OptID[1]+"' , '"+.@OptVal[1]+"', '"+.@OptParam[1]+"', '"+.@OptID[2]+"' , '"+.@OptVal[2]+"', '"+.@OptParam[2]+"', '"+.@OptID[3]+"' , '"+.@OptVal[3]+"', '"+.@OptParam[3]+"', '"+.@OptID[4]+"' , '"+.@OptVal[4]+"', '"+.@OptParam[4]+"' )";
			dispbottom "[頭飾倉庫] 已存入"+getitemname(.@nameid),0x00ffff;
			break;

		case 2:
			mes "["+strnpcinfo(1)+"]";
			mes "請選擇您要取出的頭飾";
			next;
			query_sql("SELECT `nameid`, `refine`, `card0`, `card1`, `card2`, `card3`, `OptID1`, `OptVal1`, `OptParam1`, `OptID2`, `OptVal2`, `OptParam2`, `OptID3`, `OptVal3`, `OptParam3`, `OptID4`, `OptVal4`, `OptParam4`, `OptID5`, `OptVal5`, `OptParam5` FROM `head_storage` WHERE `char_id` = '"+getcharid(0)+"'",.@nameid, .@refine_cnt, .@card0, .@card1, .@card2, .@card3, .@OptID1, .@OptVal1, .@OptParam1, .@OptID2, .@OptVal2, .@OptParam2, .@OptID3, .@OptVal3, .@OptParam3, .@OptID4, .@OptVal4, .@OptParam4, .@OptID5, .@OptVal5, .@OptParam5);
			for( .@i = 0; .@i < getarraysize(.@nameid); .@i++ )
				.@menu$ = .@menu$ + (getitemname(.@nameid[.@i]))+":";
			.@j = select(.@menu$)-1;
			setarray .@OPT_ID[0], .@OptID1[.@j], .@OptID2[.@j], .@OptID3[.@j], .@OptID4[.@j], .@OptID5[.@j];
			setarray .@OPT_VALUE[0], .@OptVal1[.@j], .@OptVal2[.@j], .@OptVal3[.@j], .@OptVal4[.@j], .@OptVal5[.@j];
			setarray .@OPT_PARAM[0], .@OptParam1[.@j], .@OptParam2[.@j], .@OptParam3[.@j], .@OptParam4[.@j], .@OptParam5[.@j];
			getitem3 .@nameid[.@j], 1, 1, .@refine_cnt[.@j], 0, .@card0[.@j], .@card1[.@j], .@card2[.@j], .@card3[.@j], .@OPT_ID, .@OPT_VALUE, .@OPT_PARAM;
			query_sql("DELETE FROM `head_storage` WHERE `char_id` = '"+getcharid(0)+"' AND `nameid` = '"+.@nameid[.@j]+"'");
			dispbottom "[頭飾倉庫] 已取出"+getitemname(.@nameid),0x00ffff;
			break;
	}
	doevent strnpcinfo(0)+"::OnReCalc";
	recalculatestat;
	end;
OnInit:
	setarray .EquipPosEN[1],EQI_HEAD_TOP,EQI_HEAD_MID,EQI_HEAD_LOW,EQI_COSTUME_HEAD_TOP,EQI_COSTUME_HEAD_MID,EQI_COSTUME_HEAD_LOW;
	query_sql("CREATE TABLE IF NOT EXISTS `head_storage` (`char_id` INT(11) NOT NULL, `nameid` INT(11) NOT NULL, `refine` INT(11) NOT NULL,`card0` INT(11) NOT NULL,`card1` INT(11) NOT NULL,`card2` INT(11) NOT NULL,`card3` INT(11) NOT NULL,`OptID1` INT(11) NOT NULL,`OptVal1` INT(11) NOT NULL,`OptParam1` INT(11) NOT NULL,`OptID2` INT(11) NOT NULL,`OptVal2` INT(11) NOT NULL,`OptParam2` INT(11) NOT NULL,`OptID3` INT(11) NOT NULL,`OptVal3` INT(11) NOT NULL,`OptParam3` INT(11) NOT NULL,`OptID4` INT(11) NOT NULL,`OptVal4` INT(11) NOT NULL,`OptParam4` INT(11) NOT NULL,`OptID5` INT(11) NOT NULL,`OptVal5` INT(11) NOT NULL,`OptParam5` INT(11) NOT NULL);");
	debugmes "頭飾存放資料庫安裝完成！";
	end;

OnPCLoginEvent:
	deletearray .@EQI_HEAD_TOP;
	query_sql("SELECT `nameid` FROM `head_storage` WHERE `char_id` = '"+getcharid(0)+"'", .@EQI_HEAD_TOP);
	end;

OnPCStatCalcEvent:
	for( .@i = 0; .@i < getarraysize(.@EQI_HEAD_TOP); .@i++ )
	{
		switch(.@EQI_HEAD_TOP[.@i])
		{
			case 2221:	bonus bDex,100;	break;
			case 2285:	bonus bStr,100;	break;
			case 2286:	bonus bAgi,100;	break;
		}
	}
	end;
}