python2-requests PKGBUILD

# Maintainer:  Marcell Meszaros < marcell.meszaros AT runbox.eu >
# Contributor: Felix Yan <[email protected]>
# Contributor: Massimiliano Torromeo <[email protected]>
# Contributor: Drommer <[email protected]>

_pkgname='requests'
_commit='79f60274f7e461b8fd2f579e741f748438d7eadb'
pkgname='python2-requests'
pkgver=2.27.1.r6105.79f60274
pkgrel=1
pkgdesc='HTTP for Humans (Python 2)'
arch=('any')
url="https://pypi.org/project/requests"
license=('Apache')
depends=('python2')
makedepends=('python2-setuptools')
optdepends=('python2-pysocks: SOCKS proxy support (deprecated)')
source=("https://github.com/psf/${_pkgname}/archive/${_commit}.tar.gz"
        'certs.patch')
sha256sums=('0a1546273cd6912b44373de111d55c1b0497054e9ffcbfc7d892a81124d09dcb'
            '31dd7b6956ed5488cb55ad81ca91a95036dda7c8662d0bf82d71335ea44a5da3')

prepare() {
  cd ${_pkgname}-${_commit}

  sed -e "s/,<.*'/'/" \
      -e '/certifi/d' \
      -e '/charset_normalizer/d' \
      -i 'setup.py'

  patch --verbose -p1 -i "${srcdir}/certs.patch"

  sed -e '1s|#![ ]*/[a-zA-Z0-9./_ ]*python.*|#!/usr/bin/env python2|' \
      -i $(find . -name '*.py')
}

build() {
  cd ${_pkgname}-${_commit}
  python2 setup.py build
}

package() {
  cd ${_pkgname}-${_commit}
  python2 setup.py install --root="${pkgdir}" --prefix='/usr' --optimize=1 --skip-build
  install --verbose -Dm 644 'README.md' -t "${pkgdir}/usr/share/doc/${pkgname}"
}