buildscript {
    repositories {
        maven {
            url 'https://repos.internal/maven/'
        }
    }
    dependencies {
        classpath 'external.common.script:common-gradle:4.+'
        classpath 'org.asciidoctor:asciidoctor-gradle-plugin:1.5.11'
        classpath 'com.netflix.nebula:nebula-project-plugin:6.0.2'
        classpath 'gradle.plugin.org.jetbrains.gradle.plugin.idea-ext:gradle-idea-ext:0.5'
    }
    dependencies {
        delete "build/gradle"
        ant.unjar src: configurations.classpath.files.find { it.name.matches '.*common-gradle.*' }, dest: 'build/gradle'
    }
}


apply plugin: "application"
apply from: "build/gradle/service.gradle"
// plugin ids cannot be used due to https://github.com/gradle/gradle/issues/1262
apply plugin: nebula.plugin.responsible.NebulaFacetPlugin // apply plugin: 'nebula.facet'
apply plugin: org.asciidoctor.gradle.AsciidoctorPlugin // apply plugin: 'org.asciidoctor.convert'
apply plugin: org.jetbrains.gradle.ext.IdeaExtPlugin // apply plugin: 'org.jetbrains.gradle.plugin.idea-ext'

// ...

dependencyUpdates {
    revision = "release"
    resolutionStrategy = {
        componentSelection { rules ->
            rules.all { ComponentSelection selection ->
                boolean rejected = ['alpha', 'beta', 'rc', 'cr', 'm', 'preview', 'b', 'ea'].any { qualifier ->
                    selection.candidate.version ==~ /(?i).*[.-]${qualifier}[.\d-+]*/
                }
                if (rejected) {
                    selection.reject('Release candidate')
                }
            }
        }
    }
    checkForGradleUpdate = true
    gradleReleaseChannel = "current"
}