blitDisks
	move.l	screenpointer2,d6
	move.l	animation_buffer_ptr,d5
	add.l	animation_buffer_off,d5


	lea		endmask,a0				; leftmost endmask to erase trash graphics after shift

	move.w	#160-4*8+8,$ffff8a30.w			;Destination Y-inc, bytes to skip after each written row
	move.w	#6,$ffff8a20.w					;Source X-inc
	move.w	#6,$ffff8a22.w					;Source Y-inc
	move.w	#8,$ffff8a2e.w					;Destination X-inc, bytes to skip after each written word
	move.w	#-1,$ffff8a2a.w					;Endmask 2, applied to every word between this and next
	move.w	#-1,$ffff8a2c.w					;Endmask 3, applited to every last word in a row
	move.b	#%00000010,$ffff8a3a.w			;Halftone operation (COPY)
	move.b	#%00000011,$ffff8a3b.w			;Logic operation (COPY)
	move.w	#4,$ffff8a36.w					;Number of words to copy per row
	move.b	#%11000000,d4
	move.w	#48,d7

	lea		diskPositionList,a6
.again
	move.l	(a6)+,d2						;x
	blt		.endWrite

		move.l	(a6)+,d1					; y

		move.l	d6,$ffff8a32.w				;Blitter destination address
		move.l	d5,$ffff8a24.w				;Blitter source address

		move.l	d2,d3
		and.l	#$fffffff0,d2
		lsr.l	#1,d2
		and.l	#$0000000f,d3					; bitmask position
		move.b	d3,$ffff8a3d.w					;Shift
		add.b	#%1000000,$ffff8a3d.w

		add.w	d3,d3
		move.w	(a0,d3.w),$ffff8a28.w				;

		add.l	d1,d2
		add.l	d2,$ffff8a32.w					;X-movement

		move.w	d7,$ffff8a38.w					;Number of rows to copy
		move.b	d4,$ffff8a3c.w				;Start blitter


		addq.l	#2,d5
		addq.l	#2,d6

		move.l	d6,$ffff8a32.w				;Blitter destination address
		move.l	d5,$ffff8a24.w				;Blitter source address
		add.l	d2,$ffff8a32.w					;X-movement

		move.w	d7,$ffff8a38.w					;Number of rows to copy
		move.b	d4,$ffff8a3c.w				;Start blitter
		not.w	$ffff8240

		addq.l	#2,d5
		addq.l	#2,d6

		move.l	d6,$ffff8a32.w				;Blitter destination address
		move.l	d5,$ffff8a24.w				;Blitter source address
		add.l	d2,$ffff8a32.w					;X-movement

		move.w	d7,$ffff8a38.w					;Number of rows to copy
		move.b	d4,$ffff8a3c.w				;Start blitter
		not.w	$ffff8240


		subq.l	#4,d5
		subq.l	#4,d6


		jmp		.again
.endWrite
	rts