https://rathena.org/board/topic/116906-add-script/

prontera,155,181,5	script	SampleNPC::mvp_ss_warper	4_F_KAFRA1,{
	doevent "mvp_ss_main::OnTalk";
}

-	script	mvp_ss_main	-1,{

	OnInit:
		.map$ = "guild_vs1-2";
		hideonnpc "mvp_ss_warper";
		end;

	OnTalk:
		warp .map$, 0, 0;
		end;

	OnMinute34:
		hideoffnpc "mvp_ss_warper";
		announce "Attention to all players online",0;
		sleep 1000;
		for (.@i = 5; .@i > 0; .@i--) {
			announce "MVP summoner is start in "+.@i+" minute(s) please warp to center of prontera",0;
			sleep 60000;
		}
		sleep 1000;
		for (.@i = 5; .@i > 0; .@i--) {
			mapannounce .map$,"MVP summoner start in "+.@i+"s",0;
			sleep 1000;
		}
		hideonnpc "mvp_ss_warper";
		initnpctimer; // Start the timer
		monster .map$,0,0,"Angeling",1096,1,"mvp_ss_main::OnWave";
		monster .map$,0,0,"Archangeling",1388,1,"mvp_ss_main::OnWave";
		monster .map$,0,0,"Ghostring",1582,1,"mvp_ss_main::OnWave";
		end;

	OnWave:
		if(!mobcount(.map$,"mvp_ss_main::OnWave")) {
			sleep 5000;
			mapannounce .map$,"First wave clear",0;
			sleep 2000;
			for (.@i = 5; .@i > 0; .@i--) {
				mapannounce .map$,"Second wave start in "+.@i+"s",0;
				sleep 1000;
			}
			monster .map$,0,0,"Maya Purple",1289,1,"mvp_ss_main::OnWaveFinal";
			monster .map$,0,0,"Mutant Dragon",1262,1,"mvp_ss_main::OnWaveFinal";
			monster .map$,0,0,"Tirfing",1204,"mvp_ss_main::OnWaveFinal";
		}
		end;

	OnWaveFinal:
		if(!mobcount(.map$,"mvp_ss_main::OnWaveFinal")) {
			sleep 5000;
			mapannounce .map$,"GG",0;
			sleep 2000;
			mapannounce .map$,"Stage is Clear",0;
			sleep 2000;
			mapannounce .map$,"all players warp to Prontera",0;
			sleep 2000;
			mapwarp .map$,"prontera",180,180;
		}
		end;
}