API tools faq
paste
Advertisement
mawen1250

Contra-Sharpen mod 2.8

mawen1250
Aug 20th, 2012
183
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Avisynth 16.79 KB | None | 0 0
raw download clone embed print report
  1. ###### Contra-Sharpen mod 2.8 ###### by mawen1250 ###### 2012.08.20 ######
  2.  
  3. Function CSmod(clip filtered, clip "source", clip "pclip", int "strength", float "divisor", float "index", float "ss_w", float "ss_h",
  4. \ bool "chroma", int "preblur", bool "prec", bool "secure", bool "limit", bool "choversh", bool "Slimit", bool "SlimitY", bool "Tlimit",
  5. \ bool "ssrep", int "preR", int "Smethod", int "Smode", int "Szrp", int "Spwr", int "SdmpLo", int "SdmpHi", int "RGmode", int "RGmodeU",
  6. \ int "Repmode", int "RepmodeU", int "Sovershoot", int "Sundershoot", int "Tovershoot", int "Tundershoot", int "Soft", int "Soothe",
  7. \ string "filter_ss", int "blksize", int "overlap", int "thSAD", int "thSCD1", int "thSCD2", bool "truemotion", bool "MVglobal",
  8. \ int "pel", int "pelsearch", int "search", int "searchparam", int "MVsharp", int "DCT", bool "usepasf", string "kernel", bool "ss_hq",
  9. \ string "ssmethod", int "thr", bool "ssout", bool "ssoutc")
  10. {
  11.  
  12. sw       = filtered.width()
  13. sh       = filtered.height()
  14. HD       = (sw > 1024 || sh > 576) ? true : false
  15.  
  16. chroma   = Default(chroma,  false  )
  17. ss_w     = Default(ss_w,    1.50   )   #Super sampling multiplier of width.
  18. ss_h     = Default(ss_h,    1.50   )   #Super sampling multiplier of height.
  19. ss_hq    = Default(ss_hq,   ss_w*ss_h>=2.25)   #True using nnedi3_rpow2 in super sampling, false using non-ringing Spline64Resize.
  20. ssout    = Default(ssout,   false  )   #Output in super sampling resolution.
  21. ssoutc   = Default(ssoutc,  true   )   #Whether to output correct chroma when (chroma==false && ss_hq==false && ssout==true).
  22. ssrep    = Default(ssrep,   false  )   #When limiting sharpening to source clip, whether to repair in super sampling resolution.
  23. preblur  = Default(preblur, 1      )   #Pre-filtering, 1 uses Minblur, 2 uses Minblur(Uses SBR by default) mixed with Minblur+FluxSmoothT, 3 uses Minblur(Uses SBR by default)+FluxSmoothT.
  24. prec     = Default(prec,    preblur>=1)   #Whether to use preblur in chroma plane
  25. preR     = Default(preR,    preblur>=2?0:ss_w*ss_h<3?1:2)   #Preblur setting, 1-3 sets radius of MinBlur, 0 uses SBR instead of normal MinBlur.
  26. usepasf  = Default(usepasf, false  )   #Whether to use pre-filtered clip as input(filtered) clip, which will reduce noise/halo/ring from input clip.
  27. limit    = Default(limit,   true   )   #Whether to limit sharpening to source clip, only takes effect when (Defined(source) || Defined(filter_ss) || usepasf) == true.
  28. thr      = Default(thr,     0      )   #When limiting sharpening to source clip, allow sharpening more than the source in [thr].
  29. RGmode   = Default(RGmode,  HD?20:11)
  30. RGmodeU  = Default(RGmodeU, RGmode )
  31. Repmode  = Default(Repmode, 1      )
  32. RepmodeU = Default(RepmodeU,Repmode)
  33. ssout    = (ss_w > 1.0 || ss_h > 1.0) ? ssout : false
  34. ssrep    = (ss_w > 1.0 || ss_h > 1.0) ? ssrep : false
  35. ssrep    = ssout ? true : ssrep
  36. filter_ss= filter_ss == "AA" ? "SangNom(aa=48).TurnRight().SangNom(aa=48).TurnLeft()" : filter_ss   #When defining filter_ss="AA", will automatically use SangNom for anti-aliasing in super sampling clip.
  37. limit    = Defined(source) || Defined(filter_ss) || usepasf ? limit  : false
  38.  
  39. Smethod  = Default(Smethod, 3      )   #Sharpen Method - 1: 3x3 kernel, 2: Min/Max, 3: Min/Max + 3x3 kernel.
  40. secure   = Default(secure,  true   )   #Mode to avoid banding & oil painting (or face wax) effect of sharpening.(from LSFmod)
  41. Smode    = Default(Smode,   3      )   #Sharpen Mode - 1: Linear, 2: Non-linear 1, 3:Non-linear 2(from LSFmod).
  42. divisor  = Default(divisor, 1.5    )
  43. index    = Default(index,   0.8    )
  44. strength = Default(strength,100    )
  45. Szrp     = Default(Szrp,    16     )
  46. Spwr     = Default(Spwr,    4      )
  47. SdmpLo   = Default(SdmpLo,  4      )
  48. SdmpHi   = Default(SdmpHi,  48     )
  49.  
  50. Slimit      = Default(Slimit,      true        )   #Spatial limit with overshoot and undershoot. Disabled when (limit==true && thr==0).
  51. Sovershoot  = Default(Sovershoot,  strength/100)
  52. Sundershoot = Default(Sundershoot, Sovershoot  )
  53. choversh    = Default(choversh,    true        )   #When (limit==true && thr>=1 && choversh==false), luma will sharpen more than source, chroma will not.
  54. Tlimit      = Default(Tlimit,      false       )   #Use MC Temporal limit at the end of sharpening(only process luma).(from MCTD)
  55. Tovershoot  = Default(Tovershoot,  strength/25 )
  56. Tundershoot = Default(Tundershoot, Tovershoot  )
  57. SlimitY     = Default(SlimitY,     !Tlimit     )   #It will automatically set Slimit=true, SlimitY=false to use Spatial limit on chroma when Tlimit=true.
  58. Soft        = Default(Soft,        -2          )   #Soft the sharpening effect (-1 = old autocalculate, -2 = new autocalculate, 100 = disable). Disabled when (limit==true && thr==0).(from LSFmod)
  59. Soothe      = Default(Soothe,      24          )   #Soothe temporal stabilization, 0-100 sets minimum percent of the original sharpening to keep, -1 disables Soothe. Disabled when Tlimit=true.
  60.  
  61. blksize     = Default(blksize,     HD ? 16 : 8 )
  62. overlap     = Default(overlap,     HD ? 8  : 4 )
  63. thSAD       = Default(thSAD,       300         )
  64. thSCD1      = Default(thSCD1,      300         )
  65. thSCD2      = Default(thSCD2,      100         )
  66. truemotion  = Default(truemotion,  false       )
  67. MVglobal    = Default(MVglobal,    true        )
  68. pel         = Default(pel,         2           )
  69. pelsearch   = Default(pelsearch,   2           )
  70. search      = Default(search,      2           )
  71. searchparam = Default(searchparam, 2           )
  72. MVsharp     = Default(MVsharp,     2           )
  73. DCT         = Default(DCT,         0           )
  74.  
  75.  
  76. ss_w     = max(ss_w, 1.0)
  77. ss_h     = max(ss_h, 1.0)
  78. wss      = Round(sw*ss_w/8)*8
  79. hss      = Round(sh*ss_h/8)*8
  80. rfactor  = max(Round(sqrt(ss_w*ss_h)/2)*2, 2)
  81. ssmethod = Defined(ssmethod) ? ssmethod
  82. \        : ss_hq ? """nnedi3_rpow2(rfactor=rfactor, qual=2, cshift="Spline64Resize", fwidth=wss, fheight=hss)"""
  83. \                : "nonringSpline64Resize(wss, hss, chroma=chroma||ssoutc)"
  84. #You can define your own super sampling method with ssmethod.
  85.  
  86. ch21     = chroma ? 2 : 1
  87. ch31     = chroma ? 3 : 1
  88. Slimit   = limit && thr==0 ? false : Slimit
  89. Soft     = limit && thr==0 ? 100
  90. \        : Soft <= -2  ? Round( (1.0+(2.0/(ss_w+ss_h))) * sqrt(strength) )
  91. \        : Soft == -1  ? sqrt( (((ss_w+ss_h)/2.0-1.0)*100.0) ) * 10
  92. \        : Soft <= 100 ? Soft : 100
  93. Soothe   = Tlimit ? -1 : Soothe
  94. strength = Smode == 1 ? strength/50.0 : Smode == 2 ? strength/20.0 : strength/100.0
  95.  
  96. preR        = preR <= 0 ? 0 : preR >= 3 ? 3 : preR
  97. Sovershoot  = Sovershoot  < 0 ? 0 : Sovershoot
  98. Sundershoot = Sundershoot < 0 ? 0 : Sundershoot
  99. Tovershoot  = Tovershoot  < 0 ? 0 : Tovershoot
  100. Tundershoot = Tundershoot < 0 ? 0 : Tundershoot
  101.  
  102.  
  103. #super sampling with filtering
  104. defsrc      = Defined(source)
  105. source      = defsrc ? source : filtered
  106. filtered_os = filtered
  107. filtered    = (ss_w > 1.0 || ss_h > 1.0) ? Eval("filtered."+ssmethod) : filtered
  108. source_ss   = (ss_w > 1.0 || ss_h > 1.0) ? defsrc ? Eval("source."+ssmethod) : filtered : source
  109. filtered    = (ss_w > 1.0 || ss_h > 1.0) && Defined(filter_ss) ? Eval("filtered."+filter_ss) : filtered
  110. filtered_ds = (ss_w > 1.0 || ss_h > 1.0) && Defined(filter_ss) ? filtered.nonringSpline64Resize(sw, sh, chroma=chroma) : filtered_os
  111.  
  112. Assert( (isFrameBased(filtered_os)),                            """CSmod: input clip "filtered" must be Frame Based!""" )
  113. Assert( (isFrameBased(source)),                                   """CSmod: input clip "source" must be Frame Based!""" )
  114. Assert( (source.width() == sw && source.height() == sh), """CSmod: resolution of "filtered" and "source" must match!""" )
  115.  
  116.  
  117. #pre-filtering before sharpening
  118. spatial  = filtered.MinBlur(preR, chroma ? (prec ? 3 : 2) : 1)
  119. temporal = spatial .FluxsmoothT(7).Repair(spatial, 1, prec ? 1 : -1)
  120. temporal = chroma&&!prec ? temporal.MergeChroma(filtered) : temporal
  121. mixed    = temporal.merge(spatial,0.251)
  122. pre      = Defined(pclip) ? pclip
  123. \                         : preblur==1 ? spatial
  124. \                         : preblur==2 ? mixed
  125. \                         : preblur>=3 ? temporal
  126. \                         : filtered
  127. #You can define your own pre-filter clip with pclip.
  128. pre_ds   = (pre.width() == sw && pre.height() == sh) ? pre : pre.nonringSpline64Resize(sw, sh, chroma=chroma)
  129. pre      = (ss_w > 1.0 || ss_h > 1.0) ? (pre.width() == wss && pre.height() == hss) ? pre : Eval("pre."+ssmethod) : pre_ds
  130.  
  131. #whether to use pre-filtered clip as main clip
  132. filtered    = usepasf ? pre    : filtered
  133. filtered_ds = usepasf ? pre_ds : filtered_ds
  134.  
  135.  
  136. #unsharp
  137. dark_limit   = pre.mt_inpand(U=ch31, V=ch31)
  138. bright_limit = pre.mt_expand(U=ch31, V=ch31)
  139. minmaxavg    = Smethod == 1 ? NOP() : mt_average(dark_limit, bright_limit, U=ch31, V=ch31)
  140.  
  141. method = Smethod == 1  ? Defined(kernel) ? Eval("pre.      "+kernel) : pre      .removegrain(RGmode, chroma ? RGmodeU : -1)
  142. \      : Smethod == 2  ?                                               minmaxavg
  143. \      :                 Defined(kernel) ? Eval("minmaxavg."+kernel) : minmaxavg.removegrain(RGmode, chroma ? RGmodeU : -1)
  144.  
  145. method = secure        ? method.mt_lutxy(pre,"x y < x 1 + x y > x 1 - x ? ?", U=ch31, V=ch31) : method
  146.  
  147.  
  148. #making difference clip of sharpening
  149. sharpdiff = mt_makediff(pre, method, U=ch31,V=ch31)
  150.  
  151.  
  152. #sharpening diff generate mode
  153. sharpdiff = Smode == 1 ? sharpdiff.mt_lut(expr="x 128 - "+string(strength)+" * 128 +", U=ch31, V=ch31)
  154. \         : Smode == 2 ? sharpdiff.mt_lut("x 128 == x x 128 - "+String(divisor)+" / Abs "+String(index)+" ^ "+String(strength)+" * x 128 > 1 -1 ? * 128 + ?", U=ch31, V=ch31)
  155. \         : Smode == 3 ? sharpdiff.mt_lut("x 128 == x x 128 - abs "+string(Szrp)+" / 1 "+string(Spwr)+" / ^ "+string(Szrp)+" * "+string(strength)+" * x 128 - x 128 - abs / * x 128 - 2 ^ "+string(Szrp)+" 2 ^ "+string(SdmpLo)+" + * x 128 - 2 ^ "+string(SdmpLo)+" + "+string(Szrp)+" 2 ^ * / * 1 "+string(SdmpHi)+" 0 == 0 "+string(Szrp)+" "+string(SdmpHi)+" / 4 ^ ? + 1 "+string(SdmpHi)+" 0 == 0 x 128 - abs "+string(SdmpHi)+" / 4 ^ ? + / * 128 + ?", U=ch31, V=ch31)
  156. \         : sharpdiff
  157.  
  158.  
  159. #spatial limit
  160. sclp   = Slimit ? mt_adddiff(filtered, sharpdiff, U=ch31, V=ch31) : NOP()
  161. sclp   = Slimit ? sclp.mt_clamp(bright_limit, dark_limit, Sovershoot, Sundershoot, Y=SlimitY?3:2, U=ch31, V=ch31) : NOP()
  162.  
  163.  
  164. #Soft
  165. sharpdiff  = Slimit ? mt_makediff(sclp, filtered, U=ch31, V=ch31) : sharpdiff
  166. sharpdiff  = Soft == 100 ? sharpdiff : mt_lutxy(sharpdiff, sharpdiff.removegrain(19, chroma ? 19 : -1), "x 128 - abs y 128 - abs > y "+string(Soft)+" * x "+string(100-Soft)+" * + 100 / x ?", U=ch31, V=ch31)
  167.  
  168.  
  169. #Soothe
  170. sharpdiff2 = (Soothe >= 0 && Soothe <= 100) ? sharpdiff.temporalsoften(1,255,chroma ? 255 : 0,32,2) : NOP()
  171. sharpdiff  = (Soothe >= 0 && Soothe <= 100) ? mt_lutxy(sharpdiff, sharpdiff2, "x 128 - y 128 - * 0 < x 128 - 100 / "+string(Soothe)+" * 128 + x 128 - abs y 128 - abs > x "+string(Soothe)+" * y 100 "+string(Soothe)+" - * + 100 / x ? ?", U=ch31, V=ch31) : sharpdiff
  172.  
  173.  
  174. #the difference achieved by filtering
  175. allD       = limit  ? ssrep && (ss_w > 1.0 || ss_h > 1.0) ? mt_makediff(source_ss, filtered, U=ch31, V=ch31)
  176. \          : mt_makediff(source, filtered_ds, U=ch31, V=ch31) : NOP()
  177.  
  178. #limiting sharpening to source clip
  179. sharpdiff  = !ssrep && (ss_w > 1.0 || ss_h > 1.0) ? sharpdiff.nonringSpline64Resize(sw, sh, chroma=chroma) : sharpdiff
  180. ssDD       = limit  ? sharpdiff.repair(allD, mode=Repmode, modeU=chroma ? RepmodeU : -1) : sharpdiff
  181. ssDD       = limit && thr >= 1 ? sharpdiff.mt_lutxy(ssDD,"x 128 - abs y 128 - abs " + string(thr) + " + <= x y 128 < y " + string(thr) + " - y " + string(thr) + " + ? ?", U=choversh?ch31:ch21, V=choversh?ch31:ch21) : ssDD
  182. ssDD       = limit && thr == 0 || (limit && !choversh) ? ssDD.mt_lutxy(sharpdiff, "x 128 - abs y 128 - abs < x y ?", Y=(limit && thr >= 1 && !choversh)?2:3, U=ch31, V=ch31) : ssDD
  183. ssDD       = ssrep && (ss_w > 1.0 || ss_h > 1.0) && !ssout ? ssDD.nonringSpline64Resize(sw, sh, chroma=chroma) : ssDD
  184.  
  185. #add difference clip to clip "filtered" of ss/original resolution
  186. sclp       = ssout ? mt_adddiff(filtered, ssDD, U=ch31, V=ch31) : mt_adddiff(filtered_ds, ssDD, U=ch31, V=ch31)
  187.  
  188.  
  189. #temporal limit
  190. pre_ds = ssout  ? pre       : pre_ds
  191. source = ssout  ? source_ss : source
  192.  
  193. pMVS   = Tlimit ? pre_ds.MSuper(hpad=0, vpad=0, pel=pel, sharp=MVsharp, chroma=false) : NOP()
  194. f1v    = Tlimit ? MAnalyse(pMVS, isb=false, delta=1, truemotion=truemotion, blksize=blksize, overlap=overlap, pelsearch=pelsearch, search=search, searchparam=searchparam, DCT=DCT, global=MVglobal, chroma=false) : NOP()
  195. b1v    = Tlimit ? MAnalyse(pMVS, isb=true,  delta=1, truemotion=truemotion, blksize=blksize, overlap=overlap, pelsearch=pelsearch, search=search, searchparam=searchparam, DCT=DCT, global=MVglobal, chroma=false) : NOP()
  196. f1c    = Tlimit ? MCompensate(source, pMVS, f1v, thSAD=thSAD, thSCD1=thSCD1, thSCD2=thSCD2) : NOP()
  197. b1c    = Tlimit ? MCompensate(source, pMVS, b1v, thSAD=thSAD, thSCD1=thSCD1, thSCD2=thSCD2) : NOP()
  198. Tmax   = Tlimit ? source.mt_logic(f1c, "max", U=1, V=1).mt_logic(b1c, "max", U=1, V=1) : NOP()
  199. Tmin   = Tlimit ? source.mt_logic(f1c, "min", U=1, V=1).mt_logic(b1c, "min", U=1, V=1) : NOP()
  200. sclp   = Tlimit ? sclp.mt_clamp(Tmax, Tmin, Tovershoot, Tundershoot, U=2, V=2) : sclp
  201.  
  202.  
  203. return chroma ? sclp
  204. \             : ssout ? ssoutc ? sclp.MergeChroma(source_ss)
  205. \                              : sclp
  206. \                     : sclp.MergeChroma(filtered_os)
  207. }
  208.  
  209.  
  210. Function MinBlur(clip clp, int "r", int "uv"){
  211.  
  212. r     = default(r,1)
  213. uv    = default(uv,3)
  214.  
  215. uv2   = (uv==2) ? 1  : uv
  216. rg4   = (uv==3) ? 4  : -1
  217. rg11  = (uv==3) ? 11 : -1
  218. rg20  = (uv==3) ? 20 : -1
  219. medf  = (uv==3) ? 1  : -200
  220. uvm2  = (r==2)  ? (uv==3?3:uv==2?0:-1) : nop()
  221. uvm3  = (r==3)  ? (uv==3?3:uv==2?0:-1) : nop()
  222.  
  223. RG11D = (r==0) ? mt_makediff(clp,clp.sbr(uv=uv2),U=uv2,V=uv2)
  224. \     : (r==1) ? mt_makediff(clp,clp.removegrain(11,rg11),U=uv2,V=uv2)
  225. \     : (r==2) ? mt_makediff(clp,clp.removegrain(11,rg11).removegrain(20,rg20),U=uv2,V=uv2)
  226. \     :          mt_makediff(clp,clp.removegrain(11,rg11).removegrain(20,rg20).removegrain(20,rg20),U=uv2,V=uv2)
  227. RG4D  = (r<=1) ? mt_makediff(clp,clp.removegrain(4,rg4),U=uv2,V=uv2)
  228. \     : (r==2) ? mt_makediff(clp,clp.Quantile(radius_y=2, radius_u=uvm2, radius_v=uvm2), U=uv2,V=uv2)
  229. \     :          mt_makediff(clp,clp.Quantile(radius_y=3, radius_u=uvm3, radius_v=uvm3), U=uv2,V=uv2)
  230. #\     : (r<=2) ? mt_makediff(clp,clp.medianblur(2,2*medf,2*medf),U=uv2,V=uv2)
  231. #\     :          mt_makediff(clp,clp.medianblur(3,3*medf,3*medf),U=uv2,V=uv2)
  232. DD    = mt_lutxy(RG11D,RG4D,"x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?",U=uv2,V=uv2)
  233. clp.mt_makediff(DD,U=uv,V=uv)
  234. return(last)
  235. }
  236.  
  237. Function sbr(clip c, int "uv") {
  238. uv     = Default(uv, 1)
  239. uv2    = (uv==2) ? 1  : uv
  240. rg11   = (uv==3) ? 11 : -1
  241. rg11D  = mt_makediff(c,c.removegrain(11, rg11), U=uv2, V=uv2)
  242. rg11DD = mt_lutxy(rg11D, rg11D.removegrain(11, rg11), "x y - x 128 - * 0 < 128 x y - abs x 128 - abs < x y - 128 + x ? ?", U=uv2, V=uv2)
  243. c.mt_makediff(rg11DD, U=uv, V=uv)
  244. return(last)
  245. }
  246.  
  247. Function nonringSpline64Resize(clip input, int "target_width", int "target_height", float "src_left", float "src_top", float "src_width", float "src_height", bool "chroma", val "nr") {
  248.  
  249.   w             = input.Width
  250.   h             = input.Height
  251.  
  252.   target_width  = Default(target_width,      w)
  253.   target_height = Default(target_height,     h)
  254.   src_left      = Default(src_left,          0)
  255.   src_top       = Default(src_top,           0)
  256.   src_width     = Default(src_width,         w)
  257.   src_height    = Default(src_height,        h)
  258.   chroma        = Default(chroma,         true)
  259.   nr            = Default(nr,             true)
  260.  
  261.   Assert( IsFloat(nr) || IsBool(nr), """nonringSpline64Resize: "nr" should be either bool or float!""" )
  262.  
  263.   res_mul   = Float( target_width * target_height ) / Float( w * h )
  264.   res_mul   = min( max( res_mul, 1 ), 2.25 )
  265.   nr_weight = IsFloat(nr)       ? nr
  266.   \         : nr /* == True  */ ? Spline( res_mul, 1, 0, 2.25, 1, 3.5, 0, true )
  267.   \         :    /* == False */   0
  268.   nr_weight = min( max( nr_weight, 0 ), 1 )
  269.  
  270.   try {
  271.     inputp = chroma       ? input.IsYV12 ? input
  272.     \                                    : input.ConvertToYV12
  273.     \                     : input.ConvertToY8
  274.   } catch ( error_msg ) {
  275.     inputp = input.IsYV12 ? input
  276.     \                     : input.ConvertToYV12
  277.   }
  278.  
  279.   resize = inputp.Spline64Resize(target_width, target_height, src_left, src_top, src_width, src_height)
  280.   nrres  = inputp.GaussResize(target_width, target_height, src_left, src_top, src_width, src_height, p=100)
  281.   resize = resize.GetCSP == "Y8" ? resize.ConvertToYV12 : resize
  282.   nrres  = nrres .GetCSP == "Y8" ? nrres .ConvertToYV12 : nrres
  283.  
  284.   resize = nr_weight == 0 ? resize
  285.   \      : nr_weight == 1 ? resize.Repair(nrres, 1, chroma ? 1 : -1)
  286.   \      : chroma         ? Merge    (resize, resize.Repair(nrres, 1,  1), nr_weight)
  287.   \                       : MergeLuma(resize, resize.Repair(nrres, 1, -1), nr_weight)
  288.  
  289.   return resize
  290. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!