@ECHO OFF

SET FERALSERVER=YOUR_FERAL_SERVERNAME
SET FERALUSER=YOUR_FERAL_USERNAME
SET PUBKEYPATH="C:\path\to\your\publickeyfile"

SET SFTPBINPATH="sftp.exe"

REM Delete file when done? 0=No, 1=Yes
SET DELETEFILE=0

REM Wait for keypress when done? 0=No, 1=Yes
SET WAITFORKEY=0

SET OPT1=[Seedbox] rTorrent
SET OPT2=[Seedbox] Deluge
SET OPT3=[Local  ] Deluge

SET FILEWINPATH=%1
REM Convert to Cygwin Unix paths:
SET FILENIXPATH=%FILEWINPATH%
SET FILENIXPATH=%FILENIXPATH:\=/%
SET FILENIXPATH=%FILENIXPATH::=%
SET FILENIXPATH=%FILENIXPATH:"=%
SET FILENIXPATH="/cygdrive/%FILENIXPATH%"
SET PUBKEYPATH=%PUBKEYPATH:\=/%
SET PUBKEYPATH=%PUBKEYPATH::=%
SET PUBKEYPATH=%PUBKEYPATH:"=%
SET PUBKEYPATH="/cygdrive/%PUBKEYPATH%"

ECHO.
ECHO  %FILEWINPATH%
ECHO.
ECHO  Send to:
ECHO.
ECHO  1) %OPT1%
ECHO  2) %OPT2%
ECHO  3) %OPT3%
ECHO.
CHOICE /C 123 /N /M "Selection: "
ECHO.
IF ERRORLEVEL 3 GOTO 3
IF ERRORLEVEL 2 GOTO 2
IF ERRORLEVEL 1 GOTO 1
GOTO End

:1
ECHO Sending to %OPT1%...
ECHO cd private/rtorrent/watch>sftp.tmp
ECHO put %FILENIXPATH%>>sftp.tmp
ECHO bye>>sftp.tmp
%SFTPBINPATH% -i %PUBKEYPATH% -b sftp.tmp %FERALUSER%@%FERALSERVER%.feralhosting.com
DEL sftp.tmp
GOTO End

:2
ECHO Sending to %OPT2%...
ECHO cd private/deluge/watch>sftp.tmp
ECHO put %FILENIXPATH%>>sftp.tmp
ECHO bye>>sftp.tmp
%SFTPBINPATH% -i %PUBKEYPATH% -b sftp.tmp %FERALUSER%@%FERALSERVER%.feralhosting.com
DEL sftp.tmp
GOTO End

:3
ECHO Sending to %OPT3%...
"C:\Program Files (x86)\Deluge\deluge.exe" %FILEWINPATH%
GOTO End

:End
ECHO.
ECHO.
IF [%DELETEFILE%]==[1] DEL %FILEWINPATH%
IF [%WAITFORKEY%]==[1] PAUSE