QuickConnect 2.2

// TLD LIST

tld = [
AC AD AE AF AG AI AL AM AO AR AS ASIA AT AU AW AX AZ BA BB BD BE BF BG BH
BI BIZ BJ BM BN BO BR BS BT BW BY BZ CA CC CD CF CG CH CI CK CL CM CN CO
COM CR CU CV CX CY CZ DE DJ DK DM DO DZ EC EDU EE EG ER ES ET EU FI FJ FK
FM FO FR GA GB GD GE GF GG GH GI GL GM GN GP GQ GR GS GT GU GW GY HK HM HN
HR HT HU ID IE IL IM IN INFO IO IQ IR IS IT JE JM JO JP KE KG KH KI KM KN
KP KR KW KY KZ LB LC LI LK LR LS LT LU LV LY MA MC ME MG MH ML MM MN MO MP
MQ MR MS MT MU MV MW MX MY MZ NA NC NE NET NF NG NI NL NO NP NR NU NZ OM
ORG PA PE PF PG PH PK PL PM PN PR PS PT PW PY QA RE RO RS RU RW SA SB SC
SD SE SG SH SI SK SL SM SN SO SR ST SU SV SY SZ TC TD TG TH TJ TK TL TM TN
TO TP TR TT TV TW TZ UA UG UK US UY UZ VC VE VG VI VN VU WF WS YE YT ZA ZM ZW
]

//----------------------------------

// Some generic commands that may be used elsewhere

createine = [ if (=s (getalias $arg1) "") [ $arg1 = $arg2 ] ]
append = [$arg1 = (concat (getalias $arg1) $arg2)]
isnum = [
    bool = 1
    loop c (strlen $arg1) [
        if (< (strstr "0123456789." (substr $arg1 $c 1)) 0) [bool = 0]
    ]
    result $bool
]

// Ugly and could use many improvements, but for
// the most part, it does its job pretty nicely

isip = [
    result (
        && (
            = (listlen (strreplace $arg1 . " ")) 4
        ) (
            < (listfind i (strreplace $arg1 . " ") [|| (> $i 255) (< $i 0)]) 0
        ) (isnum $arg1)
    )
]

// Alias variables for the first use

createine qc_servlist ""
createine qc_servname ""

// Define some commands as helpers

qc_findserv = [listfind i $qc_servlist [=s $arg1 (at $i 0)]]
qc_complete = [
    qc_servname = ""
    looplist i $qc_servlist [append qc_servname (at $i 0)]
    qc_servname = (substr $qc_servname 1)
    listcomplete qc $qc_servname
    listcomplete delqcserv $qc_servname
    listcomplete viewqcserv $qc_servname
]
qc_info = [
    qc_sel = (at $qc_servlist (qc_findserv $arg1))
    echo (format "^f7Name: ^f2%1 ^f7%2: ^f2%3 ^f7Port: ^f2%4" (at $qc_sel 0) (? (isip (at $qc_sel 1)) IP Domain) (at $qc_sel 1) (at $qc_sel 2))
]

// Below here lies the magic, user commands.

qcaddserv = [
    cond (|| (> (qc_findserv $arg1) -1) (isip $arg1)) [
        error "^f3QC entry already exists or is invalid!"
    ] (
        ? (>= $numargs 2) (
            ? (< (indexof $tld (at (strreplace $arg2 . " ") (- (listlen (strreplace $arg2 . " ")) 1))) 0) (! (isip $arg2))
        ) (! (isconnected))
    ) [
        error "^f3IP or Domain is invalid!"
    ] [
        append qc_servlist (
            format ["%1 %2 %3"] @arg1 (
                ? (> @numargs 1) $arg2 (connectedip)
            ) (
                ? (> @numargs 2) $arg3 (? (isconnected) (connectedport) 28785)
            )
        )
        echo "^f2QC ^f7entry has been included successfully!"
        qc_complete
    ]
]

qcdelserv = [
    if (< (qc_findserv $arg1) 0) [
        error "^f3QC entry does not exist!"
    ] [
        qc_servlist = (strreplace $qc_servlist (format ["%1"] (at $qc_servlist (qc_findserv $arg1))) "")
        echo "^f2QC ^f7entry has been deleted successfully!"
        qc_complete
    ]
]

qclistserv = [
    echo (format "^f2%1^f7 Available servers: ^f2%2" (listlen $qc_servname) (strreplace $qc_servname " " "^f7, ^f2"))
]

qcviewserv = [
    if (< (qc_findserv $arg1) 0) [
        error "^f3QC entry does not exist!"
    ] [qc_info $arg1]
]

qcviewservall = [
    if (!=s $qc_servlist "") [
        looplist i $qc_servname [qc_info $i]
    ] [error "^f3No registered entries!"]
]

qc = [
    if (!=s $qc_servlist "") [
        connect (at (at $qc_servlist (qc_findserv $arg1)) 1) (at (at $qc_servlist (qc_findserv $arg1)) 2)
    ] [error "^f3No registered entries!"]
]

// Compile tab completion upon execution, just in case

qc_complete