EXTERNAL camera_pan(x, y)

-> ivory_tower

=== function camera_pan(x, y)
    // north = positive y
    // south = negative y
    // east = positive x
    // west = negative x
    DEBUG: panning to [{x}, {y}]


=== ivory_tower ===
# coords:0,0
~ camera_pan(0, 0)

{You've arrived at an ivory tower. It has been visible for the last hour,\
 before you even knew there was a town to the east of it.\
 |You are in front of the ivory tower{sawmill or enter or entry_road: again}.}

+ {not enter} [look around]
    -> look
+ {enter} [enter] You open the door and step inside.
    -> enter
+ north
    -> woods
+ east
    -> tower_road
+ west
    -> sawmill
+ south
    -> entry_road

= look

It's tall and white because it's a tower of ivory. It's hard to see from\
where you stand but it looks like there's a telescope on the top floor.
There are two ways in to the tower: the top and the bottom.
* [Climb up the tower]
    -> climb
* [Enter through the front door]
You try entering the tower the straightforward way.
    -> enter
+ Never mind for now
    -> ivory_tower

= enter

The walls are white on the inside and covered with numerous intricately woven\
tapestries depicting battles and other historical events. {As you enter, you\
hear a sound. Seemingly from\
every direction and no direction at once, comes a pleasant musical\
chord\
|Once again, you hear a pleasant musical chord\
}<>, announcing your arrival. Moments later, a door opens and\
<> {an old wolf|the wizard} steps out to speak with you.

{speak_wizard: -> conversation}

* [speak with the wolf]
-> speak_wizard

+ [out]
"Never mind; I had the wrong street address."
-> ivory_tower

= climb
Evidently, you enjoy doing things the hard way. You start climbing the tower.
Then you lose your grip, fall down, and die.
Ouch.
-> END

= speak_wizard

He's a brown and gray wolf with streaks of white fur on his cheek and ear fur\
showing his age. He wears an ornate robe, identifying him as a wizard.\
Upon chatting with him, you discover that the wizard wolf is the protector of\
the town to the east. He crushes their enemies, they conduct business in\
peace, and pay him regular dues so he can enjoy studying astrology in his free\
time.
-> conversation

- (conversation)

* (astro) [Astrology?]
How exciting, you've met a real astrologer. You ask him a question that's been\
on your mind for some time. How is it that the constellations can have shifted\
over the centuries and yet everyone still gets the same signs in the same\
order as before?
"It's complicated," he says simply.
-> conversation

* (sleep) [Some place to sleep?]
You explain that you've been on the road for some time and would like a place\
to sleep this evening. The wolf informs you that there's an inn down the\
road to the east that charges reasonable prices.
-> conversation

+ [Leave]
With that, you step back outside to return to your adventure.
-> ivory_tower


=== entry_road ===
~ camera_pan(0, -1)

This is the road leading back the way from which you came. You\
take {|yet }another look\
around to make sure you didn't miss anything important but it's still just as\
dusty and disinteresting as before. You're glad to have returned to\
civilization.

+ north
-> ivory_tower


=== sawmill ===
~ camera_pan(-1, 0)

You are at a logging camp. A timber wolf wearing a rugged and slightly frayed\
and stained work outfit stands next to a wagon full of wooden\
beams, writing notes with a quill pen.

+ {not stereotype and not job_why} [talk to the wolf]
    -> speak_logger
+ north
    -> camp
+ east
    -> ivory_tower

= speak_logger

Upon speaking with the timber wolf, you discover that he works for a logging\
company that has a large and growing number of orders to fill and they're\
short-staffed.

- (speaking)

* (job) [Any jobs?]

{inn.sleep:In hopes of earning your way into a reasonable place to sleep\
tonight, y|Y}
<>ou ask the wolf if his company has any positions open. He says no.
"I thought you said you were short-staffed."
"We are but we still don't have any positions open."
-> speaking

* (job_why) {job} "Why don't you have any positions open?"

"You'll have to speak with the wizard about that. He lives in the ivory tower\
to the east."
{ivory_tower.speak_wizard:You nod. "Yes, we've met. |"}What does he have to do\
with this?"
"He's the protector of the town to the east and that protection extends out\
here. You'll just have to ask him for the details."
-> speaking

* ["Timber" wolf...]

"You look like you're a timber wolf?"
The wolf nods. "That's right. What of it?"
"And you're working here, of all places."
He appears confused. "Where are you going with this?"

* * (stereotype) [stereotypes]

"You don't have to be a stereotype, you know..."
"Stereotype? What are you talking about?"
"I mean, you can go into any\
profession you want but you're, you know... A timber wolf. Working at a\
logging company."
"Boy, what are you on about? I like working here."
He laughs softly and gets back to work.
-> sawmill

+ Leave
-> sawmill

=== camp ===
~ camera_pan(-1, 1)

You are at a logging camp. Lots of dead trees around here. But there's no one\
out working, even though it's day time with plenty of light.

+ east
    -> woods
+ south
    -> sawmill


=== tower_road ===
# coords:1,0
~ camera_pan(1, 0)

This is a dirt road with two bare tracks for wagon wheels. On either side and\
between them is grass.

+ north
    -> field
+ east
    -> inn
+ west
    -> ivory_tower


=== inn ===
# coords:2,0
~ camera_pan(2, 0)

You are at the inn.

+ in
    -> in_inn
+ north
    -> disciples
+ west
    -> tower_road

= in_inn

You are in the inn.

* (sleep) rent a room
The rooms here are 6 coppers per night. You have 5 coppers. You huff in\
frustration and leave. One copper was enough for a room and a breakfast treat\
when you were a young pup. That was before the wars started.
{ivory_tower.sleep:So much for "reasonable".}
-> inn

+ out
-> inn


=== field ===
# coords:1,1
~ camera_pan(1, 1)

This field west of town is covered mostly with grass. Dozens of very old and\
partially rotten tree stumps can be seen as well.

+ east
    -> disciples
+ west
    -> woods
+ south
    -> tower_road


=== woods ===
# coords:0,1
~ camera_pan(0, 1)

There are lots of trees and shrubs making it hard to\
see for any considerable distance. After some time, you feel like you've made\
wrong turns and despite multiple attempts to retrace your steps, you can't\
find your bearings.
It seems you are lost in the woods.

+ north
    -> again
+ east
    -> again
+ south
    -> again
+ west
    -> alt

= again

Trees all around. You are still lost in the woods.

+ north
    -> again
+ east
    -> again
+ south
    -> again
+ west
    Finally, you stumble upon a clearing.
    -> camp

= alt

Trees all around. You are still lost in the woods.

+ north
    -> alt
+ east
    -> alt
+ south
    Finally, you stumble upon a clearing.
    -> camp
+ west
    -> alt


=== disciples ===
# coords:2,1
~ camera_pan(2, 1)

{You've found|You are at} a brick building on a large lot overgrown with\
vegetation,\
all encircled by a tall wooden fence. A young cat sits on a chair next to the\
open gate.{no_meditation: She avoids making eye contact.}

- (top)

* [speak to the cat]
    -> speak
+ {speak} Step inside
    -> inside
+ west
    -> field
+ south
    -> inn

= speak

She hops up to her paws and beams at you. "Are you\
here for group meditation?"

- (again)

* * (explain) [What's that?]
You ask the cat what group meditation is.
"Ah, you're new around here, aren't you? Once a week, we get together to\
meditate\
and do our lessons and exercise. As Mrigesh - that's our leader - always\
says,\
a strong body makes a strong mind. And we must remain strong in order to stand\
against evil."
"Will you be there?"
-> again

* * (evil) {explain} [Stand against evil?] "You... stand against evil?"
"That's right. Ours is the only group standing against evil in this area.\
The other residents who live around here would be lost without us, because\
they are not enlightened."
-> again

* * {evil and ivory_tower.speak_wizard} [Wizard?] "What about the wolf\
who lives in the white tower?"
"The wizard? He refuses to protect us against new threats.\
I mean, don't get me wrong. We are definitely safer with him watching over us\
but he only knows how to smite large crowds from afar. With no armies to\
face, he won't do anything."
"Anyway, are you interested?"
-> again

* * (enlightened) {evil} [Enlightened?] "Enlightened?"
"We all try to meditate together on a regular basis in order to build and\
maintain enlightenment. That and following our leader Mrigesh. He is the most\
enlightened of us all."
-> again

* * {enlightened} [How does it work?] "Can you explain to me how it works?"
The cat smiles, showing off her well-polished fangs. "You're so analytical.\
It's hard to explain. It's better to\
just feel it for yourself."
-> again

* * [Yes]
{not explain:Without even knowing what you're getting into, y|Y}ou say that\
you will be there for group meditation. The cat flicks her tail excitedly\
and tells you that it will be right inside the brick building when it's time.
-> top

* * (no_meditation) [No]
You're not planning to be there. The cat looks disappointed and sits down.\
"May you find enlightenment before\
it's too late."
-> top

* * [Maybe]
Maybe you will, maybe you will have other things to do. The cat says she\
understands and looks forward to seeing you there if you do decide to show.
-> top

= inside

Inside the brick building, you find two foxes and a cat rearranging furniture.\
One of the foxes speaks up. "If you're looking for the group meditation, you're\
in the right place. But you're early. We like to start late in the\
evening so that we're released from intrusive thoughts."

+ out
-> disciples