zone.mac

#turbo 10

Sub Main
	/if (${Defined[Param0]}) {
		/if (${Param0.Equal[szone]}) {
			/if (${Param6.Length}>0) {
				/call SayZone "${Param1}" "${Param2} ${Param3} ${Param4} ${Param5} ${Param6}"
			} else /if (${Param5.Length}>0) {
				/call SayZone "${Param1}" "${Param2} ${Param3} ${Param4} ${Param5}"
			} else /if (${Param4.Length}>0) {
				/call SayZone "${Param1}" "${Param2} ${Param3} ${Param4}"
			} else /if (${Param3.Length}>0) {
				/call SayZone "${Param1}" "${Param2} ${Param3}"
			} else /if (${Param2.Length}>0) {
				/call SayZone "${Param1}" "${Param2}"
			}
		} else {
			/call ClickZone "${Param0}"
		}
	} else {
		/call ClickZone
	}
/return


Sub SayZone(ZonerName,ZoneToPhrase)
	/if (${Target.ID}) /squelch /target clear
	/if (${Stick.Status.Equal[ON]}) /stick off
	/if (${NetAdvPath.Status}==1) /netfollow off
	/declare ZonerID int local ${Spawn[npc ${ZonerName}].ID}
	/target id ${ZonerID}
	/delay 1s ${Target.ID} == ${ZonerID}
	/if (${Target.ID} == ${ZonerID}) {
		/moveto ID ${Target.ID}
		/delay 5s !${MoveTo.Moving}
		/say ${ZoneToPhrase}
	} else {
		/bc I was unable to target ${ZonerName}.
	}
/return

Sub ClickZone(ZoneToName)
	/declare thisdoor string local
	/if (${Defined[ZoneToName]}) {
		/if (${ZoneToName.Equal[uqua]}) {
			/if (${Zone.ShortName.NotEqual[yxtta]}) /return
			| the actual statue is NIHALTAR801 but by dropping the 1,
			| the character will target whichever one they are next to.
			/varset thisdoor NIHALTAR80
		} else /if (${ZoneToName.Equal[potactics]} || ${Param0.Equal[tactics]}) {
			/if (${Zone.ShortName.NotEqual[potranquility]}) /return
			/varset thisdoor TACTICPORT500
		} else /if (${ZoneToName.Equal[povalor]} || ${Param0.Equal[valor]}) {
			/if (${Zone.ShortName.NotEqual[potranquility]}) /return
			| HOH and POVALOR are named backwards in the DB
			/varset thisdoor HONORPORT500
		} else /if (${ZoneToName.Equal[solrotower]} || ${Param0.Equal[solro]}) {
			/if (${Zone.ShortName.NotEqual[potranquility]}) /return
			/varset thisdoor SOLROPORT500
		} else /if (${ZoneToName.Equal[hohonora]} || ${Param0.Equal[hoh]}) {
			/if (${Zone.ShortName.NotEqual[potranquility]}) /return
			| HOH and POVALOR are named backwards in the DB
			/varset thisdoor VALORPORT500
		}
	}
	/declare OldZoneID int local ${Zone.ID}
	/if (${Target.ID}) /squelch /target clear
	/if (${Stick.Status.Equal[ON]}) /stick off
	/if (${NetAdvPath.Status}==1) /netfollow off
	/squelch /doortarget ${thisdoor}
	/nomodkey /keypress Insert
:MoveToDoor
	/if (${OldZoneID}==${Zone.ID}) {
		/if (${DoorTarget.Distance}<75) {
			/squelch /face fast door
			/nomodkey /keypress u
			/if (${DoorTarget.Distance}>=12) {
				/nomodkey /keypress forward hold
				/delay 1
				/nomodkey /keypress forward
			} else {
				/nomodkey /keypress back hold
				/delay 1
				/nomodkey /keypress back
			}
			/nomodkey /keypress Home
			/nomodkey /keypress u
			/goto :MoveToDoor
		} else {
			/return
		}
	}
/return