Hammer Animations (Amnesia)

int swings = 0;

void OnStart()
{
	AddUseItemCallback("", "ItemHammer", "AreaUseItem", "HammerAnimation", true);
}

void HammerAnimation(string &in asItem, string &in asEntity)
{
	SetEntityActive("ObjectHammer", true);

	swings = 1;

	StartPlayerLookAt("ObjectHammer", 2, 2, "");

	AddTimer("movehammer", 0.1, "TimerMoveHammer");
	AddTimer("hammersound", 0.27, "TimerMoveHammer");
	AddTimer("resethammer", 0.4, "TimerMoveHammer");
	AddTimer("repeat", 0.6, "TimerMoveHammer");

	PlaySoundAtEntity("", "15_rock_break", "FakeWall", 0, false);
	PlaySoundAtEntity("", "15_make_hammer", "Player", 0.25, false);
	PlaySoundAtEntity("", "03_rock_move", "FakeWall", 2, false);
}

void TimerMoveHammer(string &in asTimer)
{
	if(asTimer == "movehammer") SetMoveObjectState("ObjectHammer", 0.4);

	else if(asTimer == "hammersound") {
		StopPlayerLookAt();
		PlaySoundAtEntity("", "impact_rock_high", "Player", 0, false);
		PlaySoundAtEntity("", "15_hammer", "Player", 0, false);
	}

	else if(asTimer == "resethammer") SetMoveObjectState("ObjectHammer", 0);

	if(swings < 3 && asTimer == "repeat") {
		AddTimer("movehammer", 0.01, "TimerMoveHammer");
		AddTimer("hammersound", 0.17, "TimerMoveHammer");
		AddTimer("resethammer", 0.3, "TimerMoveHammer");
		AddTimer("repeat", 0.5, "TimerMoveHammer");

		swings = swings + 1;
	}

	else if(swings == 3 && asTimer == "repeat") {
		AddTimer("movehammer", 0.2, "TimerMoveHammer");
		AddTimer("hammersound", 0.37, "TimerMoveHammer");
		AddTimer("resethammer", 0.5, "TimerMoveHammer");
		AddTimer("repeat", 0.8, "TimerMoveHammer");

		AddTimer("break", 0.42, "TimerMoveHammer");

		swings = swings + 1;
	}

	else if(swings == 4 && asTimer == "break") FinishAnimation();

	else if(swings == 4 && asTimer == "repeat") SetEntityActive("ObjectHammer", false);
}

void FinishAnimation()
{
	SetPropHealth("FakeWall", 0);
	GiveSanityBoost();
	PlaySoundAtEntity("", "03_break_wall", "FakeWall", 0, false);
}