MineSweeper C.S. (nnUI) 1.4 [28/07/2014]

_ms_h  = 9  // board height
_ms_w  = 9  // board width
_ms_m  = 10 // board mines
_ms_th = 9  // temp H
_ms_tw = 9  // temp W
_ms_tm = 10 // temp M
_ms_fc = 0  // [FLAG] counter
_ms_hc = 0  // [MINE-HIT] counter
_ms_sm = 0  // surrounding mines counter
_ms_qh = 0  // quick hold toggle
_ms_bt = 0  // board tiles (total)
_ms_t1 = 0  // timer start (ms)
_ms_t2 = 0  // timer end (ms)
_ms_ua = 1  // undo toggle
_ms_uc = 0  // undo counter
_ms_pc = 0  // completion percentage
_ms_gm = 0  // game mode: 0 waiting | 1 active | 2 failure | 3 victory

_ms_mf = "" // board containing mine placement
_ms_nf = "" // board containing tile numbers
_ms_cf = "" // board of completion (displayed)
_ms_mp = "" // supplementary list with [MINE] positions
_ms_fp = "" // supplementary list with [FLAG] positions
_ms_tq = "" // supplementary list with [BLANK] tile queue
_ms_tr = "" // supplementary list with tile reveal positions


// ----------------------------------------- //
// ---------------- Tile ID ---------------- //
// ----------------------------------------- //
// 0x0     = [BLANK]
// 0x1-0x8 = [NUM#]
// 0x9     = [MINE-HIT]
// 0xA     = [MINE-WIN]
// 0xB     = [MINE-LOSE]
// 0xC     = [FLAG]
// 0xD     = [FLAG-WIN]
// 0xE     = [FLAG-LOSE]
// 0xF     = [HIDDEN]


append = [ $arg1 = (concat (getalias $arg1) $arg2) ]
precf  = [ substr $arg1 0 (+ (strstr $arg1 .) (+ $arg2 1)) ]
ms     = [ toggleui minesweeper ]

_ms_set_options = [
    local n
    n = (* $_ms_th $_ms_tw)
    // calculate board sizes/mines and apply limits
    if $arg1 [ _ms_th = (max (min $arg1 24) 9) ]
    if $arg2 [ _ms_tw = (max (min $arg2 30) 9) ]
    _ms_tm = (max (min (div $n 3) $_ms_tm) (div $n 10))
]

_ms_set_markers = [
    // in case of failure, update flag markers
    if (= $_ms_gm 2) [
        looplist i (listdel $_ms_fp $_ms_mp) [
            _ms_tile_open 0xE $i 0
        ]
    ]
    // update still hidden mine tiles
    looplist i $_ms_mp [
        if (= (at $_ms_cf $i) 0xF) [
            _ms_tile_open (case $_ms_gm 2 0xA 3 0xB) $i 0
        ]
    ]
]

_ms_tile_find = [
    // set variables and calculate repeated math
    local n r p c1 c2 c3 c4 c5 c6 c7 c8
    r = (mod $arg9 $_ms_w) ; p = (- $_ms_w 1)
    // calculate positions of adjacent tiles
    c1 = (- $arg9 $_ms_w)   // UP
    c2 = (+ $arg9 $_ms_w)   // DN
    c3 = (- $arg9 1)        // LT
    c4 = (+ $arg9 1)        // RT
    c5 = (- $arg9 $_ms_w 1) // UP-LT
    c6 = (- $arg9 $p)       // UP-RT
    c7 = (+ $arg9 $p)       // DN-LT
    c8 = (+ $arg9 $_ms_w 1) // DN-RT
    // if adjacent tiles fit conditions, execute
    if (> $c1 -1)                     $arg1 // UP
    if (< $c2 $_ms_bt)                $arg2 // DN
    if (> $r 0)                       $arg3 // LT
    if (< $r $p)                      $arg4 // RT
    if (&& [> $c5 -1] [> $r 0])       $arg5 // UP-LT
    if (&& [> $c6 -1] [< $r $p])      $arg6 // UP-RT
    if (&& [< $c7 $_ms_bt] [> $r 0])  $arg7 // DN-LT
    if (&& [< $c8 $_ms_bt] [< $r $p]) $arg8 // DN-RT
    arg10
]

