on *:TEXT:!verzoek *:#timboektaantje,#ergens:{
  if $dialog(ReqMuz) {
    write reqmuz.txt $2- ~ $nick ~ $ctime
    _updreq
    .timer 1 3 _hoevnr
  }
  else {
    dialog -mdie ReqMuz ReqMuz
    write reqmuz.txt $2- ~ $nick ~ $ctime
    _updreq
    .timer 1 3 _hoevnr
  }
}

alias -l _updreq {
  did -r ReqMuz 7
  var %a = 1, %b = $lines(reqmuz.txt)
  while (%a <= %b) {
    did -a ReqMuz 7 Nummer: $gettok($read(reqmuz.txt,%a),1,126) ~ Door: $gettok($read(reqmuz.txt,%a),2,126) ~ $duration($calc( $ctime - $gettok($read(reqmuz.txt,%a),3,126) )) geleden.
    inc %a 1
  }
}

alias _hoevnr { did -ra ReqMuz 6 Nummers in verzoeklijst: $iif($lines(reqmuz.txt),$lines(reqmuz.txt),Geen.) }

dialog ReqMuz {
  title "T.O.S. Verzoekjes."
  size -1 -1 250 185
  option dbu
  box "Verzoekjes", 1, 5 5 240 141
  list 7, 10 15 230 130, vsbar hsbar

  box "Debug", 5, 5 142 240 25
  edit "", 6, 15 150 220 10, read

  button "Verwijder", 2, 40 170 50 10
  button "Sluit", 3, 100 170 50 10
  button "Spelen", 4, 160 170 50 10
}


on *:DIALOG:ReqMuz:init:0:{ if $exists(reqmuz.txt) { _updreq } | _hoevnr }
on *:DIALOG:ReqMuz:sclick:3:{ dialog -x ReqMuz }
on *:DIALOG:ReqMuz:sclick:4:{
  msg #timboektaantje Speelt: $gettok($read(reqmuz.txt,$did(ReqMuz,7).sel),1,126) $+ , verzocht door: $gettok($read(reqmuz.txt,$did(ReqMuz,7).sel),2,126) $+ , $duration($calc($ctime - $gettok($read(reqmuz.txt,$did(ReqMuz,7).sel),3,126))) geleden.
  did -ra ReqMuz 6 * Verzocht nummer: $gettok($read(reqmuz.txt,$did(ReqMuz,7).sel),1,126) *
  .timer 1 3 _hoevnr
}
on *:DIALOG:ReqMuz:sclick:2:{
  if ($did(ReqMuz,7).sel) {
    write -dl $+ $did(ReqMuz,7).sel reqmuz.txt
    echo -agt * Selected: $did(ReqMuz,7).sel
    did -ra ReqMuz 6 * Nummer $did(ReqMuz,7).sel verwijderd uit verzoeklijst. *
    did -d ReqMuz 7 $did(ReqMuz,7).sel
    .timer 1 3 _hoevnr
  }
  else { did -ra ReqMuz 6 * Geen regel geselecteerd! * | .timer 1 3 _hoevnr }
}

menu channel {
  -
  Verzoekjes { dialog -mdie ReqMuz ReqMuz }
}