build_vs15_2017_v2.bat

:: ================================================================================================
:: filename: build_vs15_2017_x64_full.bat
:: purpose : cmd.exe wrapper for cmake build file and build tool msbuild from visual studio
:: author  : A. Markoczy
:: ================================================================================================
@ECHO OFF

:: --------------------------------------------------------------- Input Variables ----------------
:: Path to VsDevCmd.bat (to load msbuild)
SET VSTOOLSPATH=%PROGRAMFILES(X86)%\Microsoft Visual Studio\2017\Community\Common7\Tools\VsDevCmd.bat
:: cmake -G -> see available generators
SET GENERATOR=Visual Studio 15 2017 Win64
SET OUTDIR=build_vs15_2017_x64
:: Name of the VS Solution file
SET SLN=Tutorials.sln
:: VS Build target
SET TARGET=tutorial18_particles
:: ------------------------------------------------------------------------------------------------

:: Delete Cache (Full rebuild, optional)
:: DEL CMakeCache.txt

:: Make build files (CMAKE)
CMAKE -B%OUTDIR% -H. -G"%GENERATOR%"

:: Load VS Tools
if NOT "%VSTOOLSLOADED%" == "TRUE" (
    ECHO Loading vs tools...
    SET CURDIR=%CD%
    CALL "%VSTOOLSPATH%"
    SET VSTOOLSLOADED=TRUE
    ECHO Finished loading vs tools.
)

:: Set target if specified
IF [%TARGET%] == [] (
  SET ARGS=
) ELSE (
  SET ARGS=/t:"%TARGET%"
)

:: Goto build dir
CD %CURDIR%\%OUTDIR%
:: Exec MSBUILD
MSBUILD ".\%SLN%" %ARGS%
:: Return to current dir
CD %CURDIR%