;==================================
; Script Name:   Puda's Idoc Hunter
; Author: Puda
; Version: 2.00 menu edition
; Client Tested with: 4.0.5a
; EUO version tested with: V1.42 [Build 0099]
; Shard OSI / FS: OSI
; Revision Date: 10/15/04
; Public Release: 7/16/04
; Global Variables Used: none
; Purpose: Scanning of House signs for Decay

Initevents
ignoreitem reset
set %decay 0
; Set %uoam_setup to 1 if you are continuing logging Idocs from a previous session.
;Logging toggle, Set to true if you wish to create a uoam marker file to save decays.
;Set %filename to a directory and file name Example: set %filename c:idoc.map.
;After you are finished logging simply move the Idoc.map file from c:idoc.map to c:program filesuoamidoc.map.
;In UOAM CTRL+A, select the Files tab, select Add, type in IDOC, and hit OK.
;You can now also set a wav file for decay alerts.
set %uoam_setup 0
set %uoam true
set %filename c:\idoc.map
set %sound c:\easyuo\c21.wav

menu hide
menu clear
menu window title idoc
menu window size 125 100
menu window color $000000
menu font color white
menu font size 10
menu font bgcolor $000000
menu text stat 0 5 Status:
menu text stat 0 25 Charx/y:
menu text stat 0 45 Checking:
menu text stat 0 65 Found:
menu text stat 0 85 Last:
menu show
menu hideeuo
start:
gosub idoc
wait 0
goto start

Sub idoc
top:
finditem MRE_AKE_ULE_KOE_KLE_WJE_GNE_MKE_UKE_EKE_
+GLE_CKE_ILE_IKE_YJE_CRE_GRE_OLE_IRE_GNE_INE_SNE_UNE_
+ONE_QNE_AOE_COE_ERE_WNE_YNE_IOE_EOE_GOE_SJE_UJE_
+SLE_QNE_QJE_ALE_ARE_CLE_ELE_GKE_KRE_MLE_OKE_QKE_
+QJE_OJE_QJE_QLE_QNE_SKE_WKE_WLE_YLE_YKE_YQE_KKE G_12
wait 0
set %lastx #findx
set %lasty #findy
menu delete Checking
menu delete charx/y
menu text charx/y 55 25 #charposx #charposy
menu text Checking 65 45 #findcnt
if #findkind = -1
  {
  menu font color green
  menu text status 55 5 Ready
  wait 5
  menu font color white
  goto top
  }
event property #findid
if public notin #property && private notin #property
     {
  menu delete status
  menu font color red
  menu text Status 55 5 Wait
  wait 20
  menu delete status
  menu font color white
        goto top
  }
if condition IN #property
  {
   menu delete status
  menu font color blue
  menu text Status 55 5 Decay
  set %decay %decay + 1
  menu text found 65 65 %decay
  menu text last 55 85 %lastx %lasty
  sound %sound
  if %uoam = true
    gosub log
  wait 40
  menu font color white
  menu delete status
  }
if condition notin #property
     {
  menu delete status
  menu font color yellow
  menu text Status 55 5 Skipped
  menu font color white
  wait 20
  menu delete status
  }
ignoreitem #findid
return

Sub log
if %uoam_setup = 0
  {
  execute cmd /c echo 3 >> %filename
  set %uoam_setup 1
  }
set %facet #curskind + 1
execute cmd /c echo +town: #findx #findy %facet Decay >> %filename
return