begin ab01gutDismountScript
; this is meant to be called as player->startscript ab01gutDismountScript
float x1
float x2
if ( MenuMode )
   return
endif
if ( ScriptRunning ab01gutExitDialogueScript )
   return
endif
while ( GetItemCount "ab01reequipGreaves" > 0 )
   RemoveItem ab01reequipGreaves 1
endwhile
while ( GetItemCount "ab01guRidingClothArg" > 0 )
   RemoveItem ab01guRidingClothArg 1
endwhile
while ( GetItemCount "ab01guRidingClothKha" > 0 )
   RemoveItem ab01guRidingClothKha 1
endwhile
while ( GetItemCount "ab01guRidingCloth" > 0 )
   RemoveItem ab01guRidingCloth 1
endwhile
while ( GetItemCount "ab01guRidingFeet" > 0 )
   RemoveItem ab01guRidingFeet 1
endwhile
;ab01gutMountScript should have set x1 to armor weight class of player boots before mounting  (-1=None; 0=Light; 1=Medium; 2=Heavy)
;ab01gutMountScript should have set x2 to armor weight class of player greaves before mounting   (-1=None; 0=Light; 1=Medium; 2=Heavy)
if ( x1 == 0 )
   if ( GetItemCount "boots of blinding speed[unique]" > 0 )
      startscript ab01gutReequipBBSScript
   elseif ( GetItemCount "glass_boots" > 0 )
      equip glass_boots
   elseif ( GetItemCount "heavy_leather_boots" > 0 )
      equip heavy_leather_boots
   elseif ( GetItemCount "chitin boots" > 0 )
      equip "chitin boots"
   elseif ( GetItemCount "netch_leather_boots" > 0 )
      equip netch_leather_boots
   elseif ( GetItemCount "fur_boots" > 0 )
      equip fur_boots
   endif
elseif ( x1 == 1 )
   if ( GetItemCount "indoril boots" > 0 )
      equip "indoril boots"
   elseif ( GetItemCount "orcish_boots" > 0 )
      equip orcish_boots
   elseif ( GetItemCount "bonemold_boots" > 0 )
      equip bonemold_boots
   endif
elseif ( x1 == 2 )
   if ( GetItemCount "daedric_boots" > 0 )
      equip daedric_boots
   elseif ( GetItemCount "ebony_boots" > 0 )
      equip ebony_boots
   elseif ( GetItemCount "dwemer_boots" > 0 )
      equip dwemer_boots
   elseif ( GetItemCount "templar boots" > 0 )
      equip "templar boots"
   elseif ( GetItemCount "imperial boots" > 0 )
      equip "imperial boots"
   elseif ( GetItemCount "steel_boots" > 0 )
      equip steel_boots
   elseif ( GetItemCount "iron boots" > 0 )
      equip "iron boots"
   endif
endif
if ( x1 == -1 )
   if ( GetRace "Argonian" )
   elseif ( GetRace "Khajiit" )
   else
      if ( GetItemCount "exquisite_shoes_01" > 0 )
         equip exquisite_shoes_01
      elseif ( GetItemCount "extravagant_shoes_02" > 0 )
         equip extravagant_shoes_02
      elseif ( GetItemCount "extravagant_shoes_01" > 0 )
         equip extravagant_shoes_01
      elseif ( GetItemCount "expensive_shoes_03" > 0 )
         equip expensive_shoes_03
      elseif ( GetItemCount "expensive_shoes_02" > 0 )
         equip expensive_shoes_02
      elseif ( GetItemCount "expensive_shoes_01" > 0 )
         equip expensive_shoes_01
      elseif ( GetItemCount "common_shoes_05" > 0 )
         equip common_shoes_05
      elseif ( GetItemCount "common_shoes_04" > 0 )
         equip common_shoes_04
      elseif ( GetItemCount "common_shoes_03" > 0 )
         equip common_shoes_03
      elseif ( GetItemCount "common_shoes_02" > 0 )
         equip common_shoes_02
      elseif ( GetItemCount "common_shoes_01" > 0 )
         equip common_shoes_01
      endif
   endif
