Fischsystem

:?:/hp::
{
    SendChat("/cooked")

    Sleep, 250

    fishNumber := 5
    totalHP := 0

    Loop, 5 {
        GetChatLine(fishNumber, fish)

        RegExMatch(fish, "\*\* \(1\) Hergestellt: gekochten (.+) \((\d+) LBS\)", fish_)

        HP := Floor(fish_2 / 3)
        totalHP += HP

        message%A_Index% := PREFIX . fish_1 . " (" . fish_2 . " LBS) - {FF0000}" . HP . " HP"

        fishNumber -= 1
    }

    Loop, 5 {
        AddChatMessage(message%A_Index%)
    }

    AddChatMessage(PREFIX . "-----------------------------------------------")
    AddChatMessage(PREFIX . "Gesamt: {FF0000}" . totalHP . " HP")
}
return

:?:/fische::
{
    SendChat("/fishes")

    Sleep, 250

    fishNumber := 5
    fishMoney := 0
    totalHP := 0

    Loop, 5 {
        GetChatLine(fishNumber, fish)

        RegExMatch(fish, "\*\* \((\d)\) Fisch: (.+) \((\d+) LBS\)", fish_)

        fishValue := getFishValue(fish_2, fish_3)
        fishMoney += fishValue

        HP := Floor(fish_3 / 3)
        totalHP += HP

        message%A_Index% := PREFIX . fish_2 . " (" . fish_3 . " LBS) - {FF0000}" . fishValue . "$ {FFFFFF}- {FF0000}" . HP . " HP"

        fishNumber -= 1
    }

    Loop, 5 {
        AddChatMessage(message%A_Index%)
    }

    AddChatMessage(PREFIX . "-----------------------------------------------")
    AddChatMessage(PREFIX . "Gesamt: {FF0000}" . FormatNumber(fishMoney) . "$ {FFFFFF}- {FF0000}" . totalHP . " HP")
}
return

:?:/afish::
{
    fishNumber := 0
    fishMoney := 0
    cheapestFish := -1
    cheapestFishName := ""
    cheapestFishValue := 100000
    thrownAway := false

    Loop {
        SendChat("/fish")

        Sleep, 200

        GetChatLine(0, fishing)

        if (RegExMatch(fishing, "Du hast ein\/e (.+) mit (\d+) LBS gefangen.", fishing_)) {
            fishNumber++
            fishValue := getFishValue(fishing_1, fishing_2)

            AddChatMessage(PREFIX . "Fisch Nr. " . fishNumber . ": {FF0000}" . fishing_1 . "{FFFFFF} mit {FF0000}" . fishing_2 . " LBS{FFFFFF} - Wert: {FF0000}" . FormatNumber(fishValue) . "$")

            fishMoney += fishValue

            if (cheapestFishValue > fishValue) {
                cheapestFish := fishNumber
                cheapestFishName := fishing_1
                cheapestFishValue := fishValue
            }
        } else if (RegExMatch(fishing, "Du kannst nur 5 Fische bei dir tragen.")) {
            if (thrownAway)
                break

            fishMoney -= cheapestFishValue

            SendChat("/releasefish " . cheapestFish)
            AddChatMessage(PREFIX . "Fisch Nr. " . cheapestFish . ": {FF0000}" . cheapestFishName . "{FFFFFF} mit dem Wert: {FF0000}" . cheapestFishValue . "$ {FFFFFF}wurde weggeworfen!")

            thrownAway := true
        } else if (RegExMatch(fishing, "Du bist an keinem Angelplatz (Big Wheel Rods) oder an einem Fischerboot!")) {
            AddChatMessage(PREFIX . "Du kannst hier nicht angeln!")
            break
        } else if (RegExMatch(fishing, "Du kannst momentan nicht Angeln. Bitte warte einige Minuten.")) {
            if (fishMoney > 0){
                AddChatMessage(PREFIX . "Gesamtwert: {FF0000}" . fishMoney . "$")

                SetTimer, FishTimer, 1140000
                break
            } else {
                AddChatMessage(PREFIX . "Du kannst noch nicht angeln!")
                break
            }
        }

        Sleep, 1000
    }
}
return

:?:/asell::
{
    if (IsPlayerInRangeOfPoint(2.3247, -28.8923, 1003.5494, 10)) {
        AddChatMessage(PREFIX . "Deine Fische werden nun verkauft!")

        fishMoney := 0

        Loop, 5 {
            SendChat("/sell fish " . A_Index)

            Sleep, 200

            GetChatLine(0, chat)

            if (RegExMatch(chat, "Du hast deinen (.*) \((\d*) LBS\) für (\d*)\$ verkauft.", chat_)) {
                fishMoney += chat_3
            }

            Sleep, 1000
        }

        AddChatMessage(PREFIX . "Verdienst: {FF0000}" . FormatNumber(fishMoney) . "$")
    } else{
        AddChatMessage(PREFIX . "Du kannst deine Fische hier nicht verkaufen!")
    }
}
return

:?:/acook::
{
    Loop, 5 {
        SendChat("/cook fish " . A_Index)
        Sleep, 1000
    }
}
return

getFishValue(fishName, fishWeight){
    if (fishName == "Delphin") {
        value := fishWeight * 7
    } else if (fishName == "Makrele") {
        value := fishWeight * 8
    } else if (fishName == "Segelfisch") {
        value := fishWeight * 7
    } else if (fishName == "Bernfisch") {
        value := fishWeight * 1
    } else if (fishName == "Hai") {
        value := fishWeight * 7
    } else if (fishName == "Schwertfisch") {
        value := fishWeight * 3
    } else if (fishName == "Schildkröte") {
        value := fishWeight * 10
    } else if (fishName == "Thunfisch") {
        value := fishWeight * 12
    } else if (fishName == "Hecht") {
        value := fishWeight * 9
    } else if (fishName == "Aal") {
        value := fishWeight * 9
    } else if (fishName == "Forelle") {
        value := fishWeight * 5
    } else if (fishName == "Wolfbarsch") {
        value := fishWeight * 12
    } else if (fishName == "Zackenbarsch") {
        value := fishWeight * 3
    } else if (fishName == "Katzenfisch") {
        value := fishWeight * 4
    } else if (fishName == "Blauer Fächerfisch") {
        value := fishWeight * 2
    } else if (fishName == "Roter Schnapper") {
        value := fishWeight * 3
    } else {
        value := 0
    }

    return value
}

FishTimer:
{
    AddChatMessage(PREFIX . "Du kannst nun wieder zum Angeln gehen!")
    SetTimer, FishTimer, Off
}
return