include "tileset.asm"

SECTION "Start", ROM0[$100]
EntryPoint:
   jp init

SECTION "VBLANK", ROM0[$040]
VBLANK:
   ;update oam
   call $FF80

   ;check collision
   call checkCollision

   ;check Input
   call checkInput
   reti

SECTION "Game", ROM0[$150]

checkCollision:
   ld a, [Ball_PosY]
   cp a, 144 + 9
   jp z, .end
   inc a
   ld [Ball_PosY], a
.end
   ret

checkInput:
   ld a, %00100000
   ld [$FF00], a
   ld a, [$FF00]
   cpl
   AND %00000001
   cp 0
   call z, moveLeft

   ld a, [$FF00]
   cpl
   AND %00000010
   cp 0
   call z, moveRight
   ret

moveRight:
   ld a, [Ball_PosX]
   inc a
   ld [Ball_PosX], a
   ret

moveLeft:
   ld a, [Ball_PosX]
   dec a
   ld [Ball_PosX], a
   ret

dma_copy:
    push af                ; store the old a and status reg (f) on the stack so we can use them for our own purposes
    ld a, $C0            ; OamData variable
    ldh [$FF46], a            ; once we put this address into the DMA register, the transfer will begin ($A0 bytes from $C000)

    ; now we want to delay for 160us while the data gets copied
    ; this uses a basic countdown-jump back loop
    ld a, $28            ; this is our countdown value ($28 to 0)
dma_copy_wait:
    dec a
    jr nz, dma_copy_wait        ; if a is not 0, jump back to the wait loop

    ; once we are here, the dma is all done
    pop af                ; restore af to its old value
    ret                ; and go back to what we were doing
dma_copy_end:

;hl = destination
;bc = ByteCount
;de = Source
memcopy:
  ld a, [de]
  ldi [hl], a
  dec bc
  inc de
  ld a, b
  or c
  jr nz, memcopy
  ret

;hl = destination
;bc = Source
;a = value
memset:
   push af
.repeat
   pop af
   ldi [hl], a
   dec bc
   push af
   ld a, b
   or c
   jr nz, .repeat
   pop af
   ret

WaitForVBLANK:
   ld a, [$FF44]
   cp a, 144
   jp nz, WaitForVBLANK
   ret

init:
   ;disable interrupts
   di

   ;disable screen
   call WaitForVBLANK
   ld a, 0
   ld [$FF40], a

   ;remoe Nintendo Logo from VRAM
   ld hl, $8000
   ld bc, $81A0 - $8000
   ld a, 0
   call memset

   ld hl, $9904
   ld bc, $9930 - $9904
   ld a, 0
   call memset

   ;clear OAM
   ld hl, $C000
   ld bc, $A0
   ld a, 0
   call memset

   ;draw background
   ld hl, $9000
   ld bc, Background_END - Background
   ld de, Background
   call memcopy

   ;draw Ball
   ld hl, $8000
   ld bc, Ball_END - Ball
   ld de, Ball
   call memcopy

   ;save ball values in WRAM
   ;set x coordinate
   ld hl, Ball_PosY
   ld a, 8
   ldi [hl], a
   ;set x coordinate
   ld a, 20
   ldi [hl], a

   ld a, 0
   ;set pattern
   ldi [hl], a

   ;set flags
   ldi [hl], a

   ; copy DMA function to HRAM
   ld hl, $FF80
   ld bc, dma_copy_end - dma_copy
   ld de, dma_copy
   call memcopy

   ;set color palette
   ld a, %11100100
   ld [$FF47], a
   ld [$FF48], a

   ;enable screen
   ld a, %10000011
   ld [$FF40], a

   ;enable interrupts
   ld a, %00000001
   ld [$FFFF], a
   ei

game:
   halt
   jp game

SECTION "OAM", WRAM0[$C000]
Ball_PosY: DS 1
Ball_PosX: DS 1
Ball_PatternNumber: DS 1
Ball_Flags: DS 1