ocsP5 server

import oscP5.*;
import netP5.*;

PGraphics canvas;
OscP5 oscP5;
NetAddressList myNetAddressList = new NetAddressList();
int myListeningPort = 25565;
int myBroadcastPort = 12000;

String myConnectPattern = "/server/connect";
String myLinePattern = "/server/line";

void setup() {
  size(300, 400);
  oscP5 = new OscP5(this, myListeningPort);
  frameRate(25);

  canvas = createGraphics(width, height, JAVA2D);
  canvas.beginDraw();
  canvas.background(255);
  canvas.endDraw();
  canvas.rectMode(CENTER);
}

void draw() {
  canvas.loadPixels();
  loadPixels();
  for (int i = 0; i < pixels.length; i++) {
    pixels[i] = canvas.pixels[i];
  }
  updatePixels();
  canvas.updatePixels();
}

void oscEvent(OscMessage theOscMessage) {
  if (theOscMessage.addrPattern().equals(myConnectPattern)) {
    connect(theOscMessage.netAddress().address());
    OscMessage m = new OscMessage(myConnectPattern,new Object[0]);
    oscP5.send(m, myNetAddressList);
  } else {
    oscP5.send(theOscMessage, myNetAddressList);
  }
  display(theOscMessage);
}

void mouseDragged() {
  OscMessage m = new OscMessage(myLinePattern,new Object[0]);
  m.add(pmouseX);
  m.add(pmouseY);
  m.add(mouseX);
  m.add(mouseY);
  oscP5.send(m, myNetAddressList);
  display(m);
}

void display(OscMessage theOscMessage) {
  if (theOscMessage.addrPattern().equals(myLinePattern)) {
    int x1 = theOscMessage.get(0).intValue();
    int y1 = theOscMessage.get(1).intValue();
    int x2 = theOscMessage.get(2).intValue();
    int y2 = theOscMessage.get(3).intValue();
    canvas.beginDraw();
    canvas.stroke(0);
    canvas.strokeWeight(1);
    canvas.line(x1, y1, x2, y2);
    canvas.endDraw();
  }
}

 private void connect(String theIPaddress) {
     if (!myNetAddressList.contains(theIPaddress, myBroadcastPort)) {
       myNetAddressList.add(new NetAddress(theIPaddress, myBroadcastPort));
       println("### adding "+theIPaddress+" to the list.");
     } else {
       println("### "+theIPaddress+" is already connected.");
     }
     println("### currently there are "+myNetAddressList.list().size()+" remote locations connected.");
 }



private void disconnect(String theIPaddress) {
if (myNetAddressList.contains(theIPaddress, myBroadcastPort)) {
    myNetAddressList.remove(theIPaddress, myBroadcastPort);
       println("### removing "+theIPaddress+" from the list.");
     } else {
       println("### "+theIPaddress+" is not connected.");
     }
       println("### currently there are "+myNetAddressList.list().size());
 }