/* Charred grass = smelt grass
   charred dirt = smelt dirt
   charred gravel = smelt gravel
   ash = smelt charcoal (must be charcoal)

   all charred blocks = craft shapeless blaze powder and uncharred variant

   Grinder recipe: sand to dust, various stone types to their crushed versions, crushed granite to red sand

   Sponge recipe: 5 yellow wool in x pattern, 4 string

   todo:
   Rainbow Oak saplings are not fuel- they should be
   Torch Lever: fix the torch lever's uneven crafting recipes
   remove builder wands, effortless building is better in every way
   fix MrCrayFish recipes to use ore dictionary for dyes
*/

//First we need to make an ore list of all the axes in the game
val axes = <ore:listAllAxe>;
axes.add(<minecraft:iron_axe:*>);
axes.add(<minecraft:wooden_axe:*>);
axes.add(<minecraft:stone_axe:*>);
axes.add(<minecraft:diamond_axe:*>);
axes.add(<minecraft:golden_axe:*>);
axes.add(<botania:manasteelaxe:*>);
axes.add(<botania:elementiumaxe:*>);
axes.add(<iceandfire:silver_axe:*>);
axes.add(<iceandfire:dragonbone_axe:*>);
axes.add(<iceandfire:myrmex_desert_axe:*>);
axes.add(<iceandfire:myrmex_jungle_axe:*>);
axes.add(<immersiveengineering:axe_steel:*>);
axes.add(<thaumcraft:thaumium_axe:*>);
axes.add(<thaumcraft:void_axe:*>);
axes.add(<thaumcraft:elemental_axe:*>);
axes.add(<twilightforest:ironwood_axe:*>);
axes.add(<twilightforest:steeleaf_axe:*>);
axes.add(<twilightforest:minotaur_axe_gold:*>);
axes.add(<twilightforest:minotaur_axe:*>);
axes.add(<twilightforest:knightmetal_axe:*>);

//Not sure if we can transform an item that's in an ore dictionary list like this
recipes.remove(<cfm:item_log>);
recipes.addShapeless(<cfm:item_log> * 8, [<ore:listAllAxe>.transformDamage(), <ore:logWood>]);


recipes.remove(<cfm:item_ink_cartridge>);
recipes.addShaped(<cfm:item_ink_cartridge>, [[<ore:stone>,<ore:stone>,<ore:stone>],
											 [<ore:stone>,<ore:dyeBlack>,<ore:stone>],
											 [<ore:stone>,<ore:stone>,<ore:stone>]]);


recipes.remove(<cfm:item_soap_water>);
recipes.addShapeless(<cfm:item_soap_water>, [<minecraft:water_bucket>.noReturn(),<cfm:item_soap>]);

recipes.addShapeless(<iceandfire:chared_cobblestone>, [<minecraft:blaze_powder>, <minecraft:cobblestone>]);
recipes.addShapeless(<iceandfire:chared_dirt>, [<minecraft:blaze_powder>, <minecraft:dirt:*>]);
recipes.addShapeless(<iceandfire:chared_grass>, [<minecraft:blaze_powder>, <minecraft:grass>]);
recipes.addShapeless(<iceandfire:chared_gravel>, [<minecraft:blaze_powder>, <minecraft:gravel>]);
recipes.addShapeless(<iceandfire:chared_stone>, [<minecraft:blaze_powder>, <minecraft:stone>]);

recipes.addShaped(<minecraft:sponge>, [[<minecraft:wool:4>,<minecraft:string>,<minecraft:wool:4>],
									   [<minecraft:string>,<minecraft:wool:4>,<minecraft:string>],
									   [<minecraft:wool:4>,<minecraft:string>,<minecraft:wool:4>]]);

furnace.addRecipe(<iceandfire:chared_dirt>, <minecraft:dirt:0>, 0.7);
furnace.addRecipe(<iceandfire:chared_grass>, <minecraft:grass>, 0.7);
furnace.addRecipe(<iceandfire:chared_gravel>, <minecraft:gravel>, 0.7);
furnace.addRecipe(<iceandfire:ash>, <minecraft:coal:1>, 0.7);

furnace.setFuel(<rainboaks:rainboak_sapling>, 100);

mods.immersiveengineering.Crusher.addRecipe(<exnihilocreatio:block_dust>, <minecraft:sand>, 1600);
mods.immersiveengineering.Crusher.addRecipe(<exnihilocreatio:block_granite_crushed>, <minecraft:stone:1>, 1600);
mods.immersiveengineering.Crusher.addRecipe(<exnihilocreatio:block_diorite_crushed>, <minecraft:stone:3>, 1600);
mods.immersiveengineering.Crusher.addRecipe(<exnihilocreatio:block_andesite_crushed>, <minecraft:stone:5>, 1600);
mods.immersiveengineering.Crusher.addRecipe(<exnihilocreatio:block_endstone_crushed>, <minecraft:end_stone>, 1600);
mods.immersiveengineering.Crusher.addRecipe(<exnihilocreatio:block_netherrack_crushed>, <minecraft:netherrack>, 1600);
mods.immersiveengineering.Crusher.addRecipe(<minecraft:sand:1>, <exnihilocreatio:block_granite_crushed>, 1600);

mods.immersiveengineering.Crusher.addRecipe(<immersiveengineering:metal:18> * 3, <ore:clusterIron>, 4500, <immersiveengineering:metal:13>, 1.0);
mods.immersiveengineering.Crusher.addRecipe(<immersiveengineering:metal:19> * 3, <ore:clusterGold>, 4500, <thaumcraft:nugget:10>, 1.0);
mods.immersiveengineering.Crusher.addRecipe(<immersiveengineering:metal:9> * 3, <ore:clusterCopper>, 4500, <immersiveengineering:metal:19>, 1.0);
mods.immersiveengineering.Crusher.addRecipe(<immersiveengineering:metal:12> * 3, <ore:clusterSilver>, 4500, <immersiveengineering:metal:11>, 1.0);
mods.immersiveengineering.Crusher.addRecipe(<immersiveengineering:metal:11> * 3, <ore:clusterLead>, 4500, <immersiveengineering:metal:12>, 1.0);
mods.immersiveengineering.Crusher.addRecipe(<minecraft:quartz> * 10, <ore:clusterQuartz>, 4500);