_pkgname=lmms
pkgname=lmms-qt5-git
pkgver=1.2.0.rc5.r27.g926b6542a
pkgrel=1
pkgdesc='The Linux MultiMedia Studio (Qt5 Version).'
arch=('x86_64')
url='http://lmms.io'
license=('GPL')
depends=('sdl' 'glib2' 'fluidsynth' 'libpng' 'libvorbis' 'libxft' 'qt5-base' 'qt5-x11extras' 'libxinerama' 'sdl_sound' 'libsamplerate' 'shared-mime-info' 'fltk')
optdepends=('wine: Windows VST support (experimental)'
            'fftw: SpectrumAnalyzer plugin'
            'jack: Optional JACK audio backend'
            'portaudio: Optional Portaudio audio backend'
            'sdl_sound: Optional SDL audio backend'
            'pulseaudio: Optional PulseAudio backend'
            'oss: Optional OSS backend'
            'libsoundio: For soundio support'
            'lame: For exporting MP3 format')
makedepends=('qt5-tools' 'git' 'cmake' 'ninja' 'ladspa' 'raptor' 'rasqal' 'libxft' 'freetype2' 'redland' 'gcc-multilib' 'lame' 'perl-list-moreutils')
provides=('lmms' 'lmms-extras')
conflicts=('lmms' 'lmms-extras')
options=('!makeflags')
source=('git://github.com/LMMS/lmms.git')
sha512sums=('SKIP')

pkgver() {
  cd -- "$srcdir/$_pkgname"
  git describe --long --tags | sed -r 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}

prepare() {
  cd -- "$srcdir/$_pkgname"
  git submodule update --init --recursive
  git shortlog -nse | cut -f 2- > doc/CONTRIBUTORS
}

build() {
cd -- "$srcdir/$_pkgname"
cmake -DCMAKE_INSTALL_PREFIX=/usr -USE=vst -DWANT_QT5=ON
make -j$(nproc)
}

package() {
  cd "$srcdir/lmms"
  make DESTDIR="${pkgdir}" install


  # Temporary packaging fixes:

  # Delete optional weakjack.so
  cd "${pkgdir}"
  find . -maxdepth 1 -type d -not -name . -not -name usr -exec rm -r {} \;

  # Move lib64 files to lib
  cd "${pkgdir}/usr"
  mv lib64/* lib/
  rm -r lib64/
}