;-------------------------------------
;Instant Access Channel Select
;-------------------------------------

IACHSel     call        MIDIIn          ;receive CC data value byte

        btfsc       MIDI_TEMP,6     ;is data value an on or an off message?
        goto        CCOverdrive     ;on, select overdrive channel

CCClean     bsf     CH_RELAY        ;switch channel select relay to clean
        bcf     LD_RELAY        ;disable lead boost
        bsf     LE          ;pulse latch
        bcf     LE
        bcf     IASTA,0         ;clear overdrive IA flag bit
        bsf     PASTA,0         ;set clean flag bit in Port A status register
        goto        ISRExit         ;exit ISR

CCOverdrive bcf     CH_RELAY        ;switch channel select relay to overdrive
        btfsc       IASTA,1         ;is lead boost instant access button active?
        bsf     LD_RELAY        ;yes, select lead boost
        bsf     LE          ;pulse latch
        bcf     LE
        bsf     IASTA,0         ;set overdrive IA flag bit
        bcf     PASTA,0         ;clear clean flag in Port A status register
        goto        ISRExit         ;exit ISR

;----------------------------------------
;Instant Access Lead Boost Select
;----------------------------------------

IALDSel     call        MIDIIn          ;receive CC data value byte

        btfsc       MIDI_TEMP,6     ;is data value an on or an off message?
        goto        CCLDOn          ;on, select lead boost

CCLDOff     bcf     LD_RELAY        ;off, deselect lead boost
        bsf     LE          ;pulse latch
        bcf     LE
        bcf     IASTA,1         ;clear lead boost IA flag
        bcf     PASTA,1         ;clear lead boost flag in Port A status register
        goto        ISRExit         ;exit ISR

CCLDOn      btfsc       PASTA,0         ;is the clean flag set?
        goto        $+5         ;yes, do not activate lead boost, but update
                            ;lead boost IA flag
        bsf     LD_RELAY        ;no, activate lead boost
        bsf     LE          ;pulse latch
        bcf     LE
        bsf     PASTA,1         ;set lead boost flag in Port A status register
        bsf     IASTA,1         ;set lead boost IA flag bit
        goto        ISRExit         ;exit ISR