fn_hackLaptop.sqf

/*
    filename: @fn_hackLaptop.sqf
    Author: J. Schmidt
    Coded for SOG Missions and Campaigns

*/

params ["_laptop"];

if (_laptop getVariable ["inUse", false]) exitWith { hint "Someone is Already Downloading the Files." };

_laptop setVariable ["inUse", true, true];
hackComplete = false;
_ld0 = getUnitLoadout player;
_backupLoadout = _ld0;

_ld1 = getUnitLoadout player;
for "_i" from 0 to 2 do {
    _ld1 set [_i, []];
};

player setUnitLoadout _ld1;
player switchMove "acts_accessing_computer_in";
player playMoveNow "acts_accessing_computer_loop";

with uiNamespace do {
    jas92_progressBar = findDisplay 46 ctrlCreate ["RscProgress", -1];
    jas92_progressBar ctrlSetPosition [ 0.345, 0.3 ];
    jas92_progressBar progressSetPosition 0;
    jas92_progressBar ctrlCommit 0;
    jas92_text = findDisplay 46 ctrlCreate ["RscStructuredText", -1];
    jas92_text ctrlSetPosition [ 0.345, 0.2925 ];
    jas92_text ctrlCommit 0;
};

["timer", "onEachFrame", {
    params ["_start", "_end", "_backupLoadout"];

    _progress = linearConversion[_start, _end, time, 0, 1];

    (uiNamespace getVariable "jas92_progressBar") progressSetPosition _progress;
    (uiNamespace getVariable "jas92_text") ctrlSetStructuredText parseText format["%1%2", round(100 * _progress), "%"];

    if (_progress > 1) then {
        [ "timer", "onEachFrame" ] call BIS_fnc_removeStackedEventHandler;
        ctrlDelete (uiNamespace getVariable "jas92_progressBar");
        ctrlDelete (uiNamespace getVariable "jas92_text");

        player playMoveNow "acts_accessing_computer_out_short";
        player setUnitLoadout _backupLoadout;

        hackComplete = true;
    };
}, [time, time + 30, _backupLoadout]] call BIS_fnc_addStackedEventHandler;