oscP5 client

import oscP5.*;
import netP5.*;

PGraphics canvas;
OscP5 oscP5;
NetAddress myBroadcastLocation;
String myConnectionPattern = "/server/connect";
String myLinePattern = "/server/line";

void setup() {
  //size(displayWidth, displayHeight);
  size(300, 400);
  frameRate(25);

  oscP5 = new OscP5(this,12000);
  myBroadcastLocation = new NetAddress("127.0.0.1",25565);
  OscMessage m = new OscMessage(myConnectionPattern);
  oscP5.flush(m,myBroadcastLocation);
  canvas = createGraphics(width, height, JAVA2D);
  canvas.beginDraw();
  canvas.background(255);
  canvas.endDraw();
}


void draw() {
  canvas.loadPixels();
  loadPixels();
  for (int i = 0; i < pixels.length; i++) {
    pixels[i] = canvas.pixels[i];
  }
  updatePixels();
  canvas.updatePixels();
}

void mouseDragged() {
  OscMessage m = new OscMessage(myLinePattern,new Object[0]);
  m.add(pmouseX);
  m.add(pmouseY);
  m.add(mouseX);
  m.add(mouseY);
  oscP5.flush(m, myBroadcastLocation);
  display(m);
}

void oscEvent(OscMessage theOscMessage) {
   display(theOscMessage);
}

void display(OscMessage theOscMessage) {
  if (theOscMessage.addrPattern().equals(myLinePattern)) {
    int x1 = theOscMessage.get(0).intValue();
    int y1 = theOscMessage.get(1).intValue();
    int x2 = theOscMessage.get(2).intValue();
    int y2 = theOscMessage.get(3).intValue();
    canvas.beginDraw();
    canvas.stroke(0);
    canvas.strokeWeight(1);
    canvas.line(x1, y1, x2, y2);
    canvas.endDraw();
  }
}