ragel-dev

# Maintainer:  Ilya Terentyev <[email protected]>
# Contributor: Zachary Lund <[email protected]>
# Contributor: Timothy Redaelli <[email protected]>
# Contributor: Michael P <[email protected]>
# Contributor: Roberto Alsina <[email protected]>
# Contributor: Will Chappell <[email protected]>
# Contributor: Jesse Young <[email protected]>
# Contributor: Gustavo Alvarez <[email protected]>

pkgname=ragel-dev
pkgver=7.0.4
pkgrel=1
pkgdesc="Compiles finite state machines from regular languages into executable C, C++, Objective-C, C#, ASM, D, Go, Java, Ruby, OCaml, Crack, Rust or Julia code."
arch=('i686' 'x86_64')
url="http://www.complang.org/ragel/"
license=('GPL')
makedepends=('colm>=0.14.7' 'fig2dev' 'texlive-bin' 'dblatex')
depends=('gcc-libs')
conflicts=('ragel')
source=("https://www.colm.net/files/ragel/ragel-$pkgver.tar.gz")
md5sums=('2ca4f5507c1923bcf9a7909baa8254d3')

build() {
  cd "$srcdir/ragel-$pkgver"

  ./configure --prefix=/usr --with-colm=/usr
  make
}

package() {
  cd "$srcdir/ragel-$pkgver"

  make DESTDIR="$pkgdir/" install
  install -m0644 -D ragel.vim "$pkgdir"/usr/share/vim/vimfiles/syntax/ragel.vim
}