frame += 1;

buffer_clear(global.sendBuffer);

acceptJoiningPlayer();
with(JoiningPlayer)
    serviceJoiningPlayer();

// Service all players
var i;
for(i=0; i<ds_list_size(global.players); i+=1)
{
    var player;
    player = ds_list_find_value(global.players, i);

    if(socket_has_error(player.socket))
    {
        removePlayer(player);
        ServerPlayerLeave(i);
        i-=1;
    }
    else
    {
        if(player.authorized == false)
        {
            player.passwordCount += 1;
            if(player.passwordCount == 30*30)
            {
                write_ubyte(player.socket, KICK);
                write_ubyte(player.socket, KICK_PASSWORDCOUNT);
                socket_destroy(player.socket);
                player.socket = -1;
            }
        }
        processClientCommands(player, i);
    }
}

if((frame mod 7) == 0)
    serializeState(QUICK_UPDATE, global.sendBuffer);
else
    serializeState(INPUTSTATE, global.sendBuffer);

var i;
for(i=1; i<ds_list_size(global.players); i+=1)
{
    var player;
    player = ds_list_find_value(global.players, i);
    write_buffer(player.socket, global.eventBuffer);
    write_buffer(player.socket, global.sendBuffer);
    socket_send(player.socket);
}
buffer_clear(global.eventBuffer);