-	shop	Phraconshop	-1,1010:-1,1011:-1;
//====================================================//
function	script	修理裝備	{

	mes "[強化裝備人員]";
	mes"請選擇您要修理的物品選項。";
	next;
	if ( getbrokenid(1) == NULL ) {	mes "[強化裝備人員]";
					mes "您沒有任何受損的物品唷!";
					close;	}

	set .@RepItem,select(getitemname(getbrokenid(1)),getitemname(getbrokenid(2)),
				getitemname(getbrokenid(3)),getitemname(getbrokenid(4)),
				getitemname(getbrokenid(5)),getitemname(getbrokenid(6)),
				getitemname(getbrokenid(7)),getitemname(getbrokenid(8)),
				getitemname(getbrokenid(9)),getitemname(getbrokenid(10)));

	if ( getbrokenid(.@RepItem) == NULL ) {	close;	}
	mes "[強化裝備人員]";
	mes "修理 ^0000FF"+getitemname(getbrokenid(.@RepItem))+"^000000 這項物品";
	mes "需要 ^FF0000鋼鐵     1^000000 個";
	mes "　和 ^FF0000金錢 10000^000000 z";
	next;
	if (select("是的!","不了!")==2) {
					close;
					}
	if ( countitem(999) < 1 || Zeny < 10000 ) {	mes "[強化裝備人員]";
							mes "抱歉您身上的物品不足!";
							close;	}
	delitem 999,1;
	set Zeny,Zeny - 10000;
	repair(.@RepItem);
	mes"[強化裝備人員]";
	mes"鏘！鏘！鏘！";
	next;
	mes"[強化裝備人員]";
	mes"恭喜您物品已修理完成了!";
	close;
}

//==================================================//

function	script	拆除卡片	{

	mes "[強化裝備人員]";
	mes"請選擇您要拆除的物品選項。";
	next;
	set .@CardPart,select(
	getequipname(1),getequipname(2),
	getequipname(3),getequipname(4),
	getequipname(5),getequipname(6),getequipname(7),
	getequipname(8),getequipname(9),getequipname(10));

		if ( getequipcardcnt(.@CardPart) == 0 ) {
		mes "[強化裝備人員]";
		mes "這個物品並沒有插上卡片唷!";
		close;	}
	set .@CardCount,getequipcardcnt(.@CardPart);
	mes "[強化裝備人員]";
	mes "拆除 ^0000FF"+getequipname(.@CardPart)+"^000000 上的卡片，";
	mes "需要 ^FF0000金錢 "+(.@CardCount*100000)+"^000000 z";
	mes "　和 ^FF0000星星的角　　1^000000 個";
	mes "　和 ^FF0000星星的粉末  1^000000 個";
	next;
	if (select("是的!","不了!")==2) {
					close;
					}
	if ( zeny < (.@CardCount*100000) || countitem(1000) < 1 || countitem(1001) < 1 ) {	mes "[強化裝備人員]";
								mes "抱歉您身上的物品不足!";
								close;	}
	delitem 1000,1;
	delitem 1001,1;
	set zeny,zeny - (.@CardCount*100000);
	successremovecards .@CardPart;
	mes"[強化裝備人員]";
	mes"鏘！鏘！鏘！";
	next;
	mes"[強化裝備人員]";
	mes"恭喜您拆除卡片已完成了!";
	close;
}