Logo - Zadatak Kovanice

to kovanice :n :a :b :d
	; glavni program
	( local "velicine "kovanice "r )
	make "velicine (list :a (:a+:b) 0 0 (:a+2*:b) )
	make "kovanice rasporedi :n

	foreach :kovanice [
		make "r item (item # :kovanice) :velicine
		novcic :r :d
		pu fd :d pd
	]

end

to rasporedi :n
	; rasporedi :n na petice, dvice i jedinice
	( local "petice "dvice "jedinice "l )
	make "petice int (:n/5)
	make "dvice int ((:n-:petice*5)/2)
	make "jedinice (:n-:petice*5-:dvice*2)

	make "l []
	repeat :petice [make "l lput 5 :l]
	repeat :dvice [make "l lput 2 :l ]
	repeat :jedinice [make "l lput 1 :l ]
	op :l
end

to novcic :r :d
	; crtanje jednog novcica s brisanjem pozadine
	( local "p )
	polukrug :r :d make "p pos
	pu lt 90 fd :r rt 90 pd fd :d
	pu setpos :p
	rt 90 fd :r lt 90 pd fd :d
	pu setpos :p fd :d pd
	krug :r
	pu setpos :p pd

end

to krug :r
	; prebrisi oblik kruga :r i nacrtaj kruznicu :r
	setcolors [254 254 254] circle :r (fill "true)
	setcolors [255 255 255] fill
	setcolors [0 0 0] circle :r

end



to polukrug :r :d
	; prebrisi oblik slova u visine linija :d i nacrtaj polukrug :r
	( local "p )
	make "p pos
	setcolors [254 254 254]
	lt 90 arc 180 :r pu fd :r rt 90 pd fd :d rt 90 fd :r*2 rt 90 fd :d rt 180
	pu setpos :p
	pu bk :r/2

	pd  (fill "true) pu fd :r/2 pd
	setcolors [255 255 255] fill
	setcolors [0 0 0] lt 90 arc 180 :r rt 90

end



to setcolors :color
	; postavi iste boje :color crtanja i ispunjavanja
	setpc :color setfc :color
end