PKGBUILD Quadra

# Maintainer:  TDY <[email protected]>
# Contributor: Christoph Zeiler <rabyte_gmail>

pkgname=quadra
pkgver=1.2.0
pkgrel=1
pkgdesc="A single/multiplayer action puzzle game reminiscent of Tetris"
arch=('i686' 'x86_64')
url="http://quadra.googlecode.com/"
license=('LGPL')
depends=('gcc-libs' 'libpng' 'libxpm' 'libxxf86vm')
makedepends=('bc')
source=(http://$pkgname.googlecode.com/files/$pkgname-$pkgver.tar.gz
    configure.patch
    desktop.patch)
md5sums=('df179970c4eb75af9ccdc5527d901fa6'
         '3ceb422223db6775060e80c8e77869e5'
         '54841131c0ed173a422aee07fb3fe62f')

prepare(){
  cd ${srcdir}/$pkgname-$pkgver

  patch -Np0 -i ../../configure.patch
  patch -Np0 -i ../../desktop.patch
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure --prefix=/usr --disable-version-check
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm644 Quadra.desktop "$pkgdir/usr/share/applications/$pkgname.desktop"
}

# vim:set ts=2 sw=2 et: