BAPI_MATERIAL_SAVEDATA

    data(plantData) = value bapi_marc_ga( ) .
    data(plantDataX) = value bapi_marcx( plant = struc-werks ) .
    data(storageLocationData) = value bapi_mard_ga( ) .
    data(storageLocationDataX) = value bapi_mardx( plant = struc-werks stge_loc = struc-lgort ) .
    data(bapiRet) = value fmfg_t_bapiReturn( ) .
    call function 'BAPI_MATERIAL_GETALL'
      EXPORTING
        material            = struc-matnr     " Material Number
        plant               = struc-werks     " Plant
        storageLocation     = struc-lgort     " Storage Location
      IMPORTING
        plantData           = plantData           " Material Data at Plant Level
        storageLocationData = storageLocationData " Material Data at Storage Location Level
      TABLES
        return              = bapiRet.             " Return Parameters

    if plantData-availCheck is initial .
      plantData-availCheck = '01' .
      plantDataX-availCheck = abap_true .
    endif .

    if plantData-mrp_type is initial .
      plantData-mrp_type = 'NA' .
      plantDataX-mrp_type = abap_true .
    endif .

    storageLocationData-reorder_pt = struc-minbe .
    storageLocationDataX-reorder_pt = abap_true .

    storageLocationData-repl_qty = struc-lbstf .
    storageLocationDataX-repl_qty = abap_true .

    storageLocationData-stge_bin = struc-lgpbe .
    storageLocationDataX-stge_bin = abap_true .

    data(materialHeader) = value bapiMatHead(
                                   material = struc-matnr
                                   storage_view = abap_true
                                   mrp_view = abap_true
                                 ) .
    free __postBapiResult .
    data(bapiReturn) = value bapiRet2( ) .
    call function 'BAPI_MATERIAL_SAVEDATA'
      EXPORTING
        headData             = materialHeader       " Header segment with control information
        plantData            = value bapi_marc(     " Plant-specific material data
                                 plant = struc-werks
                                 mrp_type = plantData-mrp_type
                                 availCheck = plantData-availCheck
                               )
        plantDataX           = plantDataX           " Information on update for PLANTDATA
        storageLocationData  = value bapi_mard(     " Storage-location-specific material data
                                 plant      = struc-werks
                                 stge_loc   = struc-lgort
                                 reorder_pt = storageLocationData-reorder_pt
                                 repl_qty   = storageLocationData-repl_qty
                                 stge_bin   = storageLocationData-stge_bin
                               )
        storageLocationDataX = storageLocationDataX " Information on update for STORAGELOCATIONDATA
      importing
        return               = bapiReturn.

    call function 'BAPI_TRANSACTION_COMMIT' .