endif
if ( x2 == 0 )
   if ( GetItemCount "glass_greaves" > 0 )
      equip glass_greaves
   elseif ( GetItemCount "BM_wolf_greaves_snow" > 0 )
      equip BM_wolf_greaves_snow
   elseif ( GetItemCount "BM wolf greaves" > 0 )
      equip "BM wolf greaves"
   elseif ( GetItemCount "DarkBrotherhood greaves" > 0 )
      equip "DarkBrotherhood greaves"
   elseif ( GetItemCount "chitin greaves" > 0 )
      equip "chitin greaves"
   elseif ( GetItemCount "netch_leather_greaves" > 0 )
      equip netch_leather_greaves
   elseif ( GetItemCount "fur_greaves" > 0 )
      equip fur_greaves
   endif
elseif ( x2 == 1 )
   if ( GetItemCount "adamantium_greaves" > 0 )
      equip adamantium_greaves
   elseif ( GetItemCount "Helsethguard_greaves" > 0 )
      equip Helsethguard_greaves
   elseif ( GetItemCount "BM_bear_greaves_snow" > 0 )
      equip BM_bear_greaves_snow
   elseif ( GetItemCount "orcish_greaves" > 0 )
      equip orcish_greaves
   elseif ( GetItemCount "BM_Ice_greaves" > 0 )
      equip BM_Ice_greaves
   elseif ( GetItemCount "BM bear greaves" > 0 )
      equip "BM bear greaves"
   elseif ( GetItemCount "bonemold_greaves" > 0 )
      equip bonemold_greaves
   elseif ( GetItemCount "imperial_chain_greaves" > 0 )
      equip imperial_chain_greaves
   endif
elseif ( x2 == 2 )
   if ( GetItemCount "daedric_greaves_htab" > 0 )
      equip daedric_greaves_htab
   elseif ( GetItemCount "daedric_greaves" > 0 )
      equip daedric_greaves
   elseif ( GetItemCount "Indoril_MH_Guard_Greaves" > 0 )
      equip Indoril_MH_Guard_Greaves
   elseif ( GetItemCount "Indoril_Almalexia_Greaves" > 0 )
      equip Indoril_Almalexia_Greaves
   elseif ( GetItemCount "ebony_greaves" > 0 )
      equip ebony_greaves
   elseif ( GetItemCount "BM_NordicMail_greaves" > 0 )
      equip BM_NordicMail_greaves
   elseif ( GetItemCount "dwemer_greaves" > 0 )
      equip dwemer_greaves
   elseif ( GetItemCount "templar_greaves" > 0 )
      equip "templar_greaves"
   elseif ( GetItemCount "imperial_greaves" > 0 )
      equip "imperial_greaves"
   elseif ( GetItemCount "steel_greaves" > 0 )
      equip steel_greaves
   elseif ( GetItemCount "iron_greaves" > 0 )
      equip "iron_greaves"
   endif
endif
; safety
if ( GetWaterWalking >= 234 )
   ModWaterWalking -234
endif
if ( GetSpellEffects "ab01mountAbility" )
   set x1 to 1
elseif ( GetSpell "ab01mountAbility" )
   set x1 to 1
else
   set x1 to 0
endif
if ( x1 > 0.5 )
   set x1 to GetPos X
   set x1 to ( x1 + 100 )
   SetPos X x1
   set x1 to GetPos Y
   set x1 to ( x1 + 100 )
   SetPos Y x1
   tcl ; try moving to the ground to avoid damage with MCP feather changes (tcl moves player to the ground )
   tcl
endif
ClearForceJump
ClearForceMoveJump
RemoveSpell "ab01mountAbility"
RemoveSpellEffects "ab01mountAbility"
set ab01compMounted to 0
StopScript ab01gutDismountScript
end