deployboy>bigpy

list pieces=[];
list places=[];
list ranchans=[];
integer ncline;
key ncQryKey;

deployall(){
    integer i;
    string name;
    integer listlen = llGetListLength(pieces);
    vector pos;    rotation rot;
    for(i=0;i<listlen;i++){
        name=llList2String(pieces,i);
        rot=ZERO_ROTATION;
        if(name=="bpy.holodoor")
            rot=llEuler2Rot(<0,-50,90>*DEG_TO_RAD);
        llRezObject(name,llGetPos(),ZERO_VECTOR,rot,llList2Integer(ranchans,i));
    }
    for(i=0;i<listlen;i++){
        pos=llGetPos()+(vector)llList2String(places,i);
        llSay(llList2Integer(ranchans,i),(string)pos);
    }
    llSleep(0.5);
    llShout(4321,"go");
    llSleep(0.85);
    llShout(-33314444,"o");
    llSleep(0.5);
    llShout(-1555,"go");
}

default{
    on_rez(integer p){
        if(p==0)
            llSetPos(llGetPos()-<0,0,0.1>);
    }
    state_entry(){
        llListen(0,"",llGetOwner(),"");
        ncline=0;
        ncQryKey=llGetNotecardLine("deploydata",ncline);
    }
    touch_start(integer num){
        if(llDetectedKey(0)==llGetOwner()){
            llRegionSay(-998889,"x");
            llSetAlpha(0,-1);
            deployall();
        }
    }
    listen(integer chan,string who,key id,string msg){
        if(msg=="packup"){
            llRegionSay(-998889,"x");
            llSetAlpha(1,-1);
        }
    }
    dataserver(key qry_id, string in){
        list cmdpair=[];
        if(ncQryKey == qry_id){
            if(in!=EOF){
                cmdpair=llParseString2List(in,["#"],[]);
                pieces+=llList2String(cmdpair,0);
                places+=llList2String(cmdpair,1);
                ranchans+=(integer)llFrand(-40000)-40000;
                ncline++;
                ncQryKey=llGetNotecardLine("deploydata",ncline);
            }
        }
    }
}