Consult Script

string generic_stasis() {
    return  "while monsterhpabove 350 && !pastround 10  \n" +
            "    use seal tooth                        \n" +
            "endwhile                                   \n";
}

string free_fight() {
    return  "while !pastround 10 \n" +
            "    use seal tooth \n" +
            "endwhile            \n" +
            "attack with weapon  \n" +
            "repeat";
}

string sandworm_kill() {
    if (my_lightning() >= 20) {
        return "skill lightning strike";
    }
    if (to_int(get_property("_shatteringPunchUsed")) < 3) {
        return "skill shattering punch";
    }
    if (have_skill($skill[Fire the Jokester's Gun]) && !to_boolean(get_property("_firedJokestersGun"))) {
        return "skill fire the jokester's gun";
    }
    if (to_int(get_property("_powerPillUses")) < 20) {
        return "use power pill";
    }
    if (to_int(get_property("_usedReplicaBatoomerang")) < 3) {
        return "use replica bat-oomerang";
    }
    /* TODO: Add gingerbread mob hit. */
    return "";
}

string sandworm() {
    return  generic_stasis() + sandworm_kill();
}

string gingerbread() {
    return generic_stasis() + "use gingerbread cigarette";
}

string red_zeppelin() {
    return generic_stasis() + "use glark cable";
}

string crayon_copier() {
    if (to_int(get_property("_raindohCopiesMade")) < 5) {
        return "use rain-doh black box\n";
    }
    return "use spooky putty sheet\n";
}

string crayon() {
    return crayon_copier() + free_fight();
}

void runmacro(string macro) {
    visit_url("fight.php?action=macro&macrotext=" + url_encode(macro) ,true,true);
}
void main(int initround, monster foe, string page_text) {
    switch (foe) {
        case $monster[Giant Sandworm]:
             runmacro(sandworm());
             break;
        case $monster[Gingerbread Finance Bro]: /* I think this is the entire list of cigarettable monsters, and no extras... */
        case $monster[Gingerbread Gentrifier]:
        case $monster[Gingerbread Tech Bro]:
        case $monster[Gingerbread Vagrant]:
        case $monster[Gingerbread Wino]:
        case $monster[Gingerbread Convict]:
        case $monster[Gingerbread Lawyer]:
        case $monster[Gingerbread Mugger]:
        case $monster[Gingerbread Mutant]:
            runmacro(gingerbread());
            break;
        case $monster[Red Herring]:
        case $monster[Red Snapper]:
        case $monster[Red Butler]:
        case $monster[Man with the red buttons]:
        case $monster[Red Skeleton]:
        case $monster[Red Fox]:
            runmacro(red_zeppelin());
            break;
        case $monster[Black Crayon Beast]:
            runmacro(crayon());
            break;
        case $monster[Eldritch Tentacle]:
        case $monster[X-32-F Combat Training Snowman]:
        case $monster[BRICKO Ooze]:
        case $monster[Witchess Knight]:
        case $monster[biker]:
        case $monster[burnout]:
        case $monster[jock]:
        case $monster[party girl]:
        case $monster["plain" girl]:
        case $monster[lynyrd]:
        case $monster[sausage goblin]:
        case $monster[LOV Enforcer]:
        case $monster[LOV Engineer]:
        case $monster[LOV Equivocator]:
            runmacro(free_fight());
            break;
        default:
            return;

    }
}