miscsplashutils-0.1.8-6_PKGBUILD

# Maintainer: Heiko Baums <heiko@baums-on-web.de>
# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org

pkgname=miscsplashutils
pkgver=0.1.8
pkgrel=6
pkgdesc='Miscellaneous framebuffer utilities including fbres and fbtruetype'
arch=('i686' 'x86_64')
url='http://dev.gentoo.org/~spock/projects/gensplash/'
license=('GPL')
#depends=('freetype2')
depends=('zlib' 'bzip2' 'sh')
freetype_pkgver=2.5.0.1
source=("http://distfiles.gentoo.org/distfiles/${pkgname}-${pkgver}.tar.bz2"
        "http://downloads.sourceforge.net/sourceforge/freetype/freetype-${freetype_pkgver}.tar.bz2"
        "freetype-2.2.1-enable-valid.patch"
        "freetype-2.3.0-enable-spr.patch"
        "freetype-2.4.11-enable-sph.patch")
md5sums=('0a9505c5c5ed169e6158d2c1b06ff40b'
         'c72e9010b1d986d556fc0b2b5fcbf31a'
         '214119610444c9b02766ccee5e220680'
         '816dc8619a6904a7385769433c0a8653'
         '2422f8902224fedb46ae9eec08c8ceac')

prepare() {
  cd "${srcdir}/freetype-${freetype_pkgver}"

  ######
  # Apply patches from this version of the freetype2 package
  ######
  patch -Np1 -i "${srcdir}/freetype-2.2.1-enable-valid.patch"
  patch -Np1 -i "${srcdir}/freetype-2.3.0-enable-spr.patch"

  # Disabled for now due to resistance
  # Kept here for easier rebuilds via ABS
  # https://bugs.archlinux.org/task/35274
  #patch -Np1 -i "${srcdir}/freetype-2.4.11-enable-sph.patch"
  ######

  cd "${srcdir}/${pkgname}-${pkgver}"

  sed -i "26s:libz.a:libz.a \$\(LIBDIR\)/libbz2.a:" fbtruetype/Makefile
  sed -i "26s:\$(LIBDIR)/libfreetype\.a:../libfreetype.a:" fbtruetype/Makefile
  #/usr/bin move update
  sed -i "s/sbin/bin/g" fbtruetype/Makefile
}

build() {
  cd "${srcdir}/freetype-${freetype_pkgver}"

  ######
  # Make libfreetype.a static library to allow linking of miscsplashutils
  # static images
  ######
  # Disable PNG support as it's not needed
  ./configure --prefix=/usr \
    --without-png

  make

  cp -fp ./objs/.libs/libfreetype.a "${srcdir}/${pkgname}-${pkgver}/"
  ######

  cd "${srcdir}/${pkgname}-${pkgver}"

  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}/usr" install

  install -d "${pkgdir}/usr/lib/splash/bin"
  ln -s /usr/bin/wc "${pkgdir}/usr/lib/splash/bin"

  # install luxisri.ttf to avoid an x-server dependency
  install -D -m644 fbtruetype/luxisri.ttf "${pkgdir}/etc/splash/luxisri.ttf"
}