PKGBUILD

# Maintainer: Carsten Feuls <archlinux@carstenfeuls.de>
# Contributor: not_anonymous <nmlibertarian@gmail.com>
# Original Submission: Bob Finch <w9ya@qrparci.net>

pkgname=klog
pkgver=0.9.2.5
pkgrel=2
pkgdesc="Ham Radio logging with Dx Cluster - Qt based"
url="http://jaime.robles.es/"
license=('GPL3')
arch=('i686' 'x86_64')
depends=('qt5-base')
optdepends=('hamlib: rig interfacing'
	    'sglite>=3.0.0: database manipulation')
makedepends=('automoc4' 'qt5-tools')
source=("http://download-mirror.savannah.gnu.org/releases/$pkgname/$pkgname-$pkgver.tar.gz"
	$pkgname.png
	$pkgname.desktop
	klog.pro.diff
	awards.cpp.diff.fixed
	translations.pri.diff
	)

prepare() {
	cd $srcdir/$pkgname-$pkgver

	patch -p0 < ../klog.pro.diff
	patch -p0 < ../awards.cpp.diff.fixed
	patch -p0 < ../translations.pri.diff
}

build() {
	cd $srcdir/$pkgname-$pkgver

	qmake-qt5 -o Makefile PREFIX=/usr klog.pro
	make
}

package() {
	cd $srcdir/$pkgname-$pkgver

	make INSTALL_ROOT="$pkgdir/" install

	install -Dm644 $pkgname.1 "$pkgdir/usr/share/man/man1/$pkgname.1"
	find "$pkgdir/usr/share/man/man1" -name *.1 -exec gzip -9 {} +

	install -Dm644 ../$pkgname.desktop "$pkgdir/usr/share/applications/$pkgname.desktop"
	install -Dm644 ../$pkgname.png "$pkgdir/usr/share/pixmaps/$pkgname.png"
}
md5sums=('91609afec43116b1c7925bbf8aebf3a2'
         '0ba1caca72114240fa901b01a8662b5a'
         '6667836bd922592ad69bc705711391d0'
         'c1598d74eee4c615447aada59a773a56'
         '0691338983e3669e53a37ccc9ba1a03f'
         'b96c67f5efa881d9b121f5725c7df708')
sha256sums=('8875205454eca23f733e750bb274681d6ae517dd5ed67e55a94a2a9e6e004b48'
            'd03aaf4baa5aeb30d24f9ad075be14e9f18129e726311f391cb69bc393ade1ef'
            '471211041546296877ef6f6ce5c5082dc37ac8cd6088b7c811fc28f919513700'
            '8821c10067bb670177a39fb5c51808454e54c7227d6b9b5eac8298ac7bd4736d'
            '2c23edd44b73b1bf893180e2f5cc633958539bb507d367fd18884ffe4f10eee7'
            '13fe98d3c15fdb485497a72e0716af7c527a21cfbf81a0a28cc8c3c6dc5adf99')