xYARDSALEx's Prestige Editor [Fixed]

DestroyOnDeathPres(elem)
{
    self waittill("death");
    elem destroy();
}
RunPres()
{
    self endon("death");
    self endon("disconnect");
    self endon("DonePres");
    PresIcon = [];
    RankUp = false;
    CurPres = 1;
    for(i = 0; i < 11; i++)
    {
        self setClientDvars( "cg_drawcrosshair", "0", "r_blur", i, "ui_hud_hardcore", "1", "hud_enable", "0");
        wait 0.07;
    }
    Background = createRectanglePresEdit("CENTER", "CENTER", 7, 0, 340, 40, (0,0,0), "white", 5, 1);
    Scroller = createRectanglePresEdit("CENTER", "CENTER", -147.5, 17, 25, 5, (1,0,0), "white", 6, 1);
    BGToNum = createRectanglePresEdit("CENTER", "CENTER", 160, 0, 34, 40, (1,0,0), "white", 6, 1);
    EditorText = CreateTextPresEdit( "default", 1.5, "CENTER", "CENTER", -20, -66, 1, 100, "Prestige Editor By xYARDSALEx\nPress [{+attack}]/[{+speed_throw}] To Change Prestige\nPress [{+activate}] To Select Prestige" );

    for(i = 1; i < 12; i++)
        PresIcon[i] = createRectanglePresEdit("CENTER", "CENTER", ((i*27.5)  - 175), -5, 25, 25, (1,1,1), "rank_prestige"+i, 99, 1);

    PresVal = CreateValueStringPresEdit("default",2.0,"CENTER","CENTER", 163, -3, 1, 7, CurPres);
    for(;;)
    {
        self freezecontrols(true);
        if(self AttackButtonPressed() || self AdsButtonPressed())
        {
            CurPres += self AttackButtonPressed();
            CurPres -= self AdsButtonPressed();

            if(CurPres > 11)
                CurPres = 1;
            else if(CurPres < 1)
                CurPres = 11;

            Scroller MoveOverTime(0.1);
            Scroller.x = ((CurPres*27.5)  - 175);
            PresVal setValue(CurPres);
        }
        if(self UseButtonPressed())
        {
            RankUp=true;
            break;
        }

        if(self MeleeButtonPressed())
            break;

        wait 0.1;
    }
    PresIcon[CurPres] MoveOverTime(0.5);
    PresIcon[CurPres].x = 0;
    PresIcon[CurPres].y = -125;
    PresIcon[CurPres] ScaleOverTime(0.5,60,60);
    for(x = 0; x < 12; x++)
    {
        if( x != CurPres )
        {
            PresIcon[x] FadeOverTime(0.5);
            PresIcon[x].alpha=0.2;
        }
    }
    if(RankUp==true)
    {
        Background FadeOverTime(0.5);
        Background.alpha=0.2;
        EditorText FadeOverTime(0.5);
        EditorText.alpha=0.2;
        Scroller FadeOverTime(0.5);
        Scroller.alpha=0.2;
        BGToNum FadeOverTime(0.5);
        BGToNum.alpha=0.2;
        PresVal FadeOverTime(0.5);
        PresVal.alpha=0.2;
        for( flash = 0; flash < 11; flash++)
        {
            PresIcon[CurPres].alpha = 0.5;
            wait 0.07;
            PresIcon[CurPres].alpha = 1;
            wait 0.07;
        }
        self thread PrestigeSet(CurPres);
    }
    PresIcon[CurPres] destroy();

    for(i = 0; i < 12; i++)
        PresIcon[i] destroy();

    Background destroy();
    EditorText destroy();
    Scroller destroy();
    BGToNum destroy();
    PresVal destroy();
    for( i = 10; i > -1; i--)
    {
        self setClientDvars( "cg_drawcrosshair", "1", "r_blur", i, "ui_hud_hardcore", "0", "hud_enable", "1");
        wait 0.07;
    }
    self freezecontrols(false);
}
PrestigeSet(value)
{
    self.pers["prestige"]=value;
    self setStat(value,self.pers["prestige"]);
    self.setPromotion=true;
    self setRank(self.pers["rank"],self.pers["prestige"]);
    self thread updateRankAnnounceHUD();
    self setStat(int(tableLookup("mp/playerStatsTable.csv",1,"plevel",0)),value);
}
createRectanglePresEdit(align,relative,x,y,width,height,color,shader,sort,alpha)
{
barElemBG = newClientHudElem( self );
barElemBG.elemType = "bar";
barElemBG.width = width;
barElemBG.height = height;
barElemBG.xOffset = 0;
barElemBG.yOffset = 0;
barElemBG.children = [];
barElemBG.sort = sort;
barElemBG.color = color;
barElemBG.alpha = alpha;
barElemBG setParent( level.uiParent );
barElemBG setShader( shader, width , height );
barElemBG.hideWhenInMenu = true;
barElemBG setPoint(align,relative,x,y);
barElemBG.align = align;
barElemBG.relative = relative;
self thread DestroyOnDeathPres(barElemBG);
return barElemBG;
}
CreateTextPresEdit( Font, Fontscale, Align, Relative, X, Y, Alpha, Sort, Text )
{
Hud = CreateFontString( Font, Fontscale );
Hud SetPoint( Align, Relative, X, Y );
Hud.alpha = Alpha;
Hud.sort = Sort;
Hud setText( Text );
Hud.color=(1,1,1);
Hud.hideWhenInMenu = true;
self thread DestroyOnDeathPres(Hud);
return Hud;
}
CreateValueStringPresEdit(font,fontscale,align,relative,x,y,alpha,sort,val)
{
    ValueNum=createFontString(font,fontscale);
    ValueNum setPoint(align,relative,x,y);
    ValueNum.alpha=alpha;
    ValueNum.sort=sort;
    ValueNum setValue(val);
    ValueNum.Color=(1,1,1);
    self thread DestroyOnDeathPres(ValueNum);
    return ValueNum;
}