_ms_tile_expl = [
    // add tile to work queue
    append _ms_tq $arg1
    // execute content as long as list is populated
    while [listlen $_ms_tq] [
        do [ _ms_tile_find @(loopconcat+ i 1 8 [
                result [[ n = $c@@i ; @@@arg2]]
        ]) (at $_ms_tq 0) ]
        _ms_tq = (sublist $_ms_tq 1)
    ]
]

_ms_tile_read = [
    local n t
    n = (at $_ms_nf $arg1)
    case $n 0x9 [
        // mark the mine as hit
        _ms_tile_open 0x9 $arg1 0
        _ms_hc = (+ $_ms_hc 1)
        // if lives are enabled, reduce by one, otherwise
        if (&& $_ms_ua $_ms_uc) [ _ms_uc = (- $_ms_uc 1) ] [
            // game over, undiscovered mines are shown and flag markers updated
            _ms_gm = 2
            _ms_t2 = (getmillis)
            _ms_set_markers
        ]
    ] 0x0 [
        _ms_tile_open 0x0 $arg1 1
        // explore all surrounding tiles until number border
        _ms_tile_expl $arg1 [
            // make sure the tile is hidden
            if (= (at $_ms_cf $n) 0xF) [
                // ensure tile is a blank and add to work queue if not there
                if (&& [= (at $_ms_nf $n) 0x0] [< (listfind= $_ms_tq $n) 0]) [
                    append _ms_tq $n
                ]
                // reveal the tested tile and add to completion counter
                _ms_tile_open (at $_ms_nf $n) $n 1
            ]
        ]
    ] () [ _ms_tile_open $n $arg1 1 ]
    // when the completion counter matches the safe tiles, trigger victory and update any hidden mine tiles
    if (= $_ms_pc (- $_ms_bt $_ms_m)) [
        _ms_gm = 3 ; _ms_t2 = (getmillis)
        _ms_set_markers
    ]
]

_ms_tile_open = [
    // start the game if still in waiting phase
    if (= $_ms_gm 0) [
        _ms_init_game $arg2
        _ms_gm = 1
        _ms_t1 = (getmillis)
    ]
    // reveal # tile at given position and add to percentage counter if needed
    _ms_cf = (listsplice $_ms_cf (tohex $arg1) $arg2 1)
    if $arg3 [ _ms_pc = (+ $_ms_pc 1) ]
]

_ms_init_main = [
    // initialise board variables
    _ms_th = $arg1
    _ms_tw = $arg2
    _ms_m  = $arg3
    _ms_h  = $_ms_th
    _ms_w  = $_ms_tw
    _ms_tm = $_ms_m
    // initialise game variables
    if $_ms_ua [ _ms_uc  = (+ (div $_ms_m 20) 1) ]
    _ms_bt = (* $_ms_h $_ms_w) // total tiles
    _ms_pc = 0 // percentage counter
    _ms_t1 = 0 // timer start
    _ms_t2 = 0 // timer stop
    _ms_gm = 0 // gamemode: 0/1/2/3 = waiting/active/won/lost
    _ms_hc = 0 // [MINE-HIT] counter
    _ms_fc = 0 // [FLAG] counter
    // initialise boards
    _ms_nf = ""
    _ms_mf = (loopconcat i $_ms_bt [result "0"])
    _ms_cf = (loopconcat i $_ms_bt [result 0xF])
    // initialise supplementary lists
    _ms_tq = ""
    _ms_mp = ""
    _ms_fp = ""
    _ms_tr = ""
]

