Małek miner

@echo off
SETLOCAL EnableExtensions

set MINERPATH=E:\Zcash
set EXE=miner.exe
set varSeconds=30

set Server=eu1-zcash.flypool.org
set username=t1bAvSwSRN3TuMHkW271kUhz8Ep68HNL7n9
set workname=kombajnmachine
set password=x
set portvar=3333
set eexitvar=3
set feevar=0
set logvar=2

set varLops=0
set varSkip=0
set varRuns=0
set varForc=0

:aIsProcessRunning
@echo Miner Auto Start/Restart
@echo Loop-No - %varLops%
@echo Skipped - %varSkip%
@echo Re-Runs - %varRuns%
@echo Restart - %varForc%

TIMEOUT /T %varSeconds%
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% goto aProcessFound

goto aProcessNotFound

:aProcessFound
@echo %EXE% is Running...
@echo %EXE% skipping Start...
set /a varSkip=%varSkip%+1

REM Check for : 0 Sol/s state
findstr /c:": 0 Sol/s" "%MINERPATH%\miner.log"
if errorlevel 1 (
    echo 0 Sol/s state String NOT found...
) else (
    echo 0 Sol/s state String found
REM KILL Task %EXE%
set /a varForc=%varForc%+1
taskkill /f /im %EXE%
TIMEOUT /T 10
del "%MINERPATH%\miner.log"
)

@goto aLoopEND

:aProcessNotFound
@echo %EXE% is NOT Running...
@echo %EXE% attempt Start...
set /a varRuns=%varRuns%+1

REM Command Line
start /i /d "%MINERPATH%\" %EXE% --eexit %eexitvar% --server %Server% --user %username%.%workname% --pass %password% --port %portvar% --pec --fee %feevar% --log %logvar%

@goto aLoopEND

:aLoopEND
@echo Finished Loop...
@cls
set /a varLops=%varLops%+1

@goto aIsProcessRunning

:aExit
@pause