API tools faq
paste
Advertisement
BDuck

Untitled

BDuck
Aug 19th, 2017
111
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
text 80.39 KB | None | 0 0
raw download clone embed print report
  1. #-------------------------------------------------------------------#
  2. # #
  3. # QTGMC 3.353, by Vit, 2012, 2016 mod by A.SONY #
  4. # #
  5. # A high quality deinterlacer using motion-compensated temporal #
  6. # smoothing, with a range of features for quality and convenience #
  7. # Originally based on TempGaussMC_beta2 by Did閑 #
  8. # #
  9. #-------------------------------------------------------------------#
  10. #
  11. # Full documentation is in the 'QTGMC' html file that comes with this script
  12. #
  13. # --- LATEST CHANGES ---
  14. #
  15. # v3.353s
  16. # - added ndjamena suggestion for maximum temporal radius
  17. # - added DftDither to controle dfttest dither Parameter
  18. #
  19. # v3.352s
  20. # - added useEdiExt
  21. # - added tr0=-1 to use the EdiExt clip (if there is no EdiExt clip then it will not work)
  22. # - rep0 now will be 0 if tr0 < 1
  23. #
  24. # v3.347s
  25. # - fix SourceMatch (bug after new YUY2 method, thanks to ndjamena for report it)
  26. #
  27. # v3.346s
  28. # - EEDI3+NNEDI3 bug fix by ndjamena
  29. # - Renamed DftThreads parameter to FftThreads, to set the ncpu argument of FFT3DFilter (from VS)
  30. # - FFT3DFilter will work now in YUY2, use it with Denoiser="fft3df" (or use NoisePreset)
  31. #
  32. # v3.345s
  33. # - work with SMDegrain_KNLMeansCL now to process chroma too
  34. #
  35. # v3.343s
  36. # - edit in ChromaEdi
  37. # - others
  38. #
  39. # v3.34s (mod) 2016 12 18 (ravewulf idea in another way)
  40. # - Added yadifmod2 (if you need old one use it like this EdiMode="cYadif" or EdiMode="RepcYadif")
  41. # - fast and clean up YUY2 (will work in x64 now, no need to SSETools)
  42. #
  43. # v3.33s (mod) 2016 12 06
  44. # - Add TR2=4 and TR2=5
  45. # - add TV_range bool and dither_luma_rebuild (from SMDegrain) Str and Amp
  46. # - for avsplus now QTGMC_Bob is ready for any 420, not only yv12
  47. #
  48. # v3.33s (mod) 2016 04 11
  49. # - Add KNLMeansCL as another Denoiser to NoiseProcess
  50. # - others
  51. #
  52. # v3.33s (mod) 2016 01 19
  53. # - make QTGMC_deflate/QTGMC_inflate work with YUY2 using masktool2 for avs 2.60
  54. #
  55. # v3.33s (mod) 2015 10 23
  56. # - revert to QTGMC_deflate/QTGMC_inflate quoted from Dogway
  57. #
  58. # v3.33s (mod) 2015 9 10
  59. # - fix Multiple QTGMC Calls
  60. # - others fix
  61. #
  62. # v3.33s (mod) 2015 8 6
  63. # - some changes in bob to speed up
  64. #
  65. # v3.33s (mod) 2015 8 4
  66. # - fix bug in YUY2 with SourceMatch
  67. # - add slice=false to ditherpost to avoid artefacts
  68. #
  69. # v3.33s (mod)
  70. # - fix bob chroma
  71. # - work with new masktool2 for avs 2.60 in YUY2
  72. #
  73. # v3.33d (mod)
  74. # - Added 32 bit precision option through the lsbd (for dfttest and knlmeanscl) and lsb (mdegrain) options.
  75. # - optimized some mask handling a bit as originally suggested by Vit
  76. # - others
  77. #
  78. # v3.33
  79. # - Increased maximum value for Rep0, Rep1 and Rep2 to 7 (from 5). Higher values help with flicker on static detail, potential for minor motion blur
  80. # - Bug fix for the fact that Bob always outputs a BFF clip regardless of field order of input (thanks ajp_anton)
  81. # - Improved generation of noise (NoiseDeint="Generate") for noise bypass / EZKeepGrain
  82. # - Minor change to denoising
  83. #
  84. # v3.32
  85. # - Bugfix with shutter blur and ChromaMotion (thanks Heaud)
  86. # - Tweaked vector recalculation for shutter motion blur
  87. # - Changed defaults for TR2 when using source-match
  88. # - Minor bugfix with SLMode/SLRad on pass-through settings
  89. #
  90. # --- REQUIREMENTS ---
  91. #
  92. # Input colorspaces: YV12, YUY2, others as plugins supports
  93. #
  94. # Core plugins:
  95. # MVTools2 (2.7.5.22 or above from pinterf https://github.com/pinterf/mvtools/releases)
  96. # MaskTools v2 (2.0b1 or above)
  97. # NNEDI3 (0.9.4.6 or above)
  98. # RgTools
  99. #
  100. # Additional plugins:
  101. # NNEDI2, NNEDI, EEDI3, EEDI2, TDeInt - if selected directly or via a source-match preset
  102. # yadifmod2 - for Preset="Ultra Fast" or if selected directly
  103. # FFT3DFilter - if selected for noise processing
  104. # dfttest (1.9.4 or above) - if selected for noise processing
  105. # For FFT3DFilter & ddftest you also need the FFTW3 library (FFTW.org). On Windows the file needed for both is libfftw3f-3.dll. However, for FFT3DFilter
  106. # the file needs to be called FFTW3.dll, so you will need two copies and rename one. On Windows put the files in your System32 or SysWow64 folder
  107. # KNLMeansCL - if selected for noise processing
  108. # AddGrainC - if NoiseDeint="Generate" selected for noise bypass
  109.  
  110.  
  111. # --- GETTING STARTED ---
  112. #
  113. # Install AviSynth and ensure you have at least the core plugins listed in the requirements section above. Put them in the plugins autoload folder.
  114. # To use QTGMC write a script like this:
  115. # YourSource("yourfile") # DGDecode_mpeg2source, FFVideoSource, AviSource, whatever your source requires
  116. # QTGMC( Preset="Slow" )
  117. # SelectEven() # Add this line to keep original frame rate, leave it out for smoother doubled frame rate
  118. #
  119. # Save this script with an ".avs" extension. You can now use it as an AVI source for encoding.
  120. #
  121. # The "Preset" used selects sensible settings for a given encoding speed. Choose a preset from:
  122. # "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast" & "Draft"
  123. # The default preset is "Slower"
  124. # Don't be obsessed with using slower settings as the differences can be small. HD material benefits little from extreme settings (and will be very slow)
  125. # For much faster speeds read the full documentation, the section on 'Multi-threading'
  126. #
  127. # There are many settings for tweaking the script, full details in the main documentation. You can display settings currently being used with "ShowSettings":
  128. # QTGMC( Preset="Slow", ShowSettings=true )
  129.  
  130.  
  131. function QTGMC( clip Input, string "Preset", int "TR0", int "TR1", int "TR2", int "Rep0", int "Rep1", int "Rep2", string "EdiMode", bool "RepChroma", \
  132. int "NNSize", int "NNeurons", int "EdiQual", int "EdiMaxD", string "ChromaEdi", int "EdiThreads", clip "EdiExt", float "Sharpness", \
  133. int "SMode", int "SLMode", int "SLRad", int "SOvs", float "SVThin", int "Sbb", int "SrchClipPP", int "SubPel", int "SubPelInterp", \
  134. int "BlockSize", int "Overlap", int "Search", int "SearchParam", int "PelSearch", bool "ChromaMotion", bool "TrueMotion", int "Lambda", \
  135. int "LSAD", int "PNew", int "PLevel", bool "GlobalMotion", int "DCT", int "ThSAD1", int "ThSAD2", int "ThSCD1", int "ThSCD2", \
  136. int "SourceMatch", string "MatchPreset", string "MatchEdi", string "MatchPreset2", string "MatchEdi2", int "MatchTR2", \
  137. float "MatchEnhance", int "Lossless", int "NoiseProcess", float "EZDenoise", float "EZKeepGrain", string "NoisePreset", string "Denoiser", \
  138. int "FftThreads", bool "DenoiseMC", int "NoiseTR", float "Sigma", bool "ChromaNoise", val "ShowNoise", float "GrainRestore", \
  139. float "NoiseRestore", string "NoiseDeint", bool "StabilizeNoise", int "InputType", float "ProgSADMask", int "FPSDivisor", \
  140. int "ShutterBlur", float "ShutterAngleSrc", float "ShutterAngleOut", int "SBlurLimit", bool "Border", bool "Precise", string "Tuning", \
  141. bool "ShowSettings", string "GlobalNames", string "PrevGlobals", int "ForceTR", \
  142. val "BT", val "DetailRestore", val "MotionBlur", val "MBlurLimit", val "NoiseBypass", float "Str", float "Amp", bool "TV_range", bool "useEdiExt", int "DftDither", bool "lsbd", bool "lsb" )
  143. {
  144. # EdiMode="RepcYadif"/"cYadif" require the Yadif plugin, which doesn't autoload. Typically the calling script would load it.
  145.  
  146. # Temporary Warnings
  147. Assert( !defined(BT), "QTGMC: Setting BT has been replaced by setting NoiseTR" )
  148. Assert( !defined(DetailRestore), "QTGMC: Setting DetailRestore has been renamed to GrainRestore" )
  149. Assert( !defined(MotionBlur), "QTGMC: Setting MotionBlur has been renamed to ShutterBlur" )
  150. Assert( !defined(MBlurLimit), "QTGMC: Setting MBlurLimit has been renamed to SBlurLimit" )
  151. Assert( !defined(NoiseBypass), "QTGMC: Setting NoiseBypass has been renamed to NoiseProcess" )
  152.  
  153. #---------------------------------------
  154. # Presets
  155. lsbd = default( lsbd, false)
  156. lsb = default( lsb, false)
  157. useEdiExt = default( useEdiExt, false)
  158. Str = default( Str, 1.0 )
  159. Amp = default( Amp, 0.0625 )
  160. TV_range = default( TV_range, true)
  161.  
  162. # Select presets / tuning
  163. Preset = default( Preset, "Slower" )
  164. pNum = (Preset == "Placebo" ) ? 0 : \
  165. (Preset == "Very Slow" ) ? 1 : \
  166. (Preset == "Slower" ) ? 2 : \
  167. (Preset == "Slow" ) ? 3 : \
  168. (Preset == "Medium" ) ? 4 : \
  169. (Preset == "Fast" ) ? 5 : \
  170. (Preset == "Faster" ) ? 6 : \
  171. (Preset == "Very Fast" ) ? 7 : \
  172. (Preset == "Super Fast") ? 8 : \
  173. (Preset == "Ultra Fast") ? 9 : \
  174. (Preset == "Draft" ) ? 10 : 11
  175. Assert( pNum < 11, "'Preset' choice is invalid" )
  176.  
  177. mpNum1 = (!defined(MatchPreset)) ? ((pNum + 3 <= 9) ? (pNum + 3) : 9) : \
  178. (MatchPreset == "Placebo" ) ? 0 : \
  179. (MatchPreset == "Very Slow" ) ? 1 : \
  180. (MatchPreset == "Slower" ) ? 2 : \
  181. (MatchPreset == "Slow" ) ? 3 : \
  182. (MatchPreset == "Medium" ) ? 4 : \
  183. (MatchPreset == "Fast" ) ? 5 : \
  184. (MatchPreset == "Faster" ) ? 6 : \
  185. (MatchPreset == "Very Fast" ) ? 7 : \
  186. (MatchPreset == "Super Fast") ? 8 : \
  187. (MatchPreset == "Ultra Fast") ? 9 : \
  188. (MatchPreset == "Draft" ) ? 10 : 11
  189. Assert( mpNum1 < 10, "'MatchPreset' choice is invalid/unsupported" )
  190. MatchPreset = Select( mpNum1, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  191.  
  192. mpNum2 = (!defined(MatchPreset2)) ? ((mpNum1 + 2 <= 9) ? (mpNum1 + 2) : 9) : \
  193. (MatchPreset2 == "Placebo" ) ? 0 : \
  194. (MatchPreset2 == "Very Slow" ) ? 1 : \
  195. (MatchPreset2 == "Slower" ) ? 2 : \
  196. (MatchPreset2 == "Slow" ) ? 3 : \
  197. (MatchPreset2 == "Medium" ) ? 4 : \
  198. (MatchPreset2 == "Fast" ) ? 5 : \
  199. (MatchPreset2 == "Faster" ) ? 6 : \
  200. (MatchPreset2 == "Very Fast" ) ? 7 : \
  201. (MatchPreset2 == "Super Fast") ? 8 : \
  202. (MatchPreset2 == "Ultra Fast") ? 9 : \
  203. (MatchPreset2 == "Draft" ) ? 10 : 11
  204. Assert( mpNum2 < 10, "'MatchPreset2' choice is invalid/unsupported" )
  205. MatchPreset2 = Select( mpNum2, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  206.  
  207. NoisePreset = default( NoisePreset, "Fast" )
  208. npNum = (NoisePreset == "Slower" ) ? 0 : \
  209. (NoisePreset == "Slow" ) ? 1 : \
  210. (NoisePreset == "Medium" ) ? 2 : \
  211. (NoisePreset == "Fast" ) ? 3 : \
  212. (NoisePreset == "Faster" ) ? 4 : 5
  213. Assert( npNum < 5, "'NoisePreset' choice is invalid" )
  214.  
  215. Tuning = default( Tuning, "None" )
  216. tNum = (Tuning == "None" ) ? 0 : \
  217. (Tuning == "DV-SD" ) ? 1 : \
  218. (Tuning == "DV-HD" ) ? 2 : 3
  219. Assert( tNum < 3, "'Tuning' choice is invalid" )
  220.  
  221. # Tunings only affect blocksize in this version
  222. bs = Select( tNum, 16, 16, 32 )
  223. bs2 = (bs >= 16) ? 32 : bs * 2
  224.  
  225. # Very Very Super Ultra
  226. # Preset groups: Placebo Slow Slower Slow Medium Fast Faster Fast Fast Fast Draft
  227. TR0 = default( TR0, Select( pNum, 2, 2, 2, 2, 2, 2, 1, 1, 1, 1, 0 ) )
  228. TR1 = default( TR1, Select( pNum, 2, 2, 2, 1, 1, 1, 1, 1, 1, 1, 1 ) )
  229. TR2X = default( TR2, Select( pNum, 3, 2, 1, 1, 1, 0, 0, 0, 0, 0, 0 ) )
  230. Rep0 = defined(Rep0) ? Rep0 : TR0 < 1 ? 0 : undefined()
  231. Rep0 = default( Rep0, Select( pNum, 4, 4, 4, 4, 3, 3, 0, 0, 0, 0, 0 ) )
  232. Rep1 = default( Rep1, Select( pNum, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ) )
  233. Rep2 = default( Rep2, Select( pNum, 4, 4, 4, 4, 4, 4, 4, 4, 3, 3, 0 ) )
  234. EdiMode = default( EdiMode, Select( pNum, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "RepYadif","Bob" ) )
  235. NNSize = default( NNSize, Select( pNum, 1, 1, 1, 1, 5, 5, 4, 4, 4, 4, 4 ) )
  236. NNeurons = default( NNeurons, Select( pNum, 2, 2, 1, 1, 1, 0, 0, 0, 0, 0, 0 ) )
  237. EdiQual = default( EdiQual, Select( pNum, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1 ) )
  238. EdiMaxD = default( EdiMaxD, Select( pNum, 12, 10, 8, 7, 7, 6, 6, 5, 4, 4, 4 ) )
  239. SMode = default( SMode, Select( pNum, 2, 2, 2, 2, 2, 2, 2, 2, 2, 2, 0 ) )
  240. SLModeX = default( SLMode, Select( pNum, 2, 2, 2, 2, 2, 2, 2, 2, 0, 0, 0 ) )
  241. SLRad = default( SLRad, Select( pNum, 3, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1 ) )
  242. Sbb = default( Sbb, Select( pNum, 3, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0 ) )
  243. SrchClipPP = default( SrchClipPP, Select( pNum, 3, 3, 3, 3, 3, 2, 2, 2, 1, 1, 0 ) )
  244. SubPel = default( SubPel, Select( pNum, 2, 2, 2, 2, 1, 1, 1, 1, 1, 1, 1 ) )
  245. Blocksize = default( Blocksize, Select( pNum, bs, bs, bs, bs, bs, bs, bs2, bs2, bs2, bs2, bs2 ) )
  246. bs = Blocksize
  247. Overlap = default( Overlap, Select( pNum, bs/2, bs/2, bs/2, bs/2, bs/2, bs/2, bs/2, bs/4, bs/4, bs/4, bs/4 ) )
  248. Search = default( Search, Select( pNum, 5, 4, 4, 4, 4, 4, 4, 4, 0, 0, 0 ) )
  249. SearchParam = default( SearchParam, Select( pNum, 2, 2, 2, 2, 2, 2, 2, 1, 1, 1, 1 ) )
  250. PelSearch = default( PelSearch, Select( pNum, 2, 2, 2, 2, 1, 1, 1, 1, 1, 1, 1 ) )
  251. ChromaMotion = default( ChromaMotion, Select( pNum, true, true, true, false, false, false, false, false, false, false, false ) )
  252. Precise = default( Precise, Select( pNum, true, true, false, false, false, false, false, false, false, false, false ) )
  253. ProgSADMask = default( ProgSADMask, Select( pNum, 10.0, 10.0, 10.0, 10.0, 10.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ) )
  254.  
  255. # Noise presets Slower Slow Medium Fast Faster
  256. Denoiser = default( Denoiser, Select( npNum, "dfttest", "dfttest", "dfttest", "fft3df", "fft3df" ) )
  257. DenoiseMC = default( DenoiseMC, Select( npNum, true, true, false, false, false ) )
  258. NoiseTR = default( NoiseTR, Select( npNum, 2, 1, 1, 1, 0 ) )
  259. NoiseDeint = default( NoiseDeint, Select( npNum, "Generate","Bob", "", "", "" ) )
  260. StabilizeNoise = default( StabilizeNoise, Select( npNum, true, true, true, false, false ) )
  261.  
  262. # The basic source-match step corrects and re-runs the interpolation of the input clip. So it initialy uses same interpolation settings as the main preset
  263. SourceMatch = default( SourceMatch, 0 )
  264. MatchNNSize = NNSize
  265. MatchNNeurons = NNeurons
  266. MatchEdiMaxD = EdiMaxD
  267. MatchEdiQual = EdiQual
  268.  
  269. # However, can use a faster initial interpolation when using source-match allowing the basic source-match step to "correct" it with higher quality settings
  270. Assert( SourceMatch == 0 || mpNum1 >= pNum, "'MatchPreset' cannot use a slower setting than 'Preset'" )
  271. # Very Very Super Ultra
  272. # Basic source-match presets Placebo Slow Slower Slow Medium Fast Faster Fast Fast Fast
  273. NNSize = (SourceMatch == 0) ? NNSize : Select( mpNum1, 1, 1, 1, 1, 5, 5, 4, 4, 4, 4 )
  274. NNeurons = (SourceMatch == 0) ? NNeurons : Select( mpNum1, 2, 2, 1, 1, 1, 0, 0, 0, 0, 0 )
  275. EdiMaxD = (SourceMatch == 0) ? EdiMaxD : Select( mpNum1, 12, 10, 8, 7, 7, 6, 6, 5, 4, 4 )
  276. EdiQual = (SourceMatch == 0) ? EdiQual : Select( mpNum1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1 )
  277. TempEdi = EdiMode # Main interpolation is actually done by basic-source match step when enabled, so a little swap and wriggle is needed
  278. EdiMode = (SourceMatch == 0) ? EdiMode : default( MatchEdi, ((mpNum1 < 9) ? EdiMode : "Yadif") ) # Force Yadif for "Ultra Fast" basic source match
  279. MatchEdi = TempEdi
  280.  
  281. # Very Very Super Ultra
  282. # Refined source-match presets Placebo Slow Slower Slow Medium Fast Faster Fast Fast Fast
  283. MatchEdi2 = default( MatchEdi2, Select( mpNum2, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "TDeint", "" ) )
  284. MatchNNSize2 = Select( mpNum2, 1, 1, 1, 1, 5, 5, 4, 4, 4, 4 )
  285. MatchNNeurons2 = Select( mpNum2, 2, 2, 1, 1, 1, 0, 0, 0, 0, 0 )
  286. MatchEdiMaxD2 = Select( mpNum2, 12, 10, 8, 7, 7, 6, 6, 5, 4, 4 )
  287. MatchEdiQual2 = Select( mpNum2, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1 )
  288.  
  289.  
  290. #---------------------------------------
  291. # Settings
  292.  
  293. # Core and Interpolation defaults
  294. TR2 = (SourceMatch > 0) ? default(TR2, ((TR2X == 0) ? 1 : TR2X)) : TR2X # ***TR2 defaults always at least 1 when using source-match***
  295. RepChroma = default( RepChroma, true )
  296. EdiThreads = default( EdiThreads, 0 )
  297. ChromaEdi = default( ChromaEdi, "" )
  298. NNeurons = (EdiMode == "NNEDI2" && NNeurons > 2) ? 2 : NNeurons # Smaller range for NNeurons in NNEDI2 (which calls it nsize)
  299. EdiQual = (EdiMode == "EEDI3+NNEDI3" || EdiMode == "NNEDI3") && EdiQual > 2 ? 2 : EdiQual # Smaller range for EdiQual in NNEDI3
  300.  
  301. # Source-match / lossless defaults
  302. MatchTR1 = TR1
  303. MatchTR2 = default( MatchTR2, 1 )
  304. MatchEnhance = default( MatchEnhance, 0.5 )
  305. Lossless = default( Lossless, 0 )
  306. Assert( Lossless <= 2, "Lossless setting only supports mode 1 ('true lossless') and mode 2 ('fake lossless') - see documentation in script and consider source-match settings" )
  307.  
  308. # Sharpness defaults. Sharpness default is always 1.0 (0.2 with source-match), but adjusted to give roughly same sharpness for all settings
  309. SMode = (defined(Sharpness) && Sharpness == 0.0) ? 0 : SMode
  310. SLMode = (SourceMatch > 0) ? default(SLMode, 0) : SLModeX # ***Sharpness limiting disabled by default for source-match***
  311. SLMode = (SLRad <= 0) ? 0 : SLMode
  312. spatialSL = (SLMode == 1 || SLMode == 3)
  313. temporalSL = (SLMode == 2 || SLMode == 4)
  314. Sharpness = default( Sharpness, (SMode == 0) ? 0.0 : ((SourceMatch > 0) ? 0.2 : 1.0) ) # Default sharpness is 1.0, or 0.2 if using source-match
  315. sharpMul = (temporalSL) ? 2 : (spatialSL) ? 1.5 : 1 # Adjust sharpness based on other settings
  316. sharpAdj = Sharpness * (sharpMul * (0.2 + TR1*0.15 + TR2*0.25) + ((SMode == 1) ? 0.1 : 0)) # [This needs a bit more refinement]
  317. Sbb = (SMode == 0) ? 0 : Sbb
  318. SOvs = default( SOvs, 0 )
  319. SVThin = default( SVThin, 0.0 )
  320.  
  321. # Noise processing settings
  322. Assert( !defined(EZDenoise) || EZDenoise <= 0.0 || !defined(EZKeepGrain) || EZKeepGrain <= 0.0, "QTGMC: EZDenoise and EZKeepGrain cannot be used together" )
  323. NoiseProcess = defined(NoiseProcess) ? NoiseProcess : \
  324. (defined(EZDenoise) && EZDenoise > 0.0) ? 1 : \
  325. (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 2 : \
  326. (Preset == "Placebo" || Preset == "Very Slow") ? 2 : 0
  327. GrainRestore = defined(GrainRestore) ? GrainRestore : \
  328. (defined(EZDenoise) && EZDenoise > 0.0) ? 0.0 : \
  329. (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.3 * sqrt(EZKeepGrain) : \
  330. Select( NoiseProcess, 0.0, 0.7, 0.3 )
  331. NoiseRestore = defined(NoiseRestore) ? NoiseRestore : \
  332. (defined(EZDenoise) && EZDenoise > 0.0) ? 0.0 : \
  333. (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.1 * sqrt(EZKeepGrain) : \
  334. Select( NoiseProcess, 0.0, 0.3, 0.1 )
  335. Sigma = defined(Sigma) ? Sigma : \
  336. (defined(EZDenoise) && EZDenoise > 0.0) ? EZDenoise : \
  337. (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 4.0 * EZKeepGrain : 2.0
  338. FftThreads = default( FftThreads, EdiThreads )
  339. ChromaNoise = default( ChromaNoise, false )
  340. ShowNoise = default( ShowNoise, 0.0 )
  341. ShowNoise = IsBool( ShowNoise ) ? (ShowNoise ? 10.0 : 0.0) : ShowNoise
  342. NoiseProcess = (ShowNoise > 0.0) ? 2 : NoiseProcess
  343. NoiseRestore = (ShowNoise > 0.0) ? 1.0 : NoiseRestore
  344. NoiseTR = (NoiseProcess == 0) ? 0 : NoiseTR
  345. GrainRestore = (NoiseProcess == 0) ? 0.0 : GrainRestore
  346. NoiseRestore = (NoiseProcess == 0) ? 0.0 : NoiseRestore
  347. totalRestore = GrainRestore + NoiseRestore
  348. StabilizeNoise = (totalRestore <= 0) ? false : StabilizeNoise
  349. noiseTD = Select( NoiseTR, 1, 3, 5 )
  350. noiseCentre = (Denoiser == "dfttest") ? "128" : "128.5"
  351.  
  352. # MVTools settings
  353. SubPelInterp = default( SubPelInterp, 2 )
  354. TrueMotion = default( TrueMotion, false )
  355. GlobalMotion = default( GlobalMotion, true )
  356. Lambda = default( Lambda, ((TrueMotion) ? 1000 : 100 ) * (BlockSize*BlockSize)/(8*8) )
  357. LSAD = default( LSAD, (TrueMotion) ? 1200 : 400 )
  358. PNew = default( PNew, (TrueMotion) ? 50 : 25 )
  359. PLevel = default( PLevel, (TrueMotion) ? 1 : 0 )
  360. DCT = default( DCT, 0 )
  361. ThSAD1 = default( ThSAD1, 10 * 8*8 )
  362. ThSAD2 = default( ThSAD2, 4 * 8*8 )
  363. ThSCD1 = default( ThSCD1, 180 )
  364. ThSCD2 = default( ThSCD2, 98 )
  365.  
  366. # Motion blur settings
  367. FPSDivisor = default( FPSDivisor, 1 )
  368. ShutterBlur = default( ShutterBlur, 0 )
  369. ShutterAngleSrc = default( ShutterAngleSrc, 180 )
  370. ShutterAngleOut = default( ShutterAngleOut, 180 )
  371. SBlurLimit = default( SBlurLimit, 4 )
  372. ShutterBlur = (ShutterAngleOut * FPSDivisor == ShutterAngleSrc) ? 0 : ShutterBlur # If motion blur output is same as input
  373.  
  374. # Miscellaneous
  375. InputType = default( InputType, 0 )
  376. Border = default( Border, false )
  377. ShowSettings = default( ShowSettings, false )
  378. GlobalNames = default( GlobalNames, "QTGMC" )
  379. PrevGlobals = default( PrevGlobals, "Replace" )
  380. ForceTR = default( ForceTR, 0 )
  381. ReplaceGlobals = (PrevGlobals == "Replace" || PrevGlobals == "Reuse") # If reusing existing globals put them back afterwards - simplifies logic later
  382. ReuseGlobals = (PrevGlobals == "Reuse")
  383. ProgSADMask = (InputType != 2 && InputType != 3) ? 0.0 : ProgSADMask
  384. rgBlur = (Precise) ? 11 : 12
  385.  
  386. # Get maximum temporal radius needed
  387. maxTR = (temporalSL) ? SLRad : 0
  388. maxTR = max(MatchTR2, maxTR)
  389. maxTR = max(TR1, maxTR)
  390. maxTR = max(TR2, maxTR)
  391. maxTR = max(NoiseTR, maxTR)
  392. maxTR = (ProgSADMask > 0.0 || StabilizeNoise || ShutterBlur > 0) ? (maxTR > 1 ? maxTR : 1) : maxTR
  393. maxTR = max(ForceTR, MaxTR)
  394.  
  395.  
  396. #---------------------------------------
  397. # Pre-Processing
  398.  
  399. w = Input.Width()
  400. h = Input.Height()
  401. yuy2 = Input.IsYUY2()
  402. epsilon = 0.0001
  403.  
  404. # Reverse "field" dominance for progressive repair mode 3 (only difference from mode 2)
  405. compl = (InputType == 3) ? Input.ComplementParity() : Input
  406.  
  407. # Pad vertically during processing (to prevent artefacts at top & bottom edges)
  408. clip = (Border) ? compl.PointResize( w,h+8, 0,-4,0,h+8+epsilon ) : compl
  409. h = (Border) ? h+8 : h
  410.  
  411. # Calculate padding needed for MVTools super clips to avoid crashes [fixed in latest MVTools, but keeping this code for a while]
  412. hpad = w - (Int((w - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  413. vpad = h - (Int((h - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  414. hpad = (hpad > 8) ? hpad : 8 # But match default padding if possible
  415. vpad = (vpad > 8) ? vpad : 8
  416.  
  417.  
  418. #---------------------------------------
  419. # Motion Analysis
  420.  
  421. # >>> Planar YUY2 for motion analysis, interleaved whilst blurring search clip
  422. planarClip = yuy2 ? clip.converttoyv16() : clip
  423.  
  424. # Bob the input as a starting point for motion search clip
  425. bobbed = (InputType == 0) ? useEdiExt ? isyuy2(EdiExt) ? EdiExt.converttoyv16() : EdiExt : planarClip.QTGMC_Bob( 0,0.5 ) : \
  426. (InputType == 1) ? planarClip : \
  427. planarClip.Blur( 0,1 )
  428.  
  429. # If required, get any existing global clips with a matching "GlobalNames" setting. Unmatched values get NOP (= 0)
  430. srchClip = QTGMC_GetUserGlobal( GlobalNames, "srchClip", ReuseGlobals )
  431. srchSuper = QTGMC_GetUserGlobal( GlobalNames, "srchSuper", ReuseGlobals )
  432. bVec1 = QTGMC_GetUserGlobal( GlobalNames, "bVec1", ReuseGlobals )
  433. fVec1 = QTGMC_GetUserGlobal( GlobalNames, "fVec1", ReuseGlobals )
  434. bVec2 = QTGMC_GetUserGlobal( GlobalNames, "bVec2", ReuseGlobals )
  435. fVec2 = QTGMC_GetUserGlobal( GlobalNames, "fVec2", ReuseGlobals )
  436. bVec3 = QTGMC_GetUserGlobal( GlobalNames, "bVec3", ReuseGlobals )
  437. fVec3 = QTGMC_GetUserGlobal( GlobalNames, "fVec3", ReuseGlobals )
  438. bVec4 = QTGMC_GetUserGlobal( GlobalNames, "bVec4", ReuseGlobals )
  439. fVec4 = QTGMC_GetUserGlobal( GlobalNames, "fVec4", ReuseGlobals )
  440. bVec5 = QTGMC_GetUserGlobal( GlobalNames, "bVec5", ReuseGlobals )
  441. fVec5 = QTGMC_GetUserGlobal( GlobalNames, "fVec5", ReuseGlobals )
  442.  
  443. CMmt = ChromaMotion ? 3 : 1
  444. CMts = ChromaMotion ? 255 : 0
  445. CMrg = ChromaMotion ? 12 : -1
  446.  
  447. # The bobbed clip will shimmer due to being derived from alternating fields. Temporally smooth over the neighboring frames using a binomial kernel. Binomial
  448. # kernels give equal weight to even and odd frames and hence average away the shimmer. The two kernels used are [1 2 1] and [1 4 6 4 1] for radius 1 and 2.
  449. # These kernels are approximately Gaussian kernels, which work well as a prefilter before motion analysis (hence the original name for this script)
  450. # Create linear weightings of neighbors first -2 -1 0 1 2
  451. ts1 = (!IsClip(srchClip) && TR0 > 0) ? bobbed.TemporalSoften( 1, 255,CMts, 28, 2 ) : NOP() # 0.00 0.33 0.33 0.33 0.00
  452. ts2 = (!IsClip(srchClip) && TR0 > 1) ? bobbed.TemporalSoften( 2, 255,CMts, 28, 2 ) : NOP() # 0.20 0.20 0.20 0.20 0.20
  453.  
  454. # Combine linear weightings to give binomial weightings - TR0=0: (1), TR0=1: (1:2:1), TR0=2: (1:4:6:4:1)
  455. binomial0 = IsClip(srchClip) ? NOP() : \
  456. TR0 == -1 && defined(EdiExt) ? isyuy2(EdiExt) ? EdiExt.converttoyv16() : EdiExt : \
  457. (TR0 == 0) ? bobbed : \
  458. (TR0 == 1) ? (ChromaMotion ? ts1.Merge( bobbed, 0.25 ) : ts1.MergeLuma( bobbed, 0.25 )) : \
  459. (ChromaMotion ? ts1.Merge( ts2, 0.357 ).Merge( bobbed, 0.125 ) : ts1.MergeLuma( ts2, 0.357 ).MergeLuma( bobbed, 0.125 ))
  460.  
  461. # Remove areas of difference between temporal blurred motion search clip and bob that are not due to bob-shimmer - removes general motion blur
  462. repair0 = (IsClip(srchClip) || Rep0 == 0) ? binomial0 : binomial0.QTGMC_KeepOnlyBobShimmerFixes( bobbed, Rep0, (RepChroma && ChromaMotion) )
  463.  
  464. # Blur image and soften edges to assist in motion matching of edge blocks. Blocks are matched by SAD (sum of absolute differences between blocks), but even
  465. # a slight change in an edge from frame to frame will give a high SAD due to the higher contrast of edges
  466. spatialBlur = (IsClip(srchClip) || SrchClipPP == 0) ? NOP() : \
  467. (SrchClipPP == 1) ? repair0.BilinearResize( w/2, h/2 ).RemoveGrain( 12,CMrg).BilinearResize( w, h ) : \
  468. repair0.RemoveGrain( 12,CMrg).GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 )
  469.  
  470. spatialBlur = (IsClip(spatialBlur) && SrchClipPP > 1) ? (ChromaMotion ? spatialBlur.Merge( repair0, 0.1 ) : spatialBlur.MergeLuma( repair0, 0.1 )) : spatialBlur
  471. tweaked = (!IsClip(srchClip) && SrchClipPP > 1) ? mt_lutxy( repair0, bobbed, "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt ) : NOP()
  472. srchcheck = IsClip(srchClip)
  473. srchClip = srchcheck ? srchClip : \
  474. (SrchClipPP == 0) ? repair0 : \
  475. (SrchClipPP < 3) ? spatialBlur : \
  476. spatialBlur.mt_lutxy( tweaked, "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt )
  477. srchClip = tv_range && !srchcheck ? srchClip.Dither_Luma_Rebuild(S0=Str,c=Amp,slice=false,lsb=lsb,uv=CMmt) : srchClip
  478. # Calculate forward and backward motion vectors from motion search clip
  479. srchSuper = IsClip(srchSuper) ? srchSuper : \
  480. (maxTR > 0) ? srchClip.MSuper( pel=SubPel, sharp=SubPelInterp, hpad=hpad, vpad=vpad, chroma=ChromaMotion ) : NOP()
  481. bVec5 = IsClip(bVec5) ? bVec5 : \
  482. (maxTR > 4) ? srchSuper.MAnalyse( isb=true, delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  483. pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  484. global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  485. bVec4 = IsClip(bVec4) ? bVec4 : \
  486. (maxTR > 3) ? srchSuper.MAnalyse( isb=true, delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  487. pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  488. global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  489. bVec3 = IsClip(bVec3) ? bVec3 : \
  490. (maxTR > 2) ? srchSuper.MAnalyse( isb=true, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  491. pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  492. global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  493. bVec2 = IsClip(bVec2) ? bVec2 : \
  494. (maxTR > 1) ? srchSuper.MAnalyse( isb=true, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  495. pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  496. global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  497. bVec1 = IsClip(bVec1) ? bVec1 : \
  498. (maxTR > 0) ? srchSuper.MAnalyse( isb=true, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  499. pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  500. global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  501. fVec1 = IsClip(fVec1) ? fVec1 : \
  502. (maxTR > 0) ? srchSuper.MAnalyse( isb=false, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  503. pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  504. global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  505. fVec2 = IsClip(fVec2) ? fVec2 : \
  506. (maxTR > 1) ? srchSuper.MAnalyse( isb=false, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  507. pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  508. global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  509. fVec3 = IsClip(fVec3) ? fVec3 : \
  510. (maxTR > 2) ? srchSuper.MAnalyse( isb=false, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  511. pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  512. global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  513. fVec4 = IsClip(fVec4) ? fVec4 : \
  514. (maxTR > 3) ? srchSuper.MAnalyse( isb=false, delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  515. pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  516. global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  517. fVec5 = IsClip(fVec5) ? fVec5 : \
  518. (maxTR > 4) ? srchSuper.MAnalyse( isb=false, delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  519. pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  520. global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  521.  
  522. # Expose search clip, motion search super clip and motion vectors to calling script through globals
  523. QTGMC_SetUserGlobal( GlobalNames, "srchClip", srchClip, ReplaceGlobals )
  524. QTGMC_SetUserGlobal( GlobalNames, "srchSuper", srchSuper, ReplaceGlobals )
  525. QTGMC_SetUserGlobal( GlobalNames, "bVec1", bVec1, ReplaceGlobals )
  526. QTGMC_SetUserGlobal( GlobalNames, "fVec1", fVec1, ReplaceGlobals )
  527. QTGMC_SetUserGlobal( GlobalNames, "bVec2", bVec2, ReplaceGlobals )
  528. QTGMC_SetUserGlobal( GlobalNames, "fVec2", fVec2, ReplaceGlobals )
  529. QTGMC_SetUserGlobal( GlobalNames, "bVec3", bVec3, ReplaceGlobals )
  530. QTGMC_SetUserGlobal( GlobalNames, "fVec3", fVec3, ReplaceGlobals )
  531. QTGMC_SetUserGlobal( GlobalNames, "bVec4", bVec4, ReplaceGlobals )
  532. QTGMC_SetUserGlobal( GlobalNames, "fVec4", fVec4, ReplaceGlobals )
  533. QTGMC_SetUserGlobal( GlobalNames, "bVec5", bVec5, ReplaceGlobals )
  534. QTGMC_SetUserGlobal( GlobalNames, "fVec5", fVec5, ReplaceGlobals )
  535.  
  536.  
  537. #---------------------------------------
  538. # Noise Processing
  539.  
  540. # >>>> Interleaved YUY2 for denoising, planar whilst pre-motion compensating
  541.  
  542. # Expand fields to full frame size before extracting noise (allows use of motion vectors which are frame-sized)
  543. fullClip = (NoiseProcess == 0) ? NOP() : \
  544. (InputType > 0) ? clip : \
  545. clip.QTGMC_Bob( 0,1.0 )
  546. fullClip = (yuy2 && NoiseTR > 0) ? fullClip.converttoyv16() : fullClip
  547. fullSuper = (NoiseTR > 0) ? fullClip.MSuper( pel=SubPel, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP() #TEST chroma OK?
  548.  
  549. # Create a motion compensated temporal window around current frame and use to guide denoisers
  550. noiseWindow = (NoiseProcess == 0) ? NOP() : \
  551. (!DenoiseMC) ? fullClip : \
  552. (NoiseTR == 0) ? fullClip : \
  553. (NoiseTR == 1) ? Interleave( fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  554. fullClip, \
  555. fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) ) : \
  556. Interleave( fullClip.MCompensate( fullSuper, fVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  557. fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  558. fullClip, \
  559. fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  560. fullClip.MCompensate( fullSuper, bVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ) )
  561. noiseWindow = yuy2 && (Denoiser == "fft3df") && NoiseTR > 0 ? noiseWindow.ConvertToYUY2() : noiseWindow
  562. dnWindow = (NoiseProcess == 0) ? NOP() : \
  563. (Denoiser == "dfttest") ? noiseWindow.dfttest( Y=true, U=ChromaNoise, V=ChromaNoise, sigma=Sigma*4, tbsize=noiseTD, threads=FftThreads, Dither=DftDither, lsb=lsbd ) : \
  564. (Denoiser == "KNLMeansCL") ? noiseWindow.SMDegrain_KNLMeansCL(Chroma=ChromaNoise, lsb=lsbd, a=2, d=NoiseTR, h=Sigma, device_type="GPU" ) : \
  565. noiseWindow.FFT3DFilter( plane=(ChromaNoise ? 4 : 0), sigma=Sigma, bt=noiseTD, ncpu=FftThreads )
  566. dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && lsbd ? dnWindow.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false) : dnWindow
  567. dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && yuy2 ? dnWindow.ConvertToYUY2() : dnWindow
  568.  
  569. # Rework denoised clip to match source format - various code paths here: discard the motion compensation window, discard doubled lines (from point resize)
  570. # Also reweave to get interlaced noise if source was interlaced (could keep the full frame of noise, but it will be poor quality from the point resize)
  571. denoised = (NoiseProcess == 0) ? NOP() : \
  572. (!DenoiseMC) ? ((InputType > 0) ? dnWindow : dnWindow.SeparateFields().SelectEvery( 4, 0,3 ).Weave()) : \
  573. (InputType > 0) ? ((NoiseTR == 0) ? dnWindow : dnWindow.SelectEvery( noiseTD, NoiseTR )) : \
  574. dnWindow.SeparateFields().SelectEvery( noiseTD*4, NoiseTR*2,NoiseTR*6+3 ).Weave()
  575.  
  576. # >>>> Switch to planar YUY2 for noise bypass
  577.  
  578. CNmt1 = ChromaNoise ? 3 : 1
  579. CNmt2 = ChromaNoise ? 3 : 2
  580. CNmt128 = ChromaNoise ? 3 : -128
  581.  
  582. # Get actual noise from difference. Then 'deinterlace' where we have weaved noise - create the missing lines of noise in various ways
  583. planarDenoised = (NoiseProcess == 0) ? NOP() : yuy2 ? denoised.converttoyv16() : denoised
  584. noise = (totalRestore > 0.0) ? mt_makediff( planarClip, planarDenoised, U=CNmt1,V=CNmt1 ) : NOP()
  585. deintNoise = (NoiseProcess == 0 || totalRestore == 0.0) ? NOP() : \
  586. (InputType != 0) ? noise : \
  587. (NoiseDeint == "Bob") ? noise.QTGMC_Bob( 0,0.5 ) : \
  588. (NoiseDeint == "Generate") ? noise.QTGMC_Generate2ndFieldNoise( denoised, ChromaNoise ) : \
  589. noise.DoubleWeave()
  590. # Motion-compensated stabilization of generated noise
  591. noiseSuper = (StabilizeNoise) ? deintNoise.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP()
  592. mcNoise = (StabilizeNoise) ? deintNoise.MCompensate( noiseSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  593. finalNoise = (StabilizeNoise) ? mt_lutxy( deintNoise, mcNoise, "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ) : deintNoise
  594.  
  595. # If NoiseProcess=1 denoise input clip. If NoiseProcess=2 leave noise in the clip and let the temporal blurs "denoise" it for a stronger effect
  596. innerClip = (NoiseProcess == 1) ? denoised : clip
  597.  
  598.  
  599. #---------------------------------------
  600. # Interpolation
  601.  
  602. # >>>> Interleaved YUY2 for interpolation
  603.  
  604. # Support badly deinterlaced progressive content - drop half the fields and reweave to get 1/2fps interlaced stream appropriate for QTGMC processing
  605. ediInput = (InputType == 2 || InputType == 3) ? innerClip.SeparateFields().SelectEvery(4,0,3).Weave() : innerClip
  606.  
  607. # Create interpolated image as starting point for output
  608. edi1 = defined(EdiExt) ? EdiExt.PointResize( w,h, 0,(EdiExt.Height()-h)/2, -0,h+epsilon ) : \
  609. QTGMC_Interpolate( ediInput, InputType, EdiMode, NNSize, NNeurons, EdiQual, EdiMaxD, EdiThreads, bobbed, ChromaEdi )
  610.  
  611. # >>>> Switch to planar YUY2 during next step - remains planar until very end of script except blurring for back blending & SVThin
  612.  
  613. # InputType=2,3: use motion mask to blend luma between original clip & reweaved clip based on ProgSADMask setting. Use chroma from original clip in any case
  614. inputTypeBlend = (ProgSADMask > 0.0) ? MMask( srchClip, bVec1, kind=1, ml=ProgSADMask ) : NOP()
  615. edi = (InputType != 2 && InputType != 3) ? (!yuy2 ? edi1 : edi1.ConvertToYV16()) :\
  616. (ProgSADMask <= 0.0) ? (!yuy2 ? edi1.MergeChroma( innerClip ) : edi1.MergeChroma( innerClip ).ConvertToYV16()) : \
  617. (!yuy2 ? mt_merge( innerClip, edi1, inputTypeBlend, U=2,V=2 ) : \
  618. mt_merge( innerClip.ConvertToYV16(), edi1.ConvertToYV16(), inputTypeBlend, U=2,V=2 ))
  619.  
  620. # Get the max/min value for each pixel over neighboring motion-compensated frames - used for temporal sharpness limiting
  621. ediSuper = (TR1 > 0 || temporalSL) ? edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  622. bComp1 = (temporalSL) ? edi.MCompensate( ediSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  623. fComp1 = (temporalSL) ? edi.MCompensate( ediSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  624. tMax = (temporalSL) ? edi.mt_logic( fComp1, "max", U=3,V=3 ).mt_logic( bComp1, "max", U=3,V=3 ) : NOP()
  625. tMin = (temporalSL) ? edi.mt_logic( fComp1, "min", U=3,V=3 ).mt_logic( bComp1, "min", U=3,V=3 ) : NOP()
  626. bComp3 = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, bVec3, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  627. fComp3 = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, fVec3, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  628. tMax = (SLRad > 1 && temporalSL) ? tMax.mt_logic( fComp3, "max", U=3,V=3 ).mt_logic( bComp3, "max", U=3,V=3 ) : tMax
  629. tMin = (SLRad > 1 && temporalSL) ? tMin.mt_logic( fComp3, "min", U=3,V=3 ).mt_logic( bComp3, "min", U=3,V=3 ) : tMin
  630.  
  631.  
  632. #---------------------------------------
  633. # Create basic output
  634.  
  635. # Use motion vectors to blur interpolated image (edi) with motion-compensated previous and next frames. As above, this is done to remove shimmer from
  636. # alternate frames so the same binomial kernels are used. However, by using motion-compensated smoothing this time we avoid motion blur. The use of
  637. # MDegrain1 (motion compensated) rather than TemporalSmooth makes the weightings *look* different, but they evaluate to the same values
  638. # Create linear weightings of neighbors first -2 -1 0 1 2
  639. degrain1 = (TR1 > 0) ? edi.MDegrain1( ediSuper, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP() # 0.00 0.33 0.33 0.33 0.00
  640. degrain2 = (TR1 > 1) ? edi.MDegrain1( ediSuper, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP() # 0.33 0.00 0.33 0.00 0.33
  641. degrain1 = (TR1 > 0) && lsb ? degrain1.ditherpost(mode=6, slice=false) : degrain1
  642. degrain2 = (TR1 > 1) && lsb ? degrain2.ditherpost(mode=6, slice=false) : degrain2
  643.  
  644. # Combine linear weightings to give binomial weightings - TR1=0: (1), TR1=1: (1:2:1), TR1=2: (1:4:6:4:1)
  645. binomial1 = (TR1 == 0) ? edi : \
  646. (TR1 == 1) ? degrain1.Merge( edi, 0.25 ) : \
  647. degrain1.Merge( degrain2, 0.2 ).Merge( edi, 0.0625 )
  648.  
  649. # Remove areas of difference between smoothed image and interpolated image that are not bob-shimmer fixes: repairs residual motion blur from temporal smooth
  650. repair1 = (Rep1 == 0) ? binomial1 : binomial1.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep1, RepChroma )
  651.  
  652. # Apply source match - use difference between output and source to succesively refine output [extracted to function to clarify main code path]
  653. match = (SourceMatch == 0) ? repair1 : \
  654. repair1.QTGMC_ApplySourceMatch( InputType, ediInput, bVec1,fVec1, bVec2,fVec2, SubPel, SubPelInterp, hpad, vpad, \
  655. ThSAD1, ThSCD1, ThSCD2, SourceMatch, MatchTR1, MatchEdi, MatchNNSize, MatchNNeurons, \
  656. MatchEdiQual, MatchEdiMaxD, MatchTR2, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, \
  657. MatchEdiMaxD2, MatchEnhance, EdiThreads, lsb )
  658.  
  659. # Lossless=2 - after preparing an interpolated, de-shimmered clip, restore the original source fields into it and clean up any artefacts.
  660. # This mode will not give a true lossless result because the resharpening and final temporal smooth are still to come, but it will add further detail.
  661. # However, it can introduce minor combing. This setting is best used together with source-match (it's effectively the final source-match stage).
  662. lossed1 = (Lossless == 2) ? QTGMC_MakeLossless( match, innerClip, InputType ) : match
  663.  
  664.  
  665. #---------------------------------------
  666. # Resharpen / retouch output
  667.  
  668. # Resharpen to counteract temporal blurs. Little sharpening needed for source-match mode since it has already recovered sharpness from source
  669. vresharp1 = (SMode == 2) ? Merge( lossed1.mt_expand( mode="vertical", U=3,V=3 ), lossed1.mt_inpand( mode="vertical", U=3,V=3 ) ) : NOP()
  670. vresharp = (Precise && SMode == 2) ? vresharp1.mt_lutxy( lossed1, "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ) : vresharp1 # Precise mode: reduce tiny overshoot
  671. resharp = (SMode == 0) ? lossed1 : \
  672. (SMode == 1) ? lossed1.mt_lutxy( lossed1.RemoveGrain( rgBlur ), "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ) : \
  673. lossed1.mt_lutxy( vresharp.RemoveGrain( rgBlur ), "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 )
  674.  
  675. # Slightly thin down 1-pixel high horizontal edges that have been widened into neigboring field lines by the interpolator
  676. SVThinSc = SVThin * 6.0
  677. vertMedD = (SVthin > 0.0) ? mt_lutxy( lossed1, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1 ), "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ) : NOP()
  678. vertMedD = (SVthin > 0.0) ? (vertMedD.Blur( 1,0 )) : NOP()
  679. neighborD = (SVthin > 0.0) ? mt_lutxy( vertMedD, vertMedD.RemoveGrain( rgBlur,-1 ), "y 128 - abs x 128 - abs > y 128 ?" ) : NOP()
  680. thin = (SVthin > 0.0) ? resharp.mt_adddiff( neighborD, U=2,V=2 ) : resharp
  681.  
  682. # Back blend the blurred difference between sharpened & unsharpened clip, before (1st) sharpness limiting (Sbb == 1,3). A small fidelity improvement
  683. backBlend1 = (Sbb != 1 && Sbb != 3) ? thin : \
  684. thin.mt_makediff( mt_makediff( thin, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  685. .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  686.  
  687. # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  688. # Occurs here (before final temporal smooth) if SLMode == 1,2. This location will restrict sharpness more, but any artefacts introduced will be smoothed
  689. sharpLimit1 = (SLMode == 1) ? backBlend1.Repair( ((SLrad <= 1) ? edi : backBlend1.Repair( edi, 12 )), 1 ) : \
  690. (SLMode == 2) ? backBlend1.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  691. backBlend1
  692.  
  693. # Back blend the blurred difference between sharpened & unsharpened clip, after (1st) sharpness limiting (Sbb == 2,3). A small fidelity improvement
  694. backBlend2 = (Sbb < 2) ? sharpLimit1 : \
  695. sharpLimit1.mt_makediff( mt_makediff( sharpLimit1, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  696. .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  697.  
  698. # Add back any extracted noise, prior to final temporal smooth - this will restore detail that was removed as "noise" without restoring the noise itself
  699. # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  700. addNoise1 = (GrainRestore <= 0.0) ? backBlend2 : \
  701. backBlend2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  702.  
  703. # Final light linear temporal smooth for denoising
  704. stableSuper = (TR2 > 0) ? addNoise1.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  705. stable = (TR2 == 0) ? addNoise1 : \
  706. (TR2 == 1) ? addNoise1.MDegrain1( stableSuper, bVec1,fVec1, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  707. (TR2 == 2) ? addNoise1.MDegrain2( stableSuper, bVec1,fVec1, bVec2,fVec2, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  708. (TR2 == 3) ? addNoise1.MDegrain3( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  709. (TR2 == 4) ? addNoise1.MDegrain4( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  710. addNoise1.MDegrain5( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4, bVec5,fVec5, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb )
  711. stable = (TR2 > 0) && lsb ? stable.ditherpost(mode=6, slice=false) : stable
  712.  
  713. # Remove areas of difference between final output & basic interpolated image that are not bob-shimmer fixes: repairs motion blur caused by temporal smooth
  714. repair2 = (Rep2 == 0) ? stable : stable.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep2, RepChroma )
  715.  
  716. # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  717. # Occurs here (after final temporal smooth) if SLMode == 3,4. Allows more sharpening here, but more prone to introducing minor artefacts
  718. sharpLimit2 = (SLMode == 3) ? repair2.Repair( ((SLrad <= 1) ? edi : repair2.Repair( edi, 12 )), 1 ) : \
  719. (SLMode == 4) ? repair2.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  720. repair2
  721.  
  722. # Lossless=1 - inject source fields into result and clean up inevitable artefacts. Provided NoiseRestore=0.0 or 1.0, this mode will make the script result
  723. # properly lossless, but this will retain source artefacts and cause some combing (where the smoothed deinterlace doesn't quite match the source)
  724. lossed2 = (Lossless == 1) ? QTGMC_MakeLossless( sharpLimit2, innerClip, InputType ) : sharpLimit2
  725.  
  726. # Add back any extracted noise, after final temporal smooth. This will appear as noise/grain in the output
  727. # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  728. addNoise2 = (NoiseRestore <= 0.0) ? lossed2 : \
  729. lossed2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  730.  
  731.  
  732. #---------------------------------------
  733. # Post-Processing
  734.  
  735. # Shutter motion blur - get level of blur depending on output framerate and blur already in source
  736. blurLevel = (ShutterAngleOut * FPSDivisor - ShutterAngleSrc) * 100.0 / 360.0
  737. Assert( blurLevel >= 0, "Cannot reduce motion blur already in source: increase ShutterAngleOut or FPSDivisor" )
  738. Assert( blurLevel <= 200, "Exceeded maximum motion blur level: decrease ShutterAngleOut or FPSDivisor" )
  739.  
  740. # ShutterBlur mode 2,3 - get finer resolution motion vectors to reduce blur "bleeding" into static areas
  741. rBlockDivide = Select( ShutterBlur, 1, 1, 2, 4 )
  742. rBlockSize = BlockSize / rBlockDivide
  743. rOverlap = Overlap / rBlockDivide
  744. rBlockSize = (rBlockSize < 4) ? 4 : rBlockSize
  745. rOverlap = (rOverlap < 2) ? 2 : rOverlap
  746. rBlockDivide = BlockSize / rBlockSize
  747. rLambda = Lambda / (rBlockDivide * rBlockDivide)
  748. sbBVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( bVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  749. truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : bVec1
  750. sbFVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( fVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  751. truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : fVec1
  752.  
  753. # Shutter motion blur - use MFlowBlur to blur along motion vectors
  754. sblurSuper = (ShutterBlur > 0) ? addNoise2.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  755. sblur = (ShutterBlur > 0) ? addNoise2.MFlowBlur( sblurSuper, sbBVec1, sbFVec1, blur=blurLevel, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  756.  
  757. # Shutter motion blur - use motion mask to reduce blurring in areas of low motion - also helps reduce blur "bleeding" into static areas, then select blur type
  758. sbMotionMask = (ShutterBlur > 0 && SBlurLimit > 0) ? MMask( srchClip, bVec1, kind=0, ml=SBlurLimit ) : NOP()
  759. sblurred = (ShutterBlur == 0) ? addNoise2 : \
  760. (SBlurLimit == 0) ? sblur : \
  761. mt_merge( addNoise2, sblur, sbMotionMask, U=3,V=3 )
  762. # Reduce frame rate
  763. decimated = (FPSDivisor != 1) ? sblurred.SelectEvery( FPSDivisor, 0 ) : sblurred
  764.  
  765. # Crop off temporary vertical padding
  766. cropped = Border ? decimated.Crop( 0, 4, -0, -4 ) : decimated
  767. h = Border ? h-8 : h
  768.  
  769. # Show output of choice + settings
  770. # >>>> Restore YUY2 to interleaved
  771. output = (ShowNoise == 0.0) ? cropped : finalNoise.mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 )
  772. output = yuy2 ? output.ConvertToYUY2() : output
  773. return (ShowSettings == false) ? output : \
  774. output.Subtitle( "TR0=" + string(TR0) + " | TR1=" + string(TR1) + " | TR2=" + string(TR2) + " | Rep0=" + string(Rep0) + " | Rep1=" + string(Rep1) + \
  775. " | Rep2=" + string(Rep2) + " | RepChroma=" + string(RepChroma) + "\nEdiMode='" + EdiMode + "' | NNSize=" + string(NNSize) + " | NNeurons=" + \
  776. string(NNeurons) + " | EdiQual=" + string(EdiQual) + " | EdiMaxD=" + string(EdiMaxD) + " | ChromaEdi='" + ChromaEdi + "' | EdiThreads=" + \
  777. string(EdiThreads) + "\nSharpness=" + string(Sharpness, "%.2f") + " | SMode=" + string(SMode) + " | SLMode=" + string(SLMode) + " | SLRad=" + \
  778. string(SLRad) + " | SOvs=" + string(SOvs) + " | SVThin=" + string(SVThin, "%.2f") + " | Sbb=" + string(Sbb) + "\nSrchClipPP=" + string(SrchClipPP) + \
  779. " | SubPel=" + string(SubPel) + " | SubPelInterp=" + string(SubPelInterp) + " | BlockSize=" + string(BlockSize) + " | Overlap=" + string(Overlap) + \
  780. "\nSearch=" + string(Search) + " | SearchParam=" + string(SearchParam) + " | PelSearch=" + string(PelSearch) + " | ChromaMotion=" + \
  781. string(ChromaMotion) + " | TrueMotion=" + string(TrueMotion) + "\nLambda=" + string(Lambda) + " | LSAD=" + string(LSAD) + " | PNew=" + string(PNew) + \
  782. " | PLevel=" + string(PLevel) + " | GlobalMotion=" + string(GlobalMotion) + " | DCT=" + string(DCT) + "\nThSAD1=" + string(ThSAD1) + " | ThSAD2=" + \
  783. string(ThSAD2) + " | ThSCD1=" + string(ThSCD1) + " | ThSCD2=" + string(ThSCD2) + "\nSourceMatch=" + string(SourceMatch) + " | MatchPreset='" + \
  784. MatchPreset + "' | MatchEdi='" + MatchEdi + "'\nMatchPreset2='" + MatchPreset2 + "' | MatchEdi2='" + MatchEdi2 + "' | MatchTR2=" + string(MatchTR2) + \
  785. " | MatchEnhance=" + string(MatchEnhance, "%.2f") + " | Lossless=" + string(Lossless) + "\nNoiseProcess=" + string(NoiseProcess) + " | Denoiser='" + \
  786. Denoiser + "' | FftThreads=" + string(FftThreads) + " | DenoiseMC=" + string(DenoiseMC) + " | NoiseTR=" + string(NoiseTR) + " | Sigma=" + \
  787. string(Sigma, "%.2f") + "\nChromaNoise=" + string(ChromaNoise) + " | ShowNoise=" + string(ShowNoise, "%.2f") + " | GrainRestore=" + \
  788. string(GrainRestore, "%.2f") + " | NoiseRestore=" + string(NoiseRestore, "%.2f") + "\nNoiseDeint='" + NoiseDeint + "' | StabilizeNoise=" + \
  789. string(StabilizeNoise) + " | InputType=" + string(InputType) + " | ProgSADMask=" + string(ProgSADMask, "%.2f") + "\nFPSDivisor=" + \
  790. string(FPSDivisor) + " | ShutterBlur=" + string(ShutterBlur) + " | ShutterAngleSrc=" + string(ShutterAngleSrc, "%.2f") + " | ShutterAngleOut=" + \
  791. string(ShutterAngleOut, "%.2f") + " | SBlurLimit=" + string(SBlurLimit) + "\nBorder=" + string(Border) + " | Precise=" + string(Precise) + \
  792. "\nPreset='" + Preset + "' | Tuning='" + Tuning + "' | GlobalNames='" + GlobalNames + "' | PrevGlobals='" + PrevGlobals + "' | ForceTR=" + \
  793. string(ForceTR), font="Lucida Console", size=11, lsp=12 )
  794. }
  795.  
  796.  
  797. #---------------------------------------
  798. # Helpers
  799.  
  800. # Same as Bob, but keeps the field order the same.
  801. function QTGMC_Bob(clip cp, float "b", float "c", int "height" )
  802. {
  803. ssispmt = Findstr(VersionString(), "AviSynth+") != 0 && Findstr(VersionString(), "r1576") == 0
  804. h = Default(height, cp.Height)
  805. w = cp.Width
  806. shift = GetParity(cp) ? 0.25 : -0.25
  807.  
  808. c420 = ssispmt ? Is420(cp) : IsYV12(cp)
  809.  
  810. c420 ? cp.SeparateFields() : nop()
  811.  
  812. oeven=c420 ? SelectEven() : nop()
  813. oodd=c420 ? SelectOdd() : nop()
  814.  
  815. even=c420 ? ssispmt ? oeven.ConvertToY().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : oeven.ConvertToY8().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : nop()
  816. odd=c420 ? ssispmt ? oodd.ConvertToY().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : oodd.ConvertToY8().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : nop()
  817.  
  818. evenChr=c420 ? Interleave(ssispmt ? oeven.ExtractU() : oeven.UToY8(), ssispmt ? oeven.ExtractV() : oeven.VToY8()).BicubicResize(w/2, h/2, b, c, 0, shift, w/2, Height()/2).AssumeFrameBased() : nop()
  819. oddChr=c420 ? Interleave(ssispmt ? oodd.ExtractU() : oodd.UToY8(), ssispmt ? oodd.ExtractV() :oodd.VToY8()).BicubicResize(w/2, h/2, b, c, 0, -shift, w/2, Height()/2).AssumeFrameBased() : nop()
  820.  
  821. c420 ? YToUV(Interleave(evenChr.SelectEven(), oddChr.SelectEven()),Interleave(evenChr.SelectOdd(), oddChr.SelectOdd()),Interleave(even, odd)) : cp.Bob( b,c, h )
  822. GetParity(cp) ? AssumeTFF() : AssumeBFF()
  823. }
  824.  
  825.  
  826. # Interpolate input clip using method given in EdiMode. Use Fallback or Bob as result if mode not in list. If ChromaEdi string if set then interpolate chroma
  827. # separately with that method (only really useful for EEDIx). The function is used as main algorithm starting point and for first two source-match stages
  828. function QTGMC_Interpolate( clip Input, int InputType, string EdiMode, int NNSize, int NNeurons, int EdiQual, int EdiMaxD, int EdiThreads, clip "Fallback", \
  829. string "ChromaEdi" )
  830. {
  831. # >>>> YUY2 is interleaved here
  832.  
  833. ChromaEdi = default( ChromaEdi, "" )
  834. CEed = (ChromaEdi == "")
  835.  
  836. interp = (InputType == 1) ? Input : \
  837. (EdiMode == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  838. (EdiMode == "NNEDI2") ? Input.NNEDI2( field=-2, nsize=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  839. (EdiMode == "NNEDI") ? Input.NNEDI( field=-2, U=CEed,V=CEed ) : \
  840. (EdiMode == "EEDI3+NNEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed, \
  841. sclip=Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) ) : \
  842. (EdiMode == "EEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed ) : \
  843. (EdiMode == "EEDI2") ? Input.SeparateFields().EEDI2( field=-2, maxd=EdiMaxD ) : \
  844. (EdiMode == "Yadif") ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  845. (EdiMode == "cYadif") ? Input.Yadif( mode=3 ) : \
  846. (EdiMode == "TDeint") ? Input.TDeInt( mode=1 ) : \
  847. (EdiMode == "RepYadif") ? isyuy2(Input) ? Repair( Input.ConvertToYv16().Yadifmod2( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  848. Input.Yadifmod2( mode=3 ) : \
  849. (EdiMode == "RepcYadif") ? isyuy2(Input) ? Repair( Input.Yadif( mode=3 ).ConvertToYv16(), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  850. Repair( Input.Yadif( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ), 2, 0 ) : \
  851. default( Fallback, Input.QTGMC_Bob( 0,0.5 ) )
  852.  
  853. interpuv = (InputType == 1) ? NOP() : \
  854. (ChromaEdi == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=4, nns=0, qual=1, threads=EdiThreads, Y=false ) : \
  855. (ChromaEdi == "Yadif") ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  856. (ChromaEdi == "cYadif") ? Input.Yadif( mode=3 ) : \
  857. (ChromaEdi == "Bob") ? Input.QTGMC_Bob( 0,0.5 ) : \
  858. NOP()
  859.  
  860. return (!IsClip(interpuv)) ? interp : interp.MergeChroma( interpuv )
  861. }
  862.  
  863.  
  864. # Functions (from original TGMC) used instead of mt_xxflate with similar operation but a somewhat stronger result. Originally added for speed, they are
  865. # no longer faster due to improvements in masktools. Difference (visual and speed) is small so may be reverted in a later version.
  866. function QTGMC_inflate( clip c, int "Y", int "U", int "V" )
  867. {
  868. # >>>> YUY2 is planar here
  869. mtY =default( Y, 3 )
  870. mtU =default( U, 1 )
  871. mtV =default( V, 1 )
  872. rgY = (mtY == 3) ? 20 : -1
  873. rgU = (mtU == 3) ? 20 : -1
  874. rgV = (mtV == 3) ? 20 : -1
  875. mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "max", Y=mtY,U=mtU,V=mtV )
  876. }
  877.  
  878. function QTGMC_deflate( clip c, int "Y", int "U", int "V" )
  879. {
  880. # >>>> YUY2 is planar here
  881. mtY =default( Y, 3 )
  882. mtU =default( U, 1 )
  883. mtV =default( V, 1 )
  884. rgY = (mtY == 3) ? 20 : -1
  885. rgU = (mtU == 3) ? 20 : -1
  886. rgV = (mtV == 3) ? 20 : -1
  887. mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "min", Y=mtY,U=mtU,V=mtV )
  888. }
  889.  
  890. # Helper function: Compare processed clip with reference clip: only allow thin, horizontal areas of difference, i.e. bob shimmer fixes
  891. # Rough algorithm: Get difference, deflate vertically by a couple of pixels or so, then inflate again. Thin regions will be removed
  892. # by this process. Restore remaining areas of difference back to as they were in reference clip.
  893. function QTGMC_KeepOnlyBobShimmerFixes( clip Input, clip Ref, int Rep, bool Chroma )
  894. {
  895. # >>>> YUY2 is planar here
  896.  
  897. # ed is the erosion distance - how much to deflate then reflate to remove thin areas of interest: 0 = minimum to 6 = maximum
  898. # od is over-dilation level - extra inflation to ensure areas to restore back are fully caught: 0 = none to 3 = one full pixel
  899. # If Rep < 10, then ed = Rep and od = 0, otherwise ed = 10s digit and od = 1s digit (nasty method, but kept for compatibility with original TGMC)
  900. Rep = default( Rep, 1 )
  901. Chroma = default( Chroma, true )
  902. ed = (Rep < 10) ? Rep : Rep / 10
  903. od = (Rep < 10) ? 0 : Rep % 10
  904. RCrg = Chroma ? 3 : 1
  905. RCrgo = Chroma ? 3 : 2
  906.  
  907. diff = mt_makediff(Ref, Input, U=3,V=3 )
  908.  
  909. # Areas of positive difference # ed = 0 1 2 3 4 5 6 7
  910. choke1 = diff. mt_inpand( mode="vertical", U=RCrg,V=RCrg ) # x x x x x x x x 1 pixel \
  911. choke1 = (ed > 2) ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1 # . . . x x x x x 1 pixel | Deflate to remove thin areas
  912. choke1 = (ed > 5) ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1 # . . . . . . x x 1 pixel /
  913. choke1 = (ed % 3 != 0) ? choke1.QTGMC_deflate( U=RCrg,V=RCrg ) : choke1 # . x x . x x . x A bit more deflate & some horizonal effect
  914. choke1 = (ed == 2 || ed == 5) ? choke1.RemoveGrain( 4 ) : choke1 # . . x . . x . . Local median
  915.  
  916. choke1 = choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) # x x x x x x x x 1 pixel \
  917. choke1 = (ed > 1) ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1 # . . x x x x x x 1 pixel | Reflate again
  918. choke1 = (ed > 4) ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1 # . . . . . x x x 1 pixel /
  919.  
  920. # Over-dilation - extra reflation up to about 1 pixel
  921. choke1 = (od == 0) ? choke1 : \
  922. (od == 1) ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ) : \
  923. (od == 2) ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ).QTGMC_inflate( U=RCrg,V=RCrg ) : \
  924. choke1.mt_expand ( U=RCrg,V=RCrg )
  925.  
  926. # Areas of negative difference (similar to above)
  927. choke2 = diff. mt_expand( mode="vertical", U=RCrg,V=RCrg )
  928. choke2 = (ed > 2) ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  929. choke2 = (ed > 5) ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  930. choke2 = (ed % 3 != 0) ? choke2.QTGMC_inflate( U=RCrg,V=RCrg ) : choke2
  931. choke2 = (ed == 2 || ed == 5) ? choke2.RemoveGrain( 4 ) : choke2
  932. choke2 = choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg )
  933. choke2 = (ed > 1) ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  934. choke2 = (ed > 4) ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  935. choke2 = (od == 0) ? choke2 : \
  936. (od == 1) ? choke2.QTGMC_deflate( U=RCrg,V=RCrg ) : \
  937. (od == 2) ? choke2.QTGMC_deflate( U=RCrg,V=RCrg ).QTGMC_deflate( U=RCrg,V=RCrg ) : \
  938. choke2.mt_inpand ( U=RCrg,V=RCrg )
  939.  
  940. # Combine above areas to find those areas of difference to restore
  941. restore = diff.mt_lutxy( choke1, "x 129 < x y 128 < 128 y ? ?", U=RCrg,V=RCrg ).mt_lutxy( choke2, "x 127 > x y 128 > 128 y ? ?", U=RCrg,V=RCrg )
  942.  
  943. return Input.mt_adddiff( restore, U=RCrgo,V=RCrgo )
  944. }
  945.  
  946.  
  947. # Given noise extracted from an interlaced source (i.e. the noise is interlaced), generate "progressive" noise with a new "field" of noise injected. The new
  948. # noise is centered on a weighted local average and uses the difference between local min & max as an estimate of local variance
  949. # YUY2 clip input is planar, but must pass interleaved version of clip to setup noise
  950. function QTGMC_Generate2ndFieldNoise( clip Input, clip InterleavedClip, bool "ChromaNoise" )
  951. {
  952. # >>>> YUY2 is planar here. Noise is generated (AddGrainC) interleaved, but immediately made planar
  953. ChromaNoise = default( ChromaNoise, false )
  954. CNmt1 = ChromaNoise ? 3 : 1
  955. origNoise = Input.SeparateFields()
  956. noiseMax = origNoise.mt_expand( mode="square", U=CNmt1,V=CNmt1 ).mt_expand( mode="horizontal", U=CNmt1,V=CNmt1 )
  957. noiseMin = origNoise.mt_inpand( mode="square", U=CNmt1,V=CNmt1 ).mt_inpand( mode="horizontal", U=CNmt1,V=CNmt1 )
  958. random = BlankClip( InterleavedClip.SeparateFields(), color_yuv=$808080 ).AddGrainC( var=1800, uvar=ChromaNoise ? 1800 : 0 )
  959. random = InterleavedClip.IsYUY2() ? random.converttoyv16() : random
  960. varRandom = mt_makediff( noiseMax, noiseMin, U=CNmt1,V=CNmt1 ).mt_lutxy( random, "x 128 - y * 256 / 128 +", U=CNmt1,V=CNmt1)
  961. newNoise = noiseMin.mt_adddiff( varRandom, U=CNmt1,V=CNmt1 )
  962. return Interleave( origNoise, newNoise ).Weave()
  963. }
  964.  
  965.  
  966. # Insert the source lines into the result to create a true lossless output. However, the other lines in the result have had considerable processing and won't
  967. # exactly match source lines. There will be some slight residual combing. Use vertical medians to clean a little of this away
  968. function QTGMC_MakeLossless( clip Input, clip Source, int InputType )
  969. {
  970. Assert( InputType != 1, "Lossless modes are incompatible with InputType=1" )
  971.  
  972. # >>>> YUY2: 'Input' is planar, 'Source' is interleaved (changed to planar here for processing) - returns planar result
  973.  
  974. # Weave the source fields and the "new" fields that have generated in the input
  975. srcFields1 = (InputType == 0) ? Source.SeparateFields() : Source.SeparateFields().SelectEvery( 4, 0,3 )
  976. srcFields = Source.IsYUY2() ? srcFields1.converttoyv16() : srcFields1
  977. newFields = Input.SeparateFields().SelectEvery( 4, 1,2 )
  978. processed = Interleave( srcFields, newFields ).SelectEvery(4, 0,1,3,2 ).Weave()
  979.  
  980. # Clean some of the artefacts caused by the above - creating a second version of the "new" fields
  981. vertMedian = processed.VerticalCleaner( mode=1 )
  982. vertMedDiff = mt_makediff( processed, vertMedian, U=3,V=3 )
  983. vmNewDiff1 = vertMedDiff.SeparateFields().SelectEvery( 4, 1,2 )
  984. vmNewDiff2 = vmNewDiff1.VerticalCleaner( mode=1 ).mt_lutxy( vmNewDiff1, "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 )
  985. vmNewDiff3 = vmNewDiff2.Repair( vmNewDiff2.RemoveGrain( 2 ), 1 )
  986.  
  987. # Reweave final result
  988. return Interleave( srcFields, newFields.mt_makediff( vmNewDiff3, U=3,V=3 )).SelectEvery( 4, 0,1,3,2 ).Weave()
  989. }
  990.  
  991.  
  992. # Source-match, a three stage process that takes the difference between deinterlaced input and the original interlaced source, to shift the input more towards
  993. # the source without introducing shimmer. All other arguments defined in main script
  994. function QTGMC_ApplySourceMatch( clip Deinterlace, int InputType, val Source, val bVec1, val fVec1, val bVec2, val fVec2, \
  995. int SubPel, int SubPelInterp, int hpad, int vpad, int ThSAD1, int ThSCD1, int ThSCD2, int SourceMatch, \
  996. int MatchTR1, string MatchEdi, int MatchNNSize, int MatchNNeurons, int MatchEdiQual, int MatchEdiMaxD,\
  997. int MatchTR2, string MatchEdi2, int MatchNNSize2, int MatchNNeurons2, int MatchEdiQual2, int MatchEdiMaxD2, \
  998. float MatchEnhance, int EdiThreads, bool lsb )
  999. {
  1000. # >>>> YUY2: 'Deinterlace' is planar, 'Source' is interleaved (changed to planar here for all processing except interpolation) - returns planar result
  1001. yuy2 = Source.IsYUY2()
  1002. Source = yuy2 ? Source.converttoyv16() : Source
  1003.  
  1004. # Basic source-match. Find difference between source clip & equivalent fields in interpolated/smoothed clip (called the "error" in formula below). Ideally
  1005. # there should be no difference, we want the fields in the output to be as close as possible to the source whilst remaining shimmer-free. So adjust the
  1006. # *source* in such a way that smoothing it will give a result closer to the unadjusted source. Then rerun the interpolation (edi) and binomial smooth with
  1007. # this new source. Result will still be shimmer-free and closer to the original source.
  1008. # Formula used for correction is P0' = P0 + (P0-P1)/(k+S(1-k)), where P0 is original image, P1 is the 1st attempt at interpolation/smoothing , P0' is the
  1009. # revised image to use as new source for interpolation/smoothing, k is the weighting given to the current frame in the smooth, and S is a factor indicating
  1010. # "temporal similarity" of the error from frame to frame, i.e. S = average over all pixels of [neighbor frame error / current frame error] . Decreasing
  1011. # S will make the result sharper, sensible range is about -0.25 to 1.0. Empirically, S=0.5 is effective [will do deeper analysis later]
  1012. errorTemporalSimilarity = 0.5 # S in formula described above
  1013. errorAdjust1 = Select( MatchTR1, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1014. match1Clip = (SourceMatch < 1 || InputType == 1) ? Deinterlace : Deinterlace.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1015. match1Update = (SourceMatch < 1 || MatchTR1 == 0) \
  1016. ? Source : mt_lutxy( Source, match1Clip, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 )
  1017. noyv16ma1Edi = MatchEdi =="NNEDI2" || MatchEdi =="NNEDI" || MatchEdi =="EEDI3+NNEDI3" || MatchEdi =="EEDI3" || MatchEdi =="EEDI2" || MatchEdi =="TDeint" || MatchEdi =="cYadif" || MatchEdi =="RepcYadif"
  1018. noyv16ma2Edi = MatchEdi2=="NNEDI2" || MatchEdi2=="NNEDI" || MatchEdi2=="EEDI3+NNEDI3" || MatchEdi2=="EEDI3" || MatchEdi2=="EEDI2" || MatchEdi2=="TDeint" || MatchEdi2=="cYadif" || MatchEdi2=="RepcYadif"
  1019. match1Edi = (SourceMatch == 0) ? NOP() : \
  1020. !noyv16ma1Edi || !yuy2 ? match1Update.QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) : \
  1021. match1Update.ConvertToYUY2() \
  1022. .QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) \
  1023. .ConvertToYv16()
  1024. match1Super = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1025. match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MDegrain1( match1Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1026. match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? match1Edi.MDegrain1( match1Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1027. match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) && lsb ? match1Degrain1.ditherpost(mode=6, slice=false) : match1Degrain1
  1028. match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) && lsb ? match1Degrain2.ditherpost(mode=6, slice=false) : match1Degrain2
  1029. match1 = (SourceMatch < 1) ? Deinterlace : \
  1030. (MatchTR1 == 0) ? match1Edi : \
  1031. (MatchTR1 == 1) ? match1Degrain1.Merge( match1Edi, 0.25 ) : \
  1032. match1Degrain1.Merge( match1Degrain2, 0.2 ).Merge( match1Edi, 0.0625 )
  1033.  
  1034. # Enhance effect of source-match stages 2 & 3 by sharpening clip prior to refinement (source-match tends to underestimate so this will leave result sharper)
  1035. match1Shp = (SourceMatch > 1 && MatchEnhance > 0.0) ? match1.mt_lutxy( match1.RemoveGrain( 12 ), "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 ) : match1
  1036.  
  1037. # Source-match refinement. Find difference between source clip & equivalent fields in (updated) interpolated/smoothed clip. Interpolate & binomially smooth
  1038. # this difference then add it back to output. Helps restore differences that the basic match missed. However, as this pass works on a difference rather than
  1039. # the source image it can be prone to occasional artefacts (difference images are not ideal for interpolation). In fact a lower quality interpolation such
  1040. # as a simple bob often performs nearly as well as advanced, slower methods (e.g. NNEDI3)
  1041. match2Clip = (SourceMatch < 2 || InputType == 1) ? match1Shp : match1Shp.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1042. match2Diff = (SourceMatch > 1) ? mt_makediff( Source, match2Clip, U=3,V=3 ) : NOP()
  1043. match2Edi = (SourceMatch <= 1) ? NOP() : \
  1044. !noyv16ma2Edi || !yuy2 ? match2Diff.QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) : \
  1045. match2Diff.ConvertToYUY2() \
  1046. .QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) \
  1047. .ConvertToYv16()
  1048. match2Super = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1049. match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MDegrain1( match2Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1050. match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? match2Edi.MDegrain1( match2Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1051. match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) && lsb ? match2Degrain1.ditherpost(mode=6, slice=false) : match2Degrain1
  1052. match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) && lsb ? match2Degrain2.ditherpost(mode=6, slice=false) : match2Degrain2
  1053. match2 = (SourceMatch < 2) ? match1 : \
  1054. (MatchTR2 == 0) ? match2Edi : \
  1055. (MatchTR2 == 1) ? match2Degrain1.Merge( match2Edi, 0.25 ) : \
  1056. match2Degrain1.Merge( match2Degrain2, 0.2 ).Merge( match2Edi, 0.0625 )
  1057.  
  1058. # Source-match second refinement - correct error introduced in the refined difference by temporal smoothing. Similar to error correction from basic step
  1059. errorAdjust2 = Select( MatchTR2, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1060. match3Update = (SourceMatch < 3 || MatchTR2 == 0) \
  1061. ? match2Edi : mt_lutxy( match2Edi, match2, "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 )
  1062. match3Super = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1063. match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MDegrain1( match3Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1064. match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? match3Update.MDegrain1( match3Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1065. match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) && lsb ? match3Degrain1.ditherpost(mode=6, slice=false) : match3Degrain1
  1066. match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) && lsb ? match3Degrain2.ditherpost(mode=6, slice=false) : match3Degrain2
  1067. match3 = (SourceMatch < 3) ? match2 : \
  1068. (MatchTR2 == 0) ? match3Update : \
  1069. (MatchTR2 == 1) ? match3Degrain1.Merge( match3Update, 0.25 ) : \
  1070. match3Degrain1.Merge( match3Degrain2, 0.2 ).Merge( match3Update, 0.0625 )
  1071.  
  1072. # Apply difference calculated in source-match refinement
  1073. return (SourceMatch < 2) ? match1 : match1Shp.mt_adddiff( match3, U=3,V=3 )
  1074. }
  1075.  
  1076.  
  1077. # Set global variable called "Prefix_Name" to "Value". Throws exception if global already exists unless Replace=true, in which case the global is overwritten
  1078. function QTGMC_SetUserGlobal( string Prefix, string Name, val Value, bool "Replace" )
  1079. {
  1080. Replace = default( Replace, false )
  1081. globalName = Prefix + "_" + Name
  1082.  
  1083. # Tricky logic to check global: enter catch block if Replace=true *or* globalName doesn't exist (i.e. need to set the global), the exception is not rethrown
  1084. # Not entering catch block means that Replace=false and global exists - so it throws an exception back to AviSynth
  1085. try { Assert( !Replace && defined(Eval(globalName)) ) }
  1086. catch (e)
  1087. {
  1088. Eval( "global " + globalName + " = Value" )
  1089. Replace = true
  1090. }
  1091. Assert( Replace, """Multiple calls to QTGMC, set PrevGlobals="Replace" or read documentation on 'Multiple QTGMC Calls'""" )
  1092. }
  1093.  
  1094. # Return value of global variable called "Prefix_Name". Returns NOP() if it doesn't exist or Reuse is false
  1095. function QTGMC_GetUserGlobal( string Prefix, string Name, bool "Reuse" )
  1096. {
  1097. Reuse = default( Reuse, false )
  1098. globalName = Prefix + "_" + Name
  1099.  
  1100. try { ret = Reuse ? Eval( globalName ) : NOP() }
  1101. catch (e) { ret = NOP() }
  1102. return ret
  1103. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!