_ms_init_game = [
    local a i r
    // find all adjacent tiles of the first-click tile
    do [ _ms_tile_find @(loopconcat+ i 1 8 [
        result [[ append a $c@@i ]]
    ]) $arg1 [ i = 0 ] ]
    // initialise the minefield board
    while [< $i $_ms_m] [
        r = (rnd $_ms_bt)
        // avoid writing to a previously picked spot
        if (&& [! (at $_ms_mf $r)] [!= $r $arg1] [< (listfind= $a $r) 0]) [
            _ms_mf = (listsplice $_ms_mf "1" $r 1)
            append _ms_mp $r
            i = (+ $i 1)
        ]
    ]
    // initialise the numerical board
    loop p $_ms_bt [
        if (at $_ms_mf $p) [ append _ms_nf 0x9 ] [
            do [ _ms_tile_find @(loopconcat+ i 1 8 [
                result [[ n = (+ (at $_ms_mf $c@@i) $n) ]]
            ]) $p [ append _ms_nf (tohex $n) ] ]
        ]
    ]
]

UImenu "minesweeper" [
    uieschide 0
    uihlist 0.01 [
        uivlist 0 [
            UIbox "box d d" 0 0.04 [
                uiclamp 1 1
                uispace 0.01 0 [
                    uialign -1
                    uihlist 0.01 [
                        local n ; n = (- $_ms_m $_ms_fc $_ms_hc)
                        uiimage "media/interface/minesweeper/flag.png" 0.032 0.032
                        uitext (concatword (? (< $n 0) "^f3") $n) 0.7
                    ]
                ]
                uispace 0.01 0 [
                    uialign 1
                    uihlist 0.01 [
                        local n t
                        t = (case $_ms_gm 0 0 1 (- $getmillis $_ms_t1) () (- $_ms_t2 $_ms_t1))
                        n = (mod $t 1000)
                        uitext (format "%1:%2%3" (div $t 1000) (if (< $n 100) [? (< $n 10) "00" "0"]) $n) 0.7
                        uiimage "media/interface/minesweeper/clock.png" 0.032 0.032
                    ]
                ]
            ]
            uispace 0.01 0.001 [
                uigroup [
                    uigrid $_ms_w 0 0 [
                        loop i $_ms_bt [
                            local c ; c = (at $_ms_cf $i)
                            uiimage (format "%1media/interface/minesweeper/tiles/%2.png" (
                                ? (|| [
                                    && uihover+? [! $uihold] [|| [= $c 0xF] [= $c 0xC]]
                                ] [
                                    && $_ms_qh [> (listfind= $_ms_tr $i) -1]
                                ]) "<mad:1.1/0.8/0.8>"
                            ) (? (&& [= $c 0xF] uihold+?) 0x0 $c)) 0.04 0.04 [
                                if (&& [< $_ms_gm 2] uihover?) [
                                    _ms_pos = $i
                                    cases $c 0xF [
                                        uirelease [ _ms_tile_read $i ]
                                        uiescpress [
                                            _ms_tile_open 0xC $i 0
                                            append _ms_fp $i
                                            _ms_fc = (+ $_ms_fc 1)
                                        ]
                                    ] 0xC [
                                        uiescpress [
                                            _ms_tile_open 0xF $i 0
                                            _ms_fp = (listdel $_ms_fp $i)
                                            _ms_fc = (- $_ms_fc 1)
                                        ]
                                    ]
                                ]
                            ]
                        ]
                    ]
                    if (&& [< $_ms_gm 2] uihover? [< 0x0 (at $_ms_cf $_ms_pos) 0x9]) [
                        uitarget 0 0 [
                            uiclamp 1 1 1 1
                            if (|| uialthold? [&& uieschold? uihold?]) [
                                local focuslist
                                _ms_sm = 0
                                _ms_qh = 1
                                _ms_tile_expl $_ms_pos [
                                    case (at $_ms_cf $n) 0xF [
                                        append focuslist $n
                                    ] 0xC [
                                        _ms_sm = (+ $_ms_sm 1)
                                    ] 0x9 [
                                        _ms_sm = (+ $_ms_sm 1)
                                    ]
                                ]
                                _ms_tr = $focuslist
                            ]
                            if (|| uialtrelease? [&& $_ms_qh [! $uialthold?] [|| [! $uihold?] [! $uieschold?]]]) [
                                local p ; p = (at $_ms_nf $_ms_pos)
                                if (&& [= $_ms_sm $p] [< 0x0 $p 0x9]) [
                                    looplist n $_ms_tr [
                                        if (= (at $_ms_cf $n) 0xF) [ _ms_tile_read $n ]
                                    ]
                                ]
                                _ms_qh = 0
                            ]
                        ]
                    ] [ _ms_qh = 0 ]
                ]
            ]
            UIbox "box d d" 0 0.04 [
                uiclamp 1 1
                uispace 0.01 0 [
                    uialign -1
                    uihlist 0.01 [
                        uiimage "media/interface/minesweeper/life.png" 0.032 0.032
                        uitext (? $_ms_ua (? $_ms_uc $_ms_uc (concatword "^f3" $_ms_uc)) "--") 0.7
                    ]
                ]
                uispace 0.01 0 [
                    uialign 1
                    uihlist 0.01 [
                        uitext (format "^f%1%2%%" (case $_ms_gm 2 3 3 0 () 7) (
                            precf (*f (divf $_ms_pc (- $_ms_bt $_ms_m)) 100) 1
                        )) 0.7
                        uiimage "media/interface/minesweeper/globe.png" 0.032 0.032
                    ]
                ]
            ]
        ]
        uivlist 0 [
            uiclamp 0 0 1 1
            UIbox "box d n n" 0.14 0 [
                uivlist 0.02 [
                    UIbuttonarea "" 0.14 0.032 [
                        uirelease [ _ms_init_main $_ms_th $_ms_tw $_ms_tm ]
                        uitext "New Game" 0.6
                    ]
                    uigrid 2 0.01 0.01 [
                        uiimage "media/interface/minesweeper/height.png" 0.032 0.032
                        uifill 0 0.032 [ uifield _ms_th 3 [ _ms_set_options $_ms_th 0 ] 0.55 style_generic_focus ]
                        uiimage "media/interface/minesweeper/width.png" 0.032 0.032
                        uifill 0 0.032 [ uifield _ms_tw 3 [ _ms_set_options 0 $_ms_tw ] 0.55 style_generic_focus ]
                        uiimage "media/interface/minesweeper/mine.png" 0.032 0.032
                        uifill 0 0.032 [ uifield _ms_tm 3 [ _ms_set_options 0 0 ] 0.55 style_generic_focus ]
                    ]
                    UIbuttonarea "" 0.14 0.032 [
                        uirelease [ _ms_ua = (! $_ms_ua) ]
                        uihlist 0.01 [
                            UIcheckbox $_ms_ua 0.016 0 0
                            uitext "Use Lives" 0.55
                        ]
                    ]
                ]
            ]
            uivlist 0.01 [
                UIbox "box d n n" 0.14 0 [
                    uiclamp 1 1
                    uivlist 0 [
                        uiclamp 1 1
                        UIbuttonarea "hold2" 0.14 0.032 [
                            uirelease [ _ms_init_main 9 9 10 ]
                            uitext (concatword (uihover? "^f0" "") "Easy") 0.55
                        ]
                        UIbuttonarea "hold2" 0.14 0.032 [
                            uirelease [ _ms_init_main 16 16 40 ]
                            uitext (concatword (uihover? "^f2" "") "Normal") 0.55
                        ]
                        UIbuttonarea "hold2" 0.14 0.032 [
                            uirelease [ _ms_init_main 16 30 80 ]
                            uitext (concatword (uihover? "^f3" "") "Hard") 0.55
                        ]
                        uiclamp* 1 1
                    ]
                ]
                uitext (concat "^f4FPS:" (tabify $getfps 1)) 0.45
                uialign- 1 1
            ]
        ]
    ]
] [
    // if game is running, restore clock on show
    if (= $_ms_gm 1) [
        _ms_t1 = (- $getmillis $_ms_t2)
    ] [ _ms_init_main $_ms_th $_ms_tw $_ms_tm ]
] [
    // if game is running, suspend clock on hide
    if (= $_ms_gm 1) [
        _ms_t2 = (- $getmillis $_ms_t1)
    ]
] [] [ uitext "Minesweeper C.S." 0.8 ]