apkstudio

# Maintainer:  Eliminater74 <eliminater74@gmail.com>
# Contributor:  < >

_pkgname=apkstudio
pkgname=$_pkgname-git
pkgver=r293.8baa7d5
pkgrel=1
epoch=1
pkgdesc='An IDE for decompiling/editing & then recompiling of android application binaries.'
arch=('i686' 'x86_64')
url='http://www.vaibhavpandey.com/apkstudio/'
license=('GPL2')
depends=('qt5-base' 'android-tools')
makedepends=('git' 'qt5-tools' 'unzip')
source=('git+https://github.com/vaibhavpandeyvpz/apkstudio.git'
        'git+https://github.com/Jorgen-VikingGod/Qt-Frameless-Window-DarkStyle.git'
        'git+https://github.com/Dax89/QHexView.git')
sha256sums=('SKIP'
            'SKIP'
            'SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/$_pkgname"
  git submodule init
  git config submodule.Qt-Frameless-Window-DarkStyle.url $srcdir/Qt-Frameless-Window-DarkStyle
  git config submodule.QHexView.url $srcdir/QHexView
  git submodule update
}

build() {
  cd "$srcdir/$_pkgname/build"
  qmake-qt5 -r ../apkstudio.pro CONFIG+=release PREFIX=/usr
  make -j$(nproc)
}

package() {
  cd "$srcdir"
  install -Dm755 "$_pkgname/build/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
  install -Dm755 "$_pkgname/resources/$_pkgname.desktop" "$pkgdir/usr/share/applications/$_pkgname.desktop"
  install -Dm755 "$_pkgname/resources/icon.png" "$pkgdir/usr/share/pixmaps/icon.png